[gentoo-commits] repo/gentoo:master commit in: media-sound/qmmp/

[Lars Wendler]

commit:     4309a30532ee50619617b493b43d4d6b915e5a8a
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Wed Nov 29 18:32:10 2017 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Wed Nov 29 18:45:36 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4309a305

media-sound/qmmp: Bump to version 1.2.0

Closes: https://bugs.gentoo.org/639174
Package-Manager: Portage-2.3.16, Repoman-2.3.6

 media-sound/qmmp/Manifest          |   1 +
 media-sound/qmmp/metadata.xml      |   2 +
 media-sound/qmmp/qmmp-1.2.0.ebuild | 163 +++++++++++++++++++++++++++++++++++++
 3 files changed, 166 insertions(+)

diff --git a/media-sound/qmmp/Manifest b/media-sound/qmmp/Manifest
index 25076b3f5ab..274f86e8217 100644
--- a/media-sound/qmmp/Manifest
+++ b/media-sound/qmmp/Manifest
@@ -1,3 +1,4 @@
 DIST qmmp-1.1.10.tar.bz2 1142444 SHA256 1e5781bf65b3a27dd5e21349ac007464e67861dda99f8a0206984687881e0b9a SHA512 f9945ea428265c900751dd692e25eb0618e162e621bda7ab5f0f77d504aee66fa06390edca0155d18ca041706f461dcb9bb20678eaf32250b766e0f593915356 WHIRLPOOL 1beaa2339fa8b86c79876774a3da12a8a5a62bf729e4fd6bd6896aa225bc573dc2272cc7438b257fe6567c8c85f38a301f2740eef788322e1d872404e5db6c0c
 DIST qmmp-1.1.12.tar.bz2 1147871 BLAKE2B e511b02c38cbc5fcb478585df14a50c9f67985da9ef5e1e11557f2acbbd454d1b1beb430c8e2e2725a7d9ceea63243746fd41ecf2970fd3c52bcf21857bc1228 SHA512 a45680dcee478a7f03a04dbc87525368ac227a9de7e803252470f517027639d3426bf27a3235996d94ad68212596c03e7a67b5ad00a642532f02a820bf4097ee
 DIST qmmp-1.1.7.tar.bz2 1135005 SHA256 464f79d9a54e6456c5abcb570d7f062e48d3eaa3d60ad2b09c58bc62af5b87a7 SHA512 058187d34b848c0917077a167bcb52c63e39b5150409295ea658484d99fcd5582f7871979d3d3eea40aa97f0d9bf2a2d72ae721b827bcc0366b1bbc652aa3a72 WHIRLPOOL 1c1f22a22329619f63a1a24590b41b352d398bb4653117c81918b2e940e887c6aaa06f178674a97893de7418673022bdc800a09643d3fb38096f6dc78b7774c3
+DIST qmmp-1.2.0.tar.bz2 1182024 BLAKE2B 0dc471b053a68ddd1f4e5e09d37776712a7c3f323f801920e34843df54a188c9bc5edfeade5791be67177bb9b7a9435ab41763b156d068522db654d9c5a51809 SHA512 63b3a499efa1886d2bb0da093ab5b495a147a0d9ad23780780fd85011ae571179d71dc4222efab39609fe59ec25b9b62d907c8d10decd7fddb73220d963dcf57

diff --git a/media-sound/qmmp/metadata.xml b/media-sound/qmmp/metadata.xml
index 472f2398ac7..3a54863df65 100644
--- a/media-sound/qmmp/metadata.xml
+++ b/media-sound/qmmp/metadata.xml
@@ -11,6 +11,7 @@
 	</maintainer>
 	<use>
 		<flag name="analyzer">Enable visual analyzer</flag>
+		<flag name="archive">Enable archiving plugin via <pkg>app-arch/libarchive</pkg>.</flag>
 		<flag name="bs2b">Enable Bauer stereophonic-to-binaural headphone filter</flag>
 		<flag name="cover">Enable album cover support</flag>
 		<flag name="crossfade">Enable crossfade effect when switching tracks</flag>
@@ -27,6 +28,7 @@
 		<flag name="qsui">Enable QMMP simple UI</flag>
 		<flag name="qtmedia">Enable playback via <pkg>dev-qt/qtmultimedia</pkg></flag>
 		<flag name="scrobbler">Enable audioscrobbler/last.fm support</flag>
+		<flag name="shout">Enable shoutcast plug-in via <pkg>media-libs/libshout</pkg>.</flag>
 		<flag name="sid">Build with SID (Commodore 64 Audio) support</flag>
 		<flag name="soxr">Use the SoX resampling library</flag>
 		<flag name="stereo">Enable stereo effect</flag>

