[gentoo-commits] gentoo-x86 commit in dev-python/pypy: pypy-1.7-r1.ebuild ChangeLog

[Mike Gilbert (floppym)]

floppym     12/01/30 15:50:35

  Modified:             ChangeLog
  Added:                pypy-1.7-r1.ebuild
  Log:
  Apply patches from Arfrever to resolve bug 397523.
  
  (Portage version: 2.2.0_alpha84/cvs/Linux x86_64)

Revision  Changes    Path
1.8                  dev-python/pypy/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pypy/ChangeLog?rev=1.8&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pypy/ChangeLog?rev=1.8&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pypy/ChangeLog?r1=1.7&r2=1.8

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/pypy/ChangeLog,v
retrieving revision 1.7
retrieving revision 1.8
diff -u -r1.7 -r1.8
--- ChangeLog	15 Jan 2012 22:07:18 -0000	1.7
+++ ChangeLog	30 Jan 2012 15:50:35 -0000	1.8
@@ -1,6 +1,14 @@
 # ChangeLog for dev-python/pypy
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/pypy/ChangeLog,v 1.7 2012/01/15 22:07:18 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pypy/ChangeLog,v 1.8 2012/01/30 15:50:35 floppym Exp $
+
+*pypy-1.7-r1 (30 Jan 2012)
+
+  30 Jan 2012; Mike Gilbert <floppym@g.o>
+  +files/pypy-1.7-distutils-fix_handling_of_executables_and_flags.patch, +files/
+  pypy-1.7-distutils.unixccompiler.UnixCCompiler.runtime_library_dir_option.patc
+  h, +pypy-1.7-r1.ebuild:
+  Apply patches from Arfrever to resolve bug 397523.
 
   15 Jan 2012; Markos Chandras <hwoarang@g.o> pypy-1.7.ebuild:
   Don't call use() in global scope. Patch by Arfrever.



1.1                  dev-python/pypy/pypy-1.7-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pypy/pypy-1.7-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pypy/pypy-1.7-r1.ebuild?rev=1.1&content-type=text/plain

Index: pypy-1.7-r1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/pypy/pypy-1.7-r1.ebuild,v 1.1 2012/01/30 15:50:35 floppym Exp $

EAPI="4"

inherit eutils toolchain-funcs check-reqs python versionator

DESCRIPTION="PyPy is a fast, compliant alternative implementation of the Python language"
HOMEPAGE="http://pypy.org/"
SRC_URI="https://bitbucket.org/pypy/pypy/get/release-${PV}.tar.bz2"
SLOTVER=$(get_version_component_range 1-2 ${PV})

LICENSE="MIT"
SLOT="${SLOTVER}"
PYTHON_ABI="2.7-pypy-${SLOTVER}"
KEYWORDS="~amd64 ~x86"
IUSE="doc examples +jit sandbox test bzip2 ncurses xml ssl"

RDEPEND=">=sys-libs/zlib-1.1.3
		virtual/libffi
		virtual/libintl
		bzip2? ( app-arch/bzip2 )
		ncurses? ( sys-libs/ncurses )
		xml? ( dev-libs/expat )
		ssl? ( dev-libs/openssl )"
DEPEND="${RDEPEND}"
PDEPEND="app-admin/python-updater"

S="${WORKDIR}/${PN}-pypy-release-${PV}"

DOC="README LICENSE"

pkg_pretend() {
	CHECKREQS_MEMORY="1250M"
	use amd64 && CHECKREQS_MEMORY="2500M"
	check-reqs_pkg_pretend
}

src_prepare() {
	epatch "${FILESDIR}/${PV}-patches.patch"
	epatch "${FILESDIR}/${PV}-scripts-location.patch"
	epatch "${FILESDIR}/${P}-distutils.unixccompiler.UnixCCompiler.runtime_library_dir_option.patch"
	epatch "${FILESDIR}/${P}-distutils-fix_handling_of_executables_and_flags.patch"
}

src_compile() {

	if use jit; then
		conf="-Ojit"
	else
		conf="-O2"
	fi
	if use sandbox; then
		conf+=" --sandbox"
	fi

	conf+=" ./pypy/translator/goal/targetpypystandalone.py"
	# Avoid linking against libraries disabled by use flags
	optional_use=("bzip2" "ncurses" "xml" "ssl")
	optional_mod=("bz2" "_minimal_curses" "pyexpat" "_ssl")
	for ((i = 0; i < ${#optional_use[*]}; i++)); do
		if use ${optional_use[$i]};	then
			conf+=" --withmod-${optional_mod[$i]}"
		else
			conf+=" --withoutmod-${optional_mod[$i]}"
		fi
	done

	translate_cmd="$(PYTHON -2) ./pypy/translator/goal/translate.py $conf"
	echo ${_BOLD}"${translate_cmd}"${_NORMAL}
	${translate_cmd} || die "compile error"
}

src_install() {
	INSPATH="/usr/$(get_libdir)/pypy${SLOT}"
	insinto ${INSPATH}
	doins -r include lib_pypy lib-python pypy-c
	fperms a+x ${INSPATH}/pypy-c
	dosym ../$(get_libdir)/pypy${SLOT}/pypy-c /usr/bin/pypy-c${SLOT}
}

src_test() {
	$(PYTHON -2) ./pypy/test_all.py --pypy=./pypy-c lib-python
}