[gentoo-commits] gentoo-x86 commit in net-misc/whois: ChangeLog whois-5.1.2.ebuild

[Tim Harder (radhermit)]

radhermit    14/05/03 08:33:11

  Modified:             ChangeLog
  Added:                whois-5.1.2.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

Revision  Changes    Path
1.200                net-misc/whois/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/whois/ChangeLog?rev=1.200&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/whois/ChangeLog?rev=1.200&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/whois/ChangeLog?r1=1.199&r2=1.200

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/whois/ChangeLog,v
retrieving revision 1.199
retrieving revision 1.200
diff -u -r1.199 -r1.200
--- ChangeLog	20 Jan 2014 13:59:15 -0000	1.199
+++ ChangeLog	3 May 2014 08:33:11 -0000	1.200
@@ -1,6 +1,11 @@
 # ChangeLog for net-misc/whois
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/whois/ChangeLog,v 1.199 2014/01/20 13:59:15 chainsaw Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/whois/ChangeLog,v 1.200 2014/05/03 08:33:11 radhermit Exp $
+
+*whois-5.1.2 (03 May 2014)
+
+  03 May 2014; Tim Harder <radhermit@g.o> +whois-5.1.2.ebuild:
+  Version bump.
 
 *whois-5.1.1 (20 Jan 2014)
 



1.1                  net-misc/whois/whois-5.1.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/whois/whois-5.1.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/whois/whois-5.1.2.ebuild?rev=1.1&content-type=text/plain

Index: whois-5.1.2.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/whois/whois-5.1.2.ebuild,v 1.1 2014/05/03 08:33:11 radhermit Exp $

EAPI=4
inherit eutils toolchain-funcs

MY_P=${P/-/_}
DESCRIPTION="improved Whois Client"
HOMEPAGE="http://www.linux.it/~md/software/"
SRC_URI="mirror://debian/pool/main/w/whois/${MY_P}.tar.xz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux"
IUSE="iconv idn nls"
RESTRICT="test" #59327

RDEPEND="iconv? ( virtual/libiconv )
	idn? ( net-dns/libidn )
	nls? ( virtual/libintl )"
DEPEND="${RDEPEND}
	app-arch/xz-utils
	>=dev-lang/perl-5
	nls? ( sys-devel/gettext )"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-4.7.2-config-file.patch

	if use nls ; then
		sed -i -e 's:#\(.*pos\):\1:' Makefile || die
	else
		sed -i -e '/ENABLE_NLS/s:define:undef:' config.h || die

		# don't generate po files when nls is disabled (bug #419889)
		sed -i -e '/^all:/s/ pos//' \
			-e '/^install:/s/ install-pos//' Makefile || die
	fi
}

src_configure() { :;} # expected no-op

src_compile() {
	unset HAVE_ICONV HAVE_LIBIDN
	use iconv && export HAVE_ICONV=1
	use idn && export HAVE_LIBIDN=1
	tc-export CC
	emake CFLAGS="${CFLAGS} ${CPPFLAGS}"
}

src_install() {
	emake BASEDIR="${ED}" prefix=/usr install
	insinto /etc
	doins whois.conf
	dodoc README debian/changelog

	if [[ ${USERLAND} != "GNU" ]]; then
		mv "${ED}"/usr/share/man/man1/{whois,mdwhois}.1 || die
		mv "${ED}"/usr/bin/{whois,mdwhois} || die
	fi
}