[gentoo-commits] repo/gentoo:master commit in: sys-kernel/gentoo-kernel-bin/

[Sam James]

commit:     43f8a729a1683b61e2b63c004243a347f42e0fb1
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sun Aug  1 20:27:24 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sun Aug  1 20:27:46 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=43f8a729

sys-kernel/gentoo-kernel-bin: bump to 5.10.55-r1 for arm64

Signed-off-by: Sam James <sam <AT> gentoo.org>

 sys-kernel/gentoo-kernel-bin/Manifest              |   1 +
 .../gentoo-kernel-bin-5.10.55-r1.ebuild            | 113 +++++++++++++++++++++
 2 files changed, 114 insertions(+)

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 8b8a3a6429d..6a91741fb71 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -34,6 +34,7 @@ DIST gentoo-kernel-5.10.54-1.amd64.xpak 65489821 BLAKE2B 7503ee8e4620649fbc27779
 DIST gentoo-kernel-5.10.54-1.arm64.xpak 61166026 BLAKE2B d86c315412edb45b9a8d4261e604db47102acfcfa94af6390855e3ca6a90959004c6958db2022a08d30f1fee35a8bb05f2c82af713433ed6e39d397163eed496 SHA512 cfd0c4eb028ee59c6e72d113387a7ec882c1c758e516cdd3e15d7f02530da9fcad96a686e3ecfa8bb23b02ec0bfec5ae889704b3885bc9fceb922ea9f90d936f
 DIST gentoo-kernel-5.10.54-1.x86.xpak 57217543 BLAKE2B e978d64011c71d186980da394914f0b2933a8154a64298c034337692ac0cf2d2093ded84a7ed574d239b3f176b951508a5ae4c248d5ab5fcce31a01f4f4c2c9c SHA512 c565daf009ccb06dc3b528e3e070464d17451c0d326b9354d103a0d97e679ef102c329da27165f050748c5813dd9bf7b3bee29e86824e97723b06d10d2f958ae
 DIST gentoo-kernel-5.10.55-1.amd64.xpak 65491981 BLAKE2B 73390f8750f11e309cf9f7b32a3f199e84717402459987af695441acbc53e2a19b126904ba2a09e7e2f51188f3b391e2f623dc338473c79baf8ef570c06e3b8d SHA512 a3c1c3e5514c0ffeda250023ad01a384449c78335ec82de2f4d67bd0913a567253ee4fd3819bbc2e82cb3575b980e9157263a2188532ea16ac5bfcbff65e37ce
+DIST gentoo-kernel-5.10.55-1.arm64.xpak 61167016 BLAKE2B 1de73432ca09ac34c84f621d3a14a4c3ef3b8e26dc3f930fff9c569f0b6c6afd44c00f1d7b41f0ddcca15c421532f53256740f12de3ad2305306d5c8181e1221 SHA512 da8952228418f8acdab8f136ebe181a201eef8b0d594645469af73d9b85a9bc297d83ea9a15c32a0b63fc3850b006091ace3ee21dab15c9104755c16dc8c95a6
 DIST gentoo-kernel-5.10.55-1.x86.xpak 57214089 BLAKE2B 6a411b8e89fa877a0f091e8a1c83896208f96e980ca00f6e73f835fe3258a58b62814e114e6728a63ba8d1679de22b7c10c0920db40ec5fd7ec73f3047667ec5 SHA512 6c762a018aa48d7c687c696ce6bf8786801e4b870812f908e1bd15a742aaf098e22b802061c150e62cb0b06e473e99f720444657b984b8f6069e037823522794
 DIST gentoo-kernel-5.12.19-1.amd64.xpak 66346655 BLAKE2B a03cbcdcd1a90d48d7e11e988d03efa43980f4d5d8af4b74e4c81f195faa01803af45fb38f7dc1f5af7e9b5338a53bc6f34837c37f7e853c088ec6c1dc084e44 SHA512 3d7f78c488ecee2532f8a8ad61e3aa0f5e238e4cd520d29288715a3dc5c488670d7378f3dc5bc110252dff10108dfbda27a54722c6b044151999428d002b34e1
 DIST gentoo-kernel-5.12.19-1.arm64.xpak 60043529 BLAKE2B 8746081847a39e1847b8e9f35fcd68565370b116d6418edf803c4cdca9d750ac8ada58c4a7fd377480a1c75b3c805864d419c02ee21675bc77ac195731385a18 SHA512 d1a8a9210a1ab3d3c1894be1fe524e64b859b0a02763feacfed1a24655540ade6c28af751b23e924fcc04fb9abd56e84c43d634ad80bbb4d5de79ed533b5ea50

diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.55-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.55-r1.ebuild
new file mode 100644
index 00000000000..9f8ae493e21
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.55-r1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 6 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}