[gentoo-commits] repo/gentoo:master commit in: dev-util/cflow/

[John Helmert III]

commit:     3d89d0c81148fbcc32c51d084713bd5e731c418f
Author:     John Helmert III <ajak <AT> gentoo <DOT> org>
AuthorDate: Thu Dec 30 17:51:18 2021 +0000
Commit:     John Helmert III <ajak <AT> gentoo <DOT> org>
CommitDate: Thu Dec 30 17:52:31 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3d89d0c8

dev-util/cflow: add 1.7

Bug: https://bugs.gentoo.org/711196
Signed-off-by: John Helmert III <ajak <AT> gentoo.org>

 dev-util/cflow/Manifest         |  1 +
 dev-util/cflow/cflow-1.7.ebuild | 56 +++++++++++++++++++++++++++++++++++++++++
 2 files changed, 57 insertions(+)

diff --git a/dev-util/cflow/Manifest b/dev-util/cflow/Manifest
index cff328000177..1d87b16c1c76 100644
--- a/dev-util/cflow/Manifest
+++ b/dev-util/cflow/Manifest
@@ -1 +1,2 @@
 DIST cflow-1.6.tar.bz2 836405 BLAKE2B 6cfbfa9f4bb503616cb0bf465e70d9951eb52e65addff16ef2a1ee79b1a115e46ac4747510dd1edf5ec1d96c29540152a6fb2227715cef9e19acbb895f5cda2e SHA512 eb26695b479205ea391623d78ee537cac084a168a52c2bf4f2e4206d7a3f813e6e3f92684903673af905172c3b1df3f8ab1ccb7986bd61ed53feee34fb3fd7c6
+DIST cflow-1.7.tar.bz2 916685 BLAKE2B 0ab6e17e67765335587b9adbbb074b4461b5082fa68095fdcd0b8c96f597f86c4bde35980efc91e5f187f1eef3f7d656eba53d6420533904a51e5c1f4830cd46 SHA512 ec7361b12099e8024f8420469eeddfa068014e8c7bc892ff5780396ce0baa1f915cc57d304f7e228f010379e08b9bd1ce31c9b50b619bb469081a5ea3d2bd9f4

diff --git a/dev-util/cflow/cflow-1.7.ebuild b/dev-util/cflow/cflow-1.7.ebuild
new file mode 100644
index 000000000000..88ed1770ffc6
--- /dev/null
+++ b/dev-util/cflow/cflow-1.7.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit elisp-common
+
+DESCRIPTION="C function call hierarchy analyzer"
+HOMEPAGE="https://www.gnu.org/software/cflow/"
+SRC_URI="http://ftp.gnu.org/gnu/cflow/${P}.tar.bz2"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="debug emacs nls"
+
+RDEPEND="emacs? ( >=app-editors/emacs-23.1:* )
+	nls? ( virtual/libintl virtual/libiconv )"
+BDEPEND="${RDEPEND}
+	sys-devel/flex
+	nls? ( sys-devel/gettext )"
+
+SITEFILE="50${PN}-gentoo.el"
+
+src_configure() {
+	econf \
+		$(use_enable nls) \
+		$(use_enable debug) \
+		EMACS=no
+}
+
+src_compile() {
+	default
+
+	if use emacs; then
+		elisp-compile elisp/cflow-mode.el
+	fi
+}
+
+src_install() {
+	default
+	doinfo doc/cflow.info
+
+	if use emacs; then
+		elisp-install ${PN} elisp/cflow-mode.{el,elc}
+		elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+	fi
+}
+
+pkg_postinst() {
+	use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}