[gentoo-commits] repo/gentoo:master commit in: dev-libs/libcbor/

[Thomas Deutschmann]

commit:     6ecfd1ca3f66b718f42a65b57ed5212199248d69
Author:     Thomas Deutschmann <whissi <AT> gentoo <DOT> org>
AuthorDate: Mon Mar 30 16:59:11 2020 +0000
Commit:     Thomas Deutschmann <whissi <AT> gentoo <DOT> org>
CommitDate: Mon Mar 30 16:59:11 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6ecfd1ca

dev-libs/libcbor: bump to v0.6.1

Package-Manager: Portage-2.3.96, Repoman-2.3.22
Signed-off-by: Thomas Deutschmann <whissi <AT> gentoo.org>

 dev-libs/libcbor/Manifest             |  1 +
 dev-libs/libcbor/libcbor-0.6.1.ebuild | 68 +++++++++++++++++++++++++++++++++++
 2 files changed, 69 insertions(+)

diff --git a/dev-libs/libcbor/Manifest b/dev-libs/libcbor/Manifest
index 727832f6f39..d9c19bffcc8 100644
--- a/dev-libs/libcbor/Manifest
+++ b/dev-libs/libcbor/Manifest
@@ -1,2 +1,3 @@
 DIST libcbor-0.5.0.tar.gz 719348 BLAKE2B 57e15e648159e7858d9d57a8b4cb7f3682f8153248610c9a3385cf9cbdea8babaf81d596b25d44bf6d59c75de23e76cce462fa7860b294019f46636726206d5a SHA512 5c2e9610d9fbb0bfc59f89a180f70b58539a1760fd39cad696af372c164a87828a23bb4d3a54d8e9d846be5271204800f0ad63656ef830f06a0ccdd10edfdb2c
 DIST libcbor-0.6.0.tar.gz 262622 BLAKE2B 2d3bc10bdb69c9205430718a8f2652672a8fa580ba7951c4012bdc8b502a9d6dcb26f398740f5fd35dfe0634f8e3d8ddf7eff5b9ec35c95cdc5383e2dce9f0ab SHA512 6adbb32780d428140388295c5d740bd77b0ae7b21e3f73629ba56a3aa4e4ee5dbb715454061b0f6f67f2b19ea8366e0e5c24f4ffb1ba629afcb7a776a15045f7
+DIST libcbor-0.6.1.tar.gz 263486 BLAKE2B 9a2415c1dde7ed611075c3b03ea1d8ab63bcb00dfc0cae3d7a3bb225b6fbee2a8f576b1f0f97eb6f0cf14c1a6e9df1c77f69320bac041287b0dec37c073f8b85 SHA512 dc9bb7d18b934fe33faabe30010425cb272d7e135f3bf233554bc934b1701f85c7b662e0d5a6a1921c21cd46acb4393600e9adc05b09d1b2a8e3c92ca9d7e4e8

diff --git a/dev-libs/libcbor/libcbor-0.6.1.ebuild b/dev-libs/libcbor/libcbor-0.6.1.ebuild
new file mode 100644
index 00000000000..368f5493f9e
--- /dev/null
+++ b/dev-libs/libcbor/libcbor-0.6.1.ebuild
@@ -0,0 +1,68 @@
+# Copyright 2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+inherit python-any-r1 cmake-utils
+
+DESCRIPTION="CBOR protocol implementation for C and others"
+HOMEPAGE="https://github.com/pjk/libcbor"
+SRC_URI="https://github.com/PJK/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0/1"
+KEYWORDS="~amd64 ~arm ~ppc64 ~x86"
+IUSE="+custom-alloc doc test"
+
+BDEPEND="
+	doc? (
+		$(python_gen_any_dep '
+			dev-python/sphinx[${PYTHON_USEDEP}]
+			dev-python/breathe[${PYTHON_USEDEP}]
+		')
+	)
+	test? ( dev-util/cmocka )
+"
+
+RESTRICT="!test? ( test )"
+
+CMAKE_MAKEFILE_GENERATOR="emake"
+
+python_check_deps() {
+	has_version "dev-python/sphinx[${PYTHON_USEDEP}]" && \
+		has_version "dev-python/breathe[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use doc && python-any-r1_pkg_setup
+}
+
+src_configure() {
+	local -a mycmakeargs=(
+		-DCMAKE_BUILD_TYPE=Release
+		-DCBOR_CUSTOM_ALLOC=$(usex custom-alloc 'ON' 'OFF')
+		-DWITH_TESTS=$(usex test 'ON' 'OFF')
+	)
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+
+	if use doc; then
+		pushd doc >/dev/null || die
+		emake html man
+		popd >/dev/null || die
+	fi
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	if use doc; then
+		dodoc -r doc/build/html
+		doman doc/build/man/*
+	fi
+}