[gentoo-commits] repo/gentoo:master commit in: dev-python/python-lsp-server/files/, dev-python/python-lsp-server/

[Andrew Ammerlaan]

commit:     61ee14e60c8a960aceeea11d3df04921a6a0ee3b
Author:     Andrew Ammerlaan <andrewammerlaan <AT> gentoo <DOT> org>
AuthorDate: Fri Dec 30 11:32:04 2022 +0000
Commit:     Andrew Ammerlaan <andrewammerlaan <AT> gentoo <DOT> org>
CommitDate: Fri Dec 30 11:32:04 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=61ee14e6

dev-python/python-lsp-server: add 1.7.0

Signed-off-by: Andrew Ammerlaan <andrewammerlaan <AT> gentoo.org>

 dev-python/python-lsp-server/Manifest              |  1 +
 ...ython-lsp-server-1.7.0-unpin-all-the-deps.patch | 51 +++++++++++++
 .../python-lsp-server-1.7.0.ebuild                 | 87 ++++++++++++++++++++++
 3 files changed, 139 insertions(+)

diff --git a/dev-python/python-lsp-server/Manifest b/dev-python/python-lsp-server/Manifest
index 902dd05fb26d..a578bb14212a 100644
--- a/dev-python/python-lsp-server/Manifest
+++ b/dev-python/python-lsp-server/Manifest
@@ -1 +1,2 @@
 DIST python-lsp-server-1.6.0.tar.gz 85242 BLAKE2B 52fcca5a93035a6ec8179908b2139e9392220cad082afb4c31b18284cdd53050c68fca4bcc9d852fa9acb49200487431fec37dc840e61ab9320fd6c3a86189ee SHA512 e4ab52f334fb1eece3458258ed39bf66eeb6056ed7e243be9c69ce2bac92792786df2fbc1d316133ac5523b44a57e7d89d4d6f18120c748e78ef20570a325c9b
+DIST python-lsp-server-1.7.0.tar.gz 95085 BLAKE2B 8cce5a01588d44efbc19f8ceec67e61580835814f403d6bda4ca2f82f56dc35c85fc3176f8ebc1eea720aa92710379f87a5e98f443f71a5d16e5bfe48702da1b SHA512 2ef31bdd4451b4b282469223ff5cc5799f4487d3dfc593dfc58483b939802754e0e375461723bf7a90d0fd71f945c927106c5d929621a70f83c3f30bddf68250

