[gentoo-commits] gentoo-x86 commit in media-libs/gstreamer: ChangeLog gstreamer-0.10.20.ebuild

[Samuli Suominen (drac)]

drac        08/06/29 14:43:26

  Modified:             ChangeLog
  Added:                gstreamer-0.10.20.ebuild
  Log:
  Version bump.
  (Portage version: 2.2_rc1/cvs/Linux 2.6.26-rc3 x86_64)

Revision  Changes    Path
1.204                media-libs/gstreamer/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/gstreamer/ChangeLog?rev=1.204&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/gstreamer/ChangeLog?rev=1.204&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/gstreamer/ChangeLog?r1=1.203&r2=1.204

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/gstreamer/ChangeLog,v
retrieving revision 1.203
retrieving revision 1.204
diff -u -r1.203 -r1.204
--- ChangeLog	14 Apr 2008 19:10:41 -0000	1.203
+++ ChangeLog	29 Jun 2008 14:43:26 -0000	1.204
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/gstreamer
 # Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/gstreamer/ChangeLog,v 1.203 2008/04/14 19:10:41 fmccor Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/gstreamer/ChangeLog,v 1.204 2008/06/29 14:43:26 drac Exp $
+
+*gstreamer-0.10.20 (29 Jun 2008)
+
+  29 Jun 2008; Samuli Suominen <drac@g.o> +gstreamer-0.10.20.ebuild:
+  Version bump.
 
   14 Apr 2008; Ferris McCormick <fmccor@g.o>
   gstreamer-0.10.17.ebuild:



1.1                  media-libs/gstreamer/gstreamer-0.10.20.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/gstreamer/gstreamer-0.10.20.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/gstreamer/gstreamer-0.10.20.ebuild?rev=1.1&content-type=text/plain

Index: gstreamer-0.10.20.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/gstreamer/gstreamer-0.10.20.ebuild,v 1.1 2008/06/29 14:43:26 drac Exp $

inherit libtool

# Create a major/minor combo for our SLOT and executables suffix
PVP=(${PV//[-\._]/ })
PV_MAJ_MIN=${PVP[0]}.${PVP[1]}

DESCRIPTION="Streaming media framework"
HOMEPAGE="http://gstreamer.sourceforge.net"
SRC_URI="http://${PN}.freedesktop.org/src/${PN}/${P}.tar.bz2"

LICENSE="LGPL-2"
SLOT=${PV_MAJ_MIN}
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="debug nls test"

RDEPEND=">=dev-libs/glib-2.12
	>=dev-libs/libxml2-2.4.9
	>=dev-libs/check-0.9.2"
DEPEND="${RDEPEND}
	nls? ( >=sys-devel/gettext-0.11.5 )
	dev-util/pkgconfig
	!<media-libs/gst-plugins-ugly-0.10.6-r1"

src_unpack() {
	unpack ${A}
	cd "${S}"
	# Needed for sane .so versioning on Gentoo/FreeBSD
	elibtoolize
}

src_compile() {
	econf --disable-dependency-tracking \
		--with-package-name="Gentoo GStreamer ebuild" \
		--with-package-origin="http://www.gentoo.org" \
		$(use_enable test tests) \
		$(use_enable debug) \
		$(use_enable nls)

	emake || die "emake failed."
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed."
	dodoc AUTHORS ChangeLog NEWS README RELEASE

	# Remove unversioned binaries to allow SLOT installations in future.
	cd "${D}"/usr/bin
	local gst_bins
	for gst_bins in $(ls *-${PV_MAJ_MIN}) ; do
		rm ${gst_bins/-${PV_MAJ_MIN}/}
		einfo "Removed ${gst_bins/-${PV_MAJ_MIN}/}"
	done
}



-- 
gentoo-commits@l.g.o mailing list