[gentoo-commits] gentoo-x86 commit in kde-plasma/kinfocenter: kinfocenter-5.3.1.ebuild metadata.xml ChangeLog

[Johannes Huber (johu)]

johu        15/05/31 22:06:17

  Added:                kinfocenter-5.3.1.ebuild metadata.xml ChangeLog
  Log:
  Initial commit for KDE Plasma 5. Imported from kde overlay. Ebuilds written by several people. Thank you all who worked on it in the overlay.
  
  (Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key 0xF3CFD2BD)

Revision  Changes    Path
1.1                  kde-plasma/kinfocenter/kinfocenter-5.3.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-plasma/kinfocenter/kinfocenter-5.3.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-plasma/kinfocenter/kinfocenter-5.3.1.ebuild?rev=1.1&content-type=text/plain

Index: kinfocenter-5.3.1.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/kde-plasma/kinfocenter/kinfocenter-5.3.1.ebuild,v 1.1 2015/05/31 22:06:17 johu Exp $

EAPI=5

KDE_HANDBOOK="true"
inherit kde5

DESCRIPTION="A utility that provides information about a computer system"
HOMEPAGE="http://www.kde.org/applications/system/kinfocenter/"
SRC_URI+=" https://www.gentoo.org/assets/img/logo/gentoo-3d-small.png -> glogo-small.png"
KEYWORDS="~amd64"
IUSE="egl gles ieee1394 +opengl +pci samba nfs wayland X"

REQUIRED_USE="egl? ( || ( gles opengl ) )"

COMMON_DEPEND="
	$(add_frameworks_dep kcmutils)
	$(add_frameworks_dep kcompletion)
	$(add_frameworks_dep kconfig)
	$(add_frameworks_dep kconfigwidgets)
	$(add_frameworks_dep kcoreaddons)
	$(add_frameworks_dep kdbusaddons)
	$(add_frameworks_dep kdelibs4support)
	$(add_frameworks_dep ki18n)
	$(add_frameworks_dep kiconthemes)
	$(add_frameworks_dep kio)
	$(add_frameworks_dep kservice)
	$(add_frameworks_dep kwidgetsaddons)
	$(add_frameworks_dep kxmlgui)
	$(add_frameworks_dep solid)
	dev-qt/qtgui:5[opengl?]
	dev-qt/qtwidgets:5
	gles? (
		dev-qt/qtgui:5[gles2]
		|| (
			media-libs/mesa[egl,gles1]
			media-libs/mesa[egl,gles2]
		)
	)
	ieee1394? ( sys-libs/libraw1394 )
	nfs? ( net-fs/nfs-utils )
	opengl? (
		virtual/glu
		virtual/opengl
	)
	pci? ( sys-apps/pciutils )
	samba? ( net-fs/samba[server(+)] )
	wayland? ( $(add_plasma_dep kwayland) )
	X? ( x11-libs/libX11 )
	!kde-base/kcontrol
	!kde-base/kinfocenter
	!kde-misc/about-distro
"
RDEPEND="${COMMON_DEPEND}
	$(add_plasma_dep kde-cli-tools)
"
DEPEND="${COMMON_DEPEND}
	$(add_frameworks_dep plasma)
"

src_configure() {
	local mycmakeargs=(
		$(cmake-utils_use_find_package egl EGL)
		$(cmake-utils_use_find_package gles OpenGLES)
		$(cmake-utils_use_find_package ieee1394 RAW1394)
		$(cmake-utils_use_find_package opengl OpenGL)
		$(cmake-utils_use_find_package pci PCIUTILS)
		$(cmake-utils_use_find_package wayland KF5Wayland)
		$(cmake-utils_use_find_package X X11)
	)

	kde5_src_configure
}

src_install() {
	kde5_src_install

	insinto /etc/xdg
	doins "${FILESDIR}"/kcm-about-distrorc

	insinto /usr/share/${PN}
	doins "${DISTDIR}"/glogo-small.png
}



1.1                  kde-plasma/kinfocenter/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-plasma/kinfocenter/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-plasma/kinfocenter/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
	<herd>kde</herd>
	<use>
		<flag name="egl">Retrieve information about OpenGL via EGL</flag>
		<flag name="gles">Show OpenGL ES information in kinfocenter</flag>
		<flag name="nfs">Show information about NFS mounts, shares and log entries</flag>
		<flag name="pci">Show advanced PCI information</flag>
		<flag name="samba">Show information about Samba mounts, shares and log entries</flag>
	</use>
</pkgmetadata>



1.1                  kde-plasma/kinfocenter/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-plasma/kinfocenter/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-plasma/kinfocenter/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for kde-plasma/kinfocenter
# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/kde-plasma/kinfocenter/ChangeLog,v 1.1 2015/05/31 22:06:17 johu Exp $

*kinfocenter-5.3.1 (31 May 2015)

  31 May 2015; Johannes Huber <johu@g.o> +files/kcm-about-distrorc,
  +kinfocenter-5.3.1.ebuild, +metadata.xml:
  Initial commit for KDE Plasma 5. Imported from kde overlay. Ebuilds written by
  several people. Thank you all who worked on it in the overlay.