diff --git a/dev-python/python-lsp-server/files/python-lsp-server-1.7.0-unpin-all-the-deps.patch b/dev-python/python-lsp-server/files/python-lsp-server-1.7.0-unpin-all-the-deps.patch
new file mode 100644
index 000000000000..7bc98e1eb2c8
--- /dev/null
+++ b/dev-python/python-lsp-server/files/python-lsp-server-1.7.0-unpin-all-the-deps.patch
@@ -0,0 +1,51 @@
+diff --git a/pyproject.toml b/pyproject.toml
+index 1422313..4e1ecad 100644
+--- a/pyproject.toml
++++ b/pyproject.toml
+@@ -13,7 +13,7 @@ readme = "README.md"
+ license = {text = "MIT"}
+ requires-python = ">=3.7"
+ dependencies = [
+-    "jedi>=0.17.2,<0.19.0",
++    "jedi>=0.17.2",
+     "python-lsp-jsonrpc>=1.0.0",
+     "pluggy>=1.0.0",
+     "docstring-to-markdown",
+@@ -27,26 +27,26 @@ Homepage = "https://github.com/python-lsp/python-lsp-server"
+ 
+ [project.optional-dependencies]
+ all = [
+-    "autopep8>=1.6.0,<1.7.0",
+-    "flake8>=5.0.0,<7",
+-    "mccabe>=0.7.0,<0.8.0",
+-    "pycodestyle>=2.9.0,<2.11.0",
++    "autopep8>=1.6.0",
++    "flake8>=5.0.0",
++    "mccabe>=0.7.0",
++    "pycodestyle>=2.9.0",
+     "pydocstyle>=2.0.0",
+-    "pyflakes>=2.5.0,<3.1.0",
++    "pyflakes>=2.5.0",
+     "pylint>=2.5.0",
+     "rope>1.2.0",
+     "yapf",
+     "whatthepatch"
+ ]
+-autopep8 = ["autopep8>=1.6.0,<1.7.0"]
+-flake8 = ["flake8>=5.0.0,<7"]
+-mccabe = ["mccabe>=0.7.0,<0.8.0"]
+-pycodestyle = ["pycodestyle>=2.9.0,<2.11.0"]
++autopep8 = ["autopep8>=1.6.0"]
++flake8 = ["flake8>=5.0.0"]
++mccabe = ["mccabe>=0.7.0"]
++pycodestyle = ["pycodestyle>=2.9.0"]
+ pydocstyle = ["pydocstyle>=2.0.0"]
+-pyflakes = ["pyflakes>=2.5.0,<3.1.0"]
++pyflakes = ["pyflakes>=2.5.0"]
+ pylint = ["pylint>=2.5.0"]
+ rope = ["rope>1.2.0"]
+-yapf = ["yapf", "whatthepatch>=1.0.2,<2.0.0"]
++yapf = ["yapf", "whatthepatch>=1.0.2"]
+ websockets = ["websockets>=10.3"]
+ test = [
+     "pylint>=2.5.0",

diff --git a/dev-python/python-lsp-server/python-lsp-server-1.7.0.ebuild b/dev-python/python-lsp-server/python-lsp-server-1.7.0.ebuild
new file mode 100644
index 000000000000..6215864096bc
--- /dev/null
+++ b/dev-python/python-lsp-server/python-lsp-server-1.7.0.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Python Language Server for the Language Server Protocol"
+HOMEPAGE="https://github.com/python-lsp/python-lsp-server"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+IUSE="all-plugins"
+
+BDEPEND="
+	test? (
+		>=dev-python/autopep8-1.6.0[${PYTHON_USEDEP}]
+		dev-python/flaky[${PYTHON_USEDEP}]
+		>=dev-python/flake8-5.0.0[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		>=dev-python/mccabe-0.7.0[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		>=dev-python/pycodestyle-2.9.0[${PYTHON_USEDEP}]
+		>=dev-python/pydocstyle-2.0.0[${PYTHON_USEDEP}]
+		>=dev-python/pyflakes-2.5.0[${PYTHON_USEDEP}]
+		>=dev-python/pylint-2.5.0[${PYTHON_USEDEP}]
+		dev-python/QtPy[gui,testlib,${PYTHON_USEDEP}]
+		>=dev-python/rope-1.2.0[${PYTHON_USEDEP}]
+		dev-python/yapf[${PYTHON_USEDEP}]
+		>=dev-python/whatthepatch-1.0.2[${PYTHON_USEDEP}]
+	)
+"
+
+RDEPEND="
+	dev-python/docstring-to-markdown[${PYTHON_USEDEP}]
+	>=dev-python/jedi-0.17.2[${PYTHON_USEDEP}]
+	>=dev-python/python-lsp-jsonrpc-1.0.0[${PYTHON_USEDEP}]
+	dev-python/pluggy[${PYTHON_USEDEP}]
+	all-plugins? (
+		>=dev-python/autopep8-1.6.0[${PYTHON_USEDEP}]
+		>=dev-python/flake8-5.0.0[${PYTHON_USEDEP}]
+		>=dev-python/mccabe-0.7.0[${PYTHON_USEDEP}]
+		>=dev-python/pycodestyle-2.9.0[${PYTHON_USEDEP}]
+		>=dev-python/pydocstyle-2.0.0[${PYTHON_USEDEP}]
+		>=dev-python/pyflakes-2.5.0[${PYTHON_USEDEP}]
+		>=dev-python/pylint-2.5.0[${PYTHON_USEDEP}]
+		>=dev-python/rope-1.2.0[${PYTHON_USEDEP}]
+		dev-python/yapf[${PYTHON_USEDEP}]
+		>=dev-python/whatthepatch-1.0.2[${PYTHON_USEDEP}]
+	)
+"
+
+# Upstream is overly cautious, insists on pinning
+# dependencies to versions required by other dependencies.
+# i.e. pin to <dev-python/pycodestyle-2.9.0 because
+# dev-python/autopep8-1.6.0 requires that version.
+# This causes way more problems then it solves.
+PATCHES=(
+	"${FILESDIR}/${P}-unpin-all-the-deps.patch"
+)
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# remove pytest-cov dep
+	sed -i -e '/addopts =/d' pyproject.toml || die
+	distutils-r1_python_prepare_all
+}
+
+pkg_postinst() {
+	optfeature "Automatically format Python code to conform to the PEP 8 style guide" dev-python/autopep8
+	optfeature "A wrapper around PyFlakes, pep8 & mccabe" dev-python/flake8
+	optfeature "flake8 plugin: McCabe complexity checker" dev-python/mccabe
+	optfeature "Python style guide checker (fka pep8)" dev-python/pycodestyle
+	optfeature "Python docstring style checker" dev-python/pydocstyle
+	optfeature "Passive checker for Python programs" dev-python/pyflakes
+	optfeature "Python code static checker" dev-python/pylint
+	optfeature "Python refactoring library" dev-python/rope
+	optfeature "A formatter for Python files" dev-python/yapf
+}