Gentoo Archives: gentoo-commits

From: "Jeroen Roovers (jer)" <jer@g.o>
To: gentoo-commits@l.g.o
Subject: [gentoo-commits] gentoo-x86 commit in app-arch/dpkg: dpkg-1.16.0.1.ebuild ChangeLog
Date: Tue, 05 Apr 2011 14:56:16
Message-Id: 20110405145605.7440F20054@flycatcher.gentoo.org
jer         11/04/05 14:56:05

  Modified:             ChangeLog
  Added:                dpkg-1.16.0.1.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha29/cvs/Linux i686)

Revision  Changes    Path
1.160                app-arch/dpkg/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/dpkg/ChangeLog?rev=1.160&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/dpkg/ChangeLog?rev=1.160&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/dpkg/ChangeLog?r1=1.159&r2=1.160

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-arch/dpkg/ChangeLog,v
retrieving revision 1.159
retrieving revision 1.160
diff -u -r1.159 -r1.160
--- ChangeLog	2 Apr 2011 14:26:20 -0000	1.159
+++ ChangeLog	5 Apr 2011 14:56:05 -0000	1.160
@@ -1,6 +1,11 @@
 # ChangeLog for app-arch/dpkg
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-arch/dpkg/ChangeLog,v 1.159 2011/04/02 14:26:20 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-arch/dpkg/ChangeLog,v 1.160 2011/04/05 14:56:05 jer Exp $
+
+*dpkg-1.16.0.1 (05 Apr 2011)
+
+  05 Apr 2011; Jeroen Roovers <jer@g.o> +dpkg-1.16.0.1.ebuild:
+  Version bump.
 
   02 Apr 2011; Raúl Porcel <armin76@g.o> dpkg-1.15.8.10.ebuild:
   arm/ia64/m68k/s390/sh/sparc stable wrt #359115



1.1                  app-arch/dpkg/dpkg-1.16.0.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/dpkg/dpkg-1.16.0.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/dpkg/dpkg-1.16.0.1.ebuild?rev=1.1&content-type=text/plain

Index: dpkg-1.16.0.1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-arch/dpkg/dpkg-1.16.0.1.ebuild,v 1.1 2011/04/05 14:56:05 jer Exp $

EAPI=3

inherit eutils multilib autotools toolchain-funcs

DESCRIPTION="Package maintenance system for Debian"
HOMEPAGE="http://packages.qa.debian.org/dpkg"
SRC_URI="mirror://debian/pool/main/d/${PN}/${P/-/_}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-solaris ~x86-solaris"
IUSE="bzip2 dselect nls test unicode zlib"

LANGS="sv de es ja fr hu pl ru"

for X in ${LANGS} ; do
	IUSE="${IUSE} linguas_${X}"
done

RDEPEND=">=dev-lang/perl-5.6.0
	dev-perl/TimeDate
	>=sys-libs/ncurses-5.2-r7
	zlib? ( >=sys-libs/zlib-1.1.4 )
	bzip2? ( app-arch/bzip2 )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	nls? ( app-text/po4a )
	test? (
		dev-perl/DateTime-Format-DateParse
		dev-perl/IO-String
		dev-perl/Test-Pod
	)"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-1.15.5.6-bootstrap.patch

	# don't mess with linker optimisation, respect user's flags (don't break!)
	sed -i -e '/DPKG_LINKER_OPTIMISATIONS/d' configure.ac || die

	# Force the use of the running bash for get-version (this file is never
	# installed, so no need to worry about hardcoding a temporary bash)
	sed -i -e '1c\#!'"${BASH}" get-version || die

	# this test depends on a Debian only gzip extension that adds --rsyncable
	# which will therefore always fail on Gentoo. (bug #310847).
	sed -i scripts/Makefile.am \
		-e '/850_Dpkg_Compression.t/d' \
		|| die "sed failed"

	eautoreconf
}

src_configure() {
	tc-export CC
	local myconf
	if use nls; then
		myconf="--enable-nls $(use_with dselect)"
	else
		if use dselect; then
			elog "Building dselect requires USE=nls - disabling USE=dselect..."
		fi
		myconf="--disable-nls --without-dselect"
	fi
	econf \
		${myconf} \
		$(use_with bzip2 bz2) \
		$(use_enable unicode) \
		$(use_with zlib) \
		--disable-compiler-warnings \
		--without-selinux \
		--without-start-stop-daemon
}

src_install() {
	strip-linguas ${LANGS}
	if [ -z "${LINGUAS}" ] ; then
		LINGUAS=none
	fi

	emake DESTDIR="${D}" LINGUAS="${LINGUAS}" install || die "emake install failed"
	rm "${ED}"/usr/sbin/install-info || die "rm install-info failed"
	dodoc ChangeLog THANKS TODO
	keepdir /usr/$(get_libdir)/db/methods/{mnt,floppy,disk}
	keepdir /usr/$(get_libdir)/db/{alternatives,info,methods,parts,updates}
}