diff --git a/media-sound/qmmp/qmmp-1.2.0.ebuild b/media-sound/qmmp/qmmp-1.2.0.ebuild
new file mode 100644
index 00000000000..f7eff28d1db
--- /dev/null
+++ b/media-sound/qmmp/qmmp-1.2.0.ebuild
@@ -0,0 +1,163 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils xdg-utils
+[[ ${PV} = 9999 ]] && inherit subversion
+
+DESCRIPTION="Qt5-based audio player with winamp/xmms skins support"
+HOMEPAGE="http://qmmp.ylsoftware.com"
+if [[ ${PV} != 9999 ]]; then
+	SRC_URI="http://qmmp.ylsoftware.com/files/${P}.tar.bz2"
+	KEYWORDS="~amd64 ~x86"
+else
+	QMMP_DEV_BRANCH="1.2"
+	ESVN_REPO_URI="svn://svn.code.sf.net/p/${PN}-dev/code/branches/${PN}-${QMMP_DEV_BRANCH}"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+# KEYWORDS further up
+IUSE="aac +alsa analyzer archive bs2b cdda cover crossfade cue curl +dbus enca ffmpeg flac game
+gnome jack ladspa libav lyrics +mad midi mms modplug mplayer musepack notifier opus oss projectm
+pulseaudio qsui qtmedia scrobbler shout sid sndfile soxr stereo tray udisks +vorbis wavpack"
+
+REQUIRED_USE="
+	gnome? ( dbus )
+	shout? ( soxr vorbis )
+	udisks? ( dbus )
+"
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	media-libs/taglib
+	x11-libs/libX11
+	aac? ( media-libs/faad2 )
+	alsa? ( media-libs/alsa-lib )
+	archive? ( app-arch/libarchive )
+	bs2b? ( media-libs/libbs2b )
+	cdda? (
+		dev-libs/libcdio:=
+		dev-libs/libcdio-paranoia
+	)
+	cue? ( media-libs/libcue )
+	curl? ( net-misc/curl )
+	dbus? ( dev-qt/qtdbus:5 )
+	enca? ( app-i18n/enca )
+	ffmpeg? (
+		!libav? ( media-video/ffmpeg:= )
+		libav? ( media-video/libav:= )
+	)
+	flac? ( media-libs/flac )
+	game? ( media-libs/game-music-emu )
+	jack? (
+		media-libs/libsamplerate
+		media-sound/jack-audio-connection-kit
+	)
+	ladspa? ( media-libs/ladspa-cmt )
+	mad? ( media-libs/libmad )
+	midi? ( media-sound/wildmidi )
+	mms? ( media-libs/libmms )
+	modplug? ( >=media-libs/libmodplug-0.8.4 )
+	mplayer? ( media-video/mplayer )
+	musepack? ( >=media-sound/musepack-tools-444 )
+	opus? ( media-libs/opusfile )
+	projectm? (
+		dev-qt/qtgui:5[-gles2]
+		dev-qt/qtopengl:5
+		media-libs/libprojectm
+	)
+	pulseaudio? ( >=media-sound/pulseaudio-0.9.9 )
+	qtmedia? ( dev-qt/qtmultimedia:5 )
+	scrobbler? ( net-misc/curl )
+	shout? ( media-libs/libshout )
+	sid? ( >=media-libs/libsidplayfp-1.1.0 )
+	sndfile? ( media-libs/libsndfile )
+	soxr? ( media-libs/soxr )
+	udisks? ( sys-fs/udisks:2 )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+	wavpack? ( media-sound/wavpack )
+"
+DEPEND="${RDEPEND}
+	dev-qt/linguist-tools:5
+"
+
+DOCS=( AUTHORS ChangeLog README )
+
+src_prepare() {
+	if has_version dev-libs/libcdio-paranoia; then
+		sed -i \
+			-e 's:cdio/cdda.h:cdio/paranoia/cdda.h:' \
+			src/plugins/Input/cdaudio/decoder_cdaudio.cpp || die
+	fi
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DUSE_AAC="$(usex aac)"
+		-DUSE_ALSA="$(usex alsa)"
+		-DUSE_ANALYZER="$(usex analyzer)"
+		-DUSE_ARCHIVE="$(usex archive)"
+		-DUSE_BS2B="$(usex bs2b)"
+		-DUSE_CDA="$(usex cdda)"
+		-DUSE_COVER="$(usex cover)"
+		-DUSE_CROSSFADE="$(usex crossfade)"
+		-DUSE_CUE="$(usex cue)"
+		-DUSE_CURL="$(usex curl)"
+		-DUSE_KDENOTIFY="$(usex dbus)"
+		-DUSE_MPRIS="$(usex dbus)"
+		-DUSE_ENCA="$(usex enca)"
+		-DUSE_FFMPEG="$(usex ffmpeg)"
+		-DUSE_FILEWRITER="$(usex vorbis)"
+		-DUSE_FLAC="$(usex flac)"
+		-DUSE_GME="$(usex game)"
+		-DUSE_GNOMEHOTKEY="$(usex gnome)"
+		-DUSE_HAL=OFF
+		-DUSE_JACK="$(usex jack)"
+		-DUSE_LADSPA="$(usex ladspa)"
+		-DUSE_LYRICS="$(usex lyrics)"
+		-DUSE_MAD="$(usex mad)"
+		-DUSE_MIDI="$(usex midi)"
+		-DUSE_MMS="$(usex mms)"
+		-DUSE_MODPLUG="$(usex modplug)"
+		-DUSE_MPLAYER="$(usex mplayer)"
+		-DUSE_MPC="$(usex musepack)"
+		-DUSE_NOTIFIER="$(usex notifier)"
+		-DUSE_OPUS="$(usex opus)"
+		-DUSE_OSS="$(usex oss)"
+		-DUSE_PROJECTM="$(usex projectm)"
+		-DUSE_PULSE="$(usex pulseaudio)"
+		-DUSE_QSUI="$(usex qsui)"
+		-DUSE_QTMULTIMEDIA="$(usex qtmedia)"
+		-DUSE_SCROBBLER="$(usex scrobbler)"
+		-DUSE_SHOUT="$(usex shout)"
+		-DUSE_SID="$(usex sid)"
+		-DUSE_SNDFILE="$(usex sndfile)"
+		-DUSE_SOXR="$(usex soxr)"
+		-DUSE_STEREO="$(usex stereo)"
+		-DUSE_STATICON="$(usex tray)"
+		-DUSE_UDISKS2="$(usex udisks)"
+		-DUSE_VORBIS="$(usex vorbis)"
+		-DUSE_WAVPACK="$(usex wavpack)"
+	)
+
+	cmake-utils_src_configure
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+}