[gentoo-commits] repo/gentoo:master commit in: sci-libs/dlib/

[David Seifert]

commit:     83a445079c6b79e602aa11c6063761f57f074c12
Author:     David Seifert <soap <AT> gentoo <DOT> org>
AuthorDate: Wed Mar 31 11:40:54 2021 +0000
Commit:     David Seifert <soap <AT> gentoo <DOT> org>
CommitDate: Wed Mar 31 11:40:54 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=83a44507

sci-libs/dlib: Version bump to 19.22

Package-Manager: Portage-3.0.18, Repoman-3.0.3
Signed-off-by: David Seifert <soap <AT> gentoo.org>

 sci-libs/dlib/Manifest          |  1 +
 sci-libs/dlib/dlib-19.22.ebuild | 97 +++++++++++++++++++++++++++++++++++++++++
 2 files changed, 98 insertions(+)

diff --git a/sci-libs/dlib/Manifest b/sci-libs/dlib/Manifest
index 63c671d911e..f824015a676 100644
--- a/sci-libs/dlib/Manifest
+++ b/sci-libs/dlib/Manifest
@@ -1 +1,2 @@
 DIST dlib-19.16.tar.gz 10411975 BLAKE2B 93047590a4d8f4685970d3db6841cbf9cc90ca8a5e50f0929a106d887e5db1b4fd96bbe14380537a3e28369a8db6d9d8c067e7768000ac3c7d0f225b46369326 SHA512 4e040ef88acff05e1a48e499b813c876b22ad3f989d076bdf19969d01036b62e51a0dff30b70046910ba31dfa1b1c2450a7fad41ae3142b7285ed74b8d584887
+DIST dlib-19.22.tar.gz 10796236 BLAKE2B 5ca840536f61b38557d39ff6c24d9727f7c494e032d5abf912ccf83f724ecad61ce241126478eeed8b14e33b994af4065b1cfaf17a3b29cfa0dafc236e4c2a06 SHA512 49af41460de9aa270e47ee1d158231e87ffdbbf56ca29a3382dd896fcf81ef04729e59bd9c26eac63fb088cefce651149e5cdb0ffed73bfd6b05127887114d94

diff --git a/sci-libs/dlib/dlib-19.22.ebuild b/sci-libs/dlib/dlib-19.22.ebuild
new file mode 100644
index 00000000000..04deb083df0
--- /dev/null
+++ b/sci-libs/dlib/dlib-19.22.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+DISTUTILS_OPTIONAL=1
+inherit cmake cuda distutils-r1
+
+DESCRIPTION="Numerical and networking C++ library"
+HOMEPAGE="http://dlib.net/"
+SRC_URI="https://github.com/davisking/dlib/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Boost-1.0"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="cblas cuda debug examples gif jpeg lapack mkl png python sqlite test X cpu_flags_x86_avx cpu_flags_x86_sse2 cpu_flags_x86_sse4_1"
+REQUIRED_USE="python? ( png ${PYTHON_REQUIRED_USE} )"
+RESTRICT="!test? ( test )"
+
+# doc needs a bunch of deps not in portage
+RDEPEND="
+	cblas? ( virtual/cblas )
+	cuda? ( dev-libs/cudnn:= )
+	gif? ( media-libs/giflib:= )
+	jpeg? ( virtual/jpeg:0= )
+	lapack? ( virtual/lapack )
+	mkl? ( sci-libs/mkl )
+	png? ( media-libs/libpng:0= )
+	python? ( ${PYTHON_DEPS} )
+	sqlite? ( dev-db/sqlite:3 )
+	X? ( x11-libs/libX11 )"
+DEPEND="${RDEPEND}"
+BDEPEND="python? ( test? ( dev-python/pytest[${PYTHON_USEDEP}] ) )"
+
+DOCS=( docs/README.txt )
+
+src_prepare() {
+	use cuda && cuda_src_prepare
+	cmake_src_prepare
+	use python && distutils-r1_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DDLIB_ENABLE_ASSERTS=$(usex debug)
+		-DDLIB_ENABLE_STACK_TRACE=$(usex debug)
+		-DDLIB_GIF_SUPPORT=$(usex gif)
+		-DDLIB_JPEG_SUPPORT=$(usex jpeg)
+		-DDLIB_PNG_SUPPORT=$(usex png)
+		-DDLIB_LINK_WITH_SQLITE3=$(usex sqlite)
+		-DDLIB_NO_GUI_SUPPORT=$(usex X OFF ON)
+		-DDLIB_USE_BLAS=$(usex cblas)
+		-DDLIB_USE_CUDA=$(usex cuda)
+		-DDLIB_USE_LAPACK=$(usex lapack)
+		-DUSE_AVX_INSTRUCTIONS=$(usex cpu_flags_x86_avx)
+		-DUSE_SSE2_INSTRUCTIONS=$(usex cpu_flags_x86_sse2)
+		-DUSE_SSE4_INSTRUCTIONS=$(usex cpu_flags_x86_sse4_1)
+	)
+	cmake_src_configure
+	use python && distutils-r1_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+	use python && distutils-r1_src_compile
+}
+
+python_test() {
+	esetup.py test
+}
+
+src_test() {
+	(
+		local BUILD_DIR="${BUILD_DIR}"/dlib/test
+		mkdir -p "${BUILD_DIR}" || die
+		cd "${BUILD_DIR}" >/dev/null || die
+
+		local CMAKE_USE_DIR="${S}"/dlib/test
+		cmake_src_configure
+		cmake_build
+
+		./dtest --runall || die "Tests failed"
+	)
+
+	use python && distutils-r1_src_test
+}
+
+src_install() {
+	cmake_src_install
+	use python && distutils-r1_src_install
+
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}
+	fi
+}