[gentoo-commits] repo/gentoo:master commit in: app-misc/jq/

[Patrick McLean]

commit:     34ceb242b5cb7367df61c856f5e876429baa41c0
Author:     Patrick McLean <chutzpah <AT> gentoo <DOT> org>
AuthorDate: Mon Feb  1 22:51:04 2016 +0000
Commit:     Patrick McLean <chutzpah <AT> gentoo <DOT> org>
CommitDate: Mon Feb  1 22:53:16 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=34ceb242

app-misc/jq: Revision bump, update bison dep to >=3.0 add rdep on oniguruma

Gentoo-Bug: 573058

Package-Manager: portage-2.2.27

 app-misc/jq/jq-1.5-r1.ebuild | 53 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

diff --git a/app-misc/jq/jq-1.5-r1.ebuild b/app-misc/jq/jq-1.5-r1.ebuild
new file mode 100644
index 0000000..df24e2f
--- /dev/null
+++ b/app-misc/jq/jq-1.5-r1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit autotools
+
+DESCRIPTION="A lightweight and flexible command-line JSON processor"
+HOMEPAGE="https://stedolan.github.com/jq/"
+SRC_URI="https://github.com/stedolan/jq/releases/download/${P}/${P}.tar.gz"
+
+LICENSE="MIT CC-BY-3.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~x64-macos"
+IUSE="oniguruma static-libs test"
+
+DEPEND=">=sys-devel/bison-3.0
+	sys-devel/flex
+	oniguruma? ( dev-libs/oniguruma[static-libs?] )
+	test? ( dev-util/valgrind )"
+RDEPEND="!static-libs? (
+		oniguruma? ( dev-libs/oniguruma[static-libs?] )
+	)"
+
+DOCS=( AUTHORS README )
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.5-dynamic-link.patch
+	"${FILESDIR}"/${P}-remove-automagic-dep-on-oniguruma.patch
+)
+
+src_prepare() {
+	sed -i '/^dist_doc_DATA/d' Makefile.am || die
+	sed -i -r "s:(m4_define\(\[jq_version\],) .+\):\1 \[${PV}\]):" \
+		configure.ac || die
+
+	default
+	eautoreconf
+}
+
+src_configure() {
+	# don't try to rebuild docs
+	econf \
+		--disable-docs \
+		$(use_enable static-libs static) \
+		$(use_with oniguruma)
+}
+
+src_install() {
+	default
+	use static-libs || find "${ED}" -name libjq.la -delete
+}