[gentoo-commits] gentoo-x86 commit in sys-libs/slang: ChangeLog slang-2.1.2.ebuild

[Matsuu Takuto (matsuu)]

matsuu      07/09/18 16:47:17

  Modified:             ChangeLog
  Added:                slang-2.1.2.ebuild
  Log:
  Version bumped, bug #182339.
  (Portage version: 2.1.3.9)

Revision  Changes    Path
1.62                 sys-libs/slang/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/slang/ChangeLog?rev=1.62&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/slang/ChangeLog?rev=1.62&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/slang/ChangeLog?r1=1.61&r2=1.62

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-libs/slang/ChangeLog,v
retrieving revision 1.61
retrieving revision 1.62
diff -u -r1.61 -r1.62
--- ChangeLog	30 Aug 2007 12:45:53 -0000	1.61
+++ ChangeLog	18 Sep 2007 16:47:16 -0000	1.62
@@ -1,6 +1,12 @@
 # ChangeLog for sys-libs/slang
 # Copyright 2002-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-libs/slang/ChangeLog,v 1.61 2007/08/30 12:45:53 phreak Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-libs/slang/ChangeLog,v 1.62 2007/09/18 16:47:16 matsuu Exp $
+
+*slang-2.1.2 (18 Sep 2007)
+
+  18 Sep 2007; MATSUU Takuto <matsuu@g.o>
+  +files/slang-2.1.2-slsh-libs.patch, +slang-2.1.2.ebuild:
+  Version bumped, bug #182339.
 
   30 Aug 2007; Christian Heim <phreak@g.o> metadata.xml:
   Removing liquidx from metadata due to his retirement (see #171155 for



1.1                  sys-libs/slang/slang-2.1.2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/slang/slang-2.1.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/slang/slang-2.1.2.ebuild?rev=1.1&content-type=text/plain

Index: slang-2.1.2.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-libs/slang/slang-2.1.2.ebuild,v 1.1 2007/09/18 16:47:16 matsuu Exp $

inherit eutils

DESCRIPTION="Console display library used by most text viewer"
HOMEPAGE="http://www.s-lang.org/"
SRC_URI="ftp://space.mit.edu/pub/davis/slang/v${PV%.*}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="2"
KEYWORDS="~amd64 ~x86"
# USE=cjk is broken; see http://www.jedsoft.org/pipermail/slang-users_jedsoft.org/2006/000399.html
IUSE="pcre png"

DEPEND=">=sys-libs/ncurses-5.2-r2
	pcre? ( dev-libs/libpcre )
	png? ( media-libs/libpng )"

MAKEOPTS="${MAKEOPTS} -j1"

src_unpack() {
	unpack ${A}
	cd "${S}"

	epatch "${FILESDIR}/${P}-slsh-libs.patch"

	sed -i -e '/^THIS_LIB/s/slang/slang-2/' src/Makefile.in || die

	grep -rlZ -- '-lslang\>' "${S}" | xargs -0 sed -i -e 's:-lslang:-lslang-2:g'
}

src_compile() {
	econf \
		$(use_with pcre) \
		$(use_with png) || die "econf failed"
	emake all || die "make all failed"
	cd slsh
	emake slsh || die "make slsh failed"
}

src_install() {
	emake DESTDIR="${D}" install install-static || die "make install failed"

	# Move headers around
	dodir /usr/include/slang-2
	mv "${D}"/usr/include/*.h "${D}/usr/include/slang-2"

	rm -rf "${D}/usr/share/doc/{slang,slsh}"

	dodoc NEWS README *.txt
	dodoc doc/*.txt doc/internal/*.txt doc/text/*.txt
	dohtml doc/slangdoc.html
	dohtml slsh/doc/html/*.html
}

pkg_postinst() {
	elog "For compatibility reason slang 2.x is installed in Gentoo as libslang-2."
	elog "This has the unfortunate consequence that if you want to build something"
	elog "from sources that uses slang 2.x, you need to change the linking library"
	elog "to -lslang-2 instead of simply -lslang."
	elog "We're sorry for the inconvenience, but it's to overcome an otherwise"
	elog "problematic situation."
}



-- 
gentoo-commits@g.o mailing list