[gentoo-commits] gentoo-x86 commit in sys-apps/moreutils: ChangeLog moreutils-0.47.ebuild

[Tim Harder (radhermit)]

radhermit    12/06/30 05:11:15

  Modified:             ChangeLog
  Added:                moreutils-0.47.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha114/cvs/Linux x86_64)

Revision  Changes    Path
1.43                 sys-apps/moreutils/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/moreutils/ChangeLog?rev=1.43&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/moreutils/ChangeLog?rev=1.43&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/moreutils/ChangeLog?r1=1.42&r2=1.43

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/moreutils/ChangeLog,v
retrieving revision 1.42
retrieving revision 1.43
diff -u -r1.42 -r1.43
--- ChangeLog	15 Apr 2012 21:23:44 -0000	1.42
+++ ChangeLog	30 Jun 2012 05:11:15 -0000	1.43
@@ -1,6 +1,12 @@
 # ChangeLog for sys-apps/moreutils
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/moreutils/ChangeLog,v 1.42 2012/04/15 21:23:44 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/moreutils/ChangeLog,v 1.43 2012/06/30 05:11:15 radhermit Exp $
+
+*moreutils-0.47 (30 Jun 2012)
+
+  30 Jun 2012; Tim Harder <radhermit@g.o> +moreutils-0.47.ebuild,
+  +files/moreutils-0.47-dtd-path.patch:
+  Version bump.
 
 *moreutils-0.46 (15 Apr 2012)
 



1.1                  sys-apps/moreutils/moreutils-0.47.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/moreutils/moreutils-0.47.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/moreutils/moreutils-0.47.ebuild?rev=1.1&content-type=text/plain

Index: moreutils-0.47.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/moreutils/moreutils-0.47.ebuild,v 1.1 2012/06/30 05:11:15 radhermit Exp $

EAPI=4
inherit eutils toolchain-funcs prefix

DESCRIPTION="a growing collection of the unix tools that nobody thought to write thirty years ago"
HOMEPAGE="http://kitenet.net/~joey/code/moreutils/"
SRC_URI="mirror://debian/pool/main/${PN:0:1}/${PN}/${PN}_${PV}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~hppa ~ppc ~ppc64 ~x86 ~x86-linux"
IUSE="+doc +perl"

RDEPEND="
	perl? (
		dev-lang/perl
		dev-perl/IPC-Run
		dev-perl/Time-Duration
		dev-perl/TimeDate
	)"
DEPEND="
	doc? (
		dev-lang/perl
		>=app-text/docbook2X-0.8.8-r2
		app-text/docbook-xml-dtd:4.4
	)"

S=${WORKDIR}/${PN}

src_prepare() {
	epatch "${FILESDIR}"/${PN}-0.47-dtd-path.patch
	eprefixify *.docbook

	# Don't build manpages
	if ! use doc ; then
		sed -i -e '/^all:/s/$(MANS)//' -e '/man1/d' Makefile || die
	fi

	# Don't install perl scripts
	if ! use perl ; then
		sed -i -e '/PERLSCRIPTS/d' Makefile || die
	fi
}

src_compile() {
	tc-export CC
	emake CFLAGS="${CFLAGS}" DOCBOOK2XMAN=docbook2man.pl PREFIX="${EPREFIX}/usr"
}

src_install() {
	emake DESTDIR="${D}" PREFIX="${EPREFIX}/usr" INSTALL_BIN=install install

	# sys-process is more advanced than parallel from moreutils, rename it
	if use doc; then
		mv -vf "${ED}"usr/share/man/man1/{,${PN}_}parallel.1 || die
	fi
	mv -vf "${ED}"usr/bin/{,${PN}_}parallel || die
}