[gentoo-commits] gentoo-x86 commit in media-libs/leptonica: leptonica-1.72-r1.ebuild ChangeLog leptonica-1.72.ebuild

[James Le Cuirot (chewi)]

chewi       15/05/02 15:59:06

  Modified:             ChangeLog
  Added:                leptonica-1.72-r1.ebuild
  Removed:              leptonica-1.72.ebuild
  Log:
  Add SLOT restrictions to some dependencies following an enlightening
  discussion on IRC.
  
  (Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key 9C6D7DE4)

Revision  Changes    Path
1.37                 media-libs/leptonica/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/leptonica/ChangeLog?rev=1.37&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/leptonica/ChangeLog?rev=1.37&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/leptonica/ChangeLog?r1=1.36&r2=1.37

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/leptonica/ChangeLog,v
retrieving revision 1.36
retrieving revision 1.37
diff -u -r1.36 -r1.37
--- ChangeLog	1 May 2015 23:24:02 -0000	1.36
+++ ChangeLog	2 May 2015 15:59:06 -0000	1.37
@@ -1,6 +1,13 @@
 # ChangeLog for media-libs/leptonica
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/leptonica/ChangeLog,v 1.36 2015/05/01 23:24:02 chewi Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/leptonica/ChangeLog,v 1.37 2015/05/02 15:59:06 chewi Exp $
+
+*leptonica-1.72-r1 (02 May 2015)
+
+  02 May 2015; James Le Cuirot <chewi@g.o> +leptonica-1.72-r1.ebuild,
+  -leptonica-1.72.ebuild:
+  Add SLOT restrictions to some dependencies following an enlightening
+  discussion on IRC.
 
 *leptonica-1.72 (01 May 2015)
 



1.1                  media-libs/leptonica/leptonica-1.72-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/leptonica/leptonica-1.72-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/leptonica/leptonica-1.72-r1.ebuild?rev=1.1&content-type=text/plain

Index: leptonica-1.72-r1.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/leptonica/leptonica-1.72-r1.ebuild,v 1.1 2015/05/02 15:59:06 chewi Exp $

EAPI=5

inherit autotools-multilib

DESCRIPTION="C library for image processing and analysis"
HOMEPAGE="http://code.google.com/p/leptonica/"
SRC_URI="http://www.leptonica.com/source/${P}.tar.gz"

LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~mips ~ppc ~ppc64 ~sparc ~x86"
IUSE="gif jpeg jpeg2k png static-libs test tiff utils webp zlib"

# N.B. Tests need some features enabled:
REQUIRED_USE="test? ( jpeg png tiff )"

DEPEND="gif? ( media-libs/giflib:=[${MULTILIB_USEDEP}] )
	jpeg? ( virtual/jpeg:0=[${MULTILIB_USEDEP}] )
	jpeg2k? ( media-libs/openjpeg:2=[${MULTILIB_USEDEP}] )
	png? ( media-libs/libpng:0=[${MULTILIB_USEDEP}]
		   sys-libs/zlib:=[${MULTILIB_USEDEP}] )
	tiff? ( media-libs/tiff:0=[${MULTILIB_USEDEP}] )
	webp? ( media-libs/libwebp:=[${MULTILIB_USEDEP}] )
	zlib? ( sys-libs/zlib:=[${MULTILIB_USEDEP}] )"
RDEPEND="${DEPEND}"

DOCS=( README version-notes )

src_prepare() {
	# unhtmlize docs
	local X
	for X in ${DOCS[@]}; do
		awk '/<\/pre>/{s--} {if (s) print $0} /<pre>/{s++}' \
			"${X}.html" > "${X}" || die 'awk failed'
		rm -f -- "${X}.html"
	done

	# Don't spam /tmp.
	sed -i -r 's/(#define\s+ADD_LEPTONICA_SUBDIR\s+)0/\11/' \
		src/environ.h || die

	autotools-utils_src_prepare
}

multilib_src_configure() {
	local myeconfargs=(
		$(use_with gif giflib)
		$(use_with jpeg)
		$(use_with jpeg2k libopenjpeg)
		$(use_with png libpng)
		$(use_with tiff libtiff)
		$(use_with webp libwebp)
		$(use_with zlib)
		$(use_enable static-libs static)
		$(multilib_native_use_enable utils programs)
	)
	autotools-utils_src_configure
}