Get Gentoo!
gentoo.org sites
gentoo.org Wiki Bugs Forums Packages
Planet Archives Sources
Infra Status

Gentoo Archives: gentoo-commits

From: "Alexis Ballier (aballier)" <aballier@g.o>
To: gentoo-commits@l.g.o
Subject: [gentoo-commits] gentoo-x86 commit in media-video/vlc: ChangeLog vlc-2.0.2.ebuild
Date: Sat, 30 Jun 2012 12:26:40
Message-Id: 20120630122625.19DE02004B@flycatcher.gentoo.org
1 aballier 12/06/30 12:26:25
2
3 Modified: ChangeLog
4 Added: vlc-2.0.2.ebuild
5 Log:
6 version bump
7
8 (Portage version: 2.2.0_alpha114/cvs/Linux x86_64)
9
10 Revision Changes Path
11 1.811 media-video/vlc/ChangeLog
12
13 file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/vlc/ChangeLog?rev=1.811&view=markup
14 plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/vlc/ChangeLog?rev=1.811&content-type=text/plain
15 diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/vlc/ChangeLog?r1=1.810&r2=1.811
16
17 Index: ChangeLog
18 ===================================================================
19 RCS file: /var/cvsroot/gentoo-x86/media-video/vlc/ChangeLog,v
20 retrieving revision 1.810
21 retrieving revision 1.811
22 diff -u -r1.810 -r1.811
23 --- ChangeLog 17 Jun 2012 04:39:22 -0000 1.810
24 +++ ChangeLog 30 Jun 2012 12:26:24 -0000 1.811
25 @@ -1,6 +1,11 @@
26 # ChangeLog for media-video/vlc
27 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
28 -# $Header: /var/cvsroot/gentoo-x86/media-video/vlc/ChangeLog,v 1.810 2012/06/17 04:39:22 yngwin Exp $
29 +# $Header: /var/cvsroot/gentoo-x86/media-video/vlc/ChangeLog,v 1.811 2012/06/30 12:26:24 aballier Exp $
30 +
31 +*vlc-2.0.2 (30 Jun 2012)
32 +
33 + 30 Jun 2012; Alexis Ballier <aballier@g.o> +vlc-2.0.2.ebuild:
34 + version bump
35
36 17 Jun 2012; Ben de Groot <yngwin@g.o> metadata.xml:
37 Remove libass useflag description, as it is now a global useflag
38
39
40
41 1.1 media-video/vlc/vlc-2.0.2.ebuild
42
43 file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/vlc/vlc-2.0.2.ebuild?rev=1.1&view=markup
44 plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/vlc/vlc-2.0.2.ebuild?rev=1.1&content-type=text/plain
45
46 Index: vlc-2.0.2.ebuild
47 ===================================================================
48 # Copyright 1999-2012 Gentoo Foundation
49 # Distributed under the terms of the GNU General Public License v2
50 # $Header: /var/cvsroot/gentoo-x86/media-video/vlc/vlc-2.0.2.ebuild,v 1.1 2012/06/30 12:26:24 aballier Exp $
51
52 EAPI="4"
53
54 SCM=""
55 if [ "${PV%9999}" != "${PV}" ] ; then
56 SCM=git-2
57 EGIT_BOOTSTRAP="bootstrap"
58 if [ "${PV%.9999}" != "${PV}" ] ; then
59 EGIT_REPO_URI="git://git.videolan.org/vlc/vlc-${PV%.9999}.git"
60 else
61 EGIT_REPO_URI="git://git.videolan.org/vlc.git"
62 fi
63 fi
64
65 inherit eutils multilib autotools toolchain-funcs flag-o-matic ${SCM}
66
67 MY_PV="${PV/_/-}"
68 MY_PV="${MY_PV/-beta/-test}"
69 MY_P="${PN}-${MY_PV}"
70
71 PATCHLEVEL="101"
72 DESCRIPTION="VLC media player - Video player and streamer"
73 HOMEPAGE="http://www.videolan.org/vlc/"
74 if [ "${PV%9999}" != "${PV}" ] ; then # Live ebuild
75 SRC_URI=""
76 elif [[ "${MY_P}" == "${P}" ]]; then
77 SRC_URI="http://download.videolan.org/pub/videolan/${PN}/${PV}/${P}.tar.xz"
78 else
79 SRC_URI="http://download.videolan.org/pub/videolan/testing/${MY_P}/${MY_P}.tar.xz"
80 fi
81
82 SRC_URI="${SRC_URI}
83 mirror://gentoo/${PN}-patches-${PATCHLEVEL}.tar.bz2"
84
85 LICENSE="LGPL-2.1 GPL-2"
86 SLOT="0"
87
88 if [ "${PV%9999}" = "${PV}" ] ; then
89 KEYWORDS="~alpha ~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
90 else
91 KEYWORDS=""
92 fi
93 IUSE="a52 aac aalib alsa altivec atmo +audioqueue avahi +avcodec
94 +avformat bidi bluray cdda cddb dbus dc1394 debug dirac direct2d
95 directfb directx dshow dts dvb +dvbpsi dvd dxva2 elibc_glibc egl +encode
96 fbosd fluidsynth +ffmpeg flac fontconfig +gcrypt gme gnome gnutls
97 growl httpd ieee1394 ios-vout jack kate kde libass libcaca libnotify
98 libproxy libsamplerate libtiger linsys libtar lirc live lua +macosx
99 +macosx-audio +macosx-dialog-provider +macosx-eyetv +macosx-quartztext
100 +macosx-qtkit +macosx-vout matroska media-library mmx modplug mp3 mpeg
101 mtp musepack ncurses neon ogg omxil opengl optimisememory oss png portaudio
102 +postproc projectm pulseaudio pvr +qt4 rtsp run-as-root samba schroedinger
103 sdl sdl-image shine shout sid skins speex sqlite sse svg +swscale switcher
104 taglib theora truetype twolame udev upnp vaapi v4l vcdx vlm vorbis waveout
105 win32codecs wingdi wma-fixed +X x264 +xcb xml xosd xv zvbi"
106
107 RDEPEND="
108 >=sys-libs/zlib-1.2.5.1-r2[minizip]
109 a52? ( >=media-libs/a52dec-0.7.4-r3 )
110 aalib? ( media-libs/aalib )
111 aac? ( >=media-libs/faad2-2.6.1 )
112 alsa? ( >=media-libs/alsa-lib-1.0.23 )
113 avahi? ( >=net-dns/avahi-0.6[dbus] )
114 avcodec? ( virtual/ffmpeg )
115 avformat? ( virtual/ffmpeg )
116 bidi? ( >=dev-libs/fribidi-0.10.4 )
117 bluray? ( >=media-libs/libbluray-0.2.1 )
118 cddb? ( >=media-libs/libcddb-1.2.0 )
119 dbus? ( >=sys-apps/dbus-1.0.2 )
120 dc1394? ( >=sys-libs/libraw1394-2.0.1 >=media-libs/libdc1394-2.0.2 )
121 dirac? ( >=media-video/dirac-0.10.0 )
122 directfb? ( dev-libs/DirectFB sys-libs/zlib )
123 dts? ( media-libs/libdca )
124 dvbpsi? ( >=media-libs/libdvbpsi-0.2.1 )
125 dvd? ( media-libs/libdvdread >=media-libs/libdvdnav-0.1.9 )
126 egl? ( virtual/opengl )
127 elibc_glibc? ( >=sys-libs/glibc-2.8 )
128 flac? ( media-libs/libogg >=media-libs/flac-1.1.2 )
129 fluidsynth? ( media-sound/fluidsynth )
130 fontconfig? ( media-libs/fontconfig )
131 gcrypt? ( >=dev-libs/libgcrypt-1.2.0 )
132 gme? ( media-libs/game-music-emu )
133 gnome? ( gnome-base/gnome-vfs )
134 gnutls? ( >=net-libs/gnutls-2.0.0 )
135 ieee1394? ( >=sys-libs/libraw1394-2.0.1 >=sys-libs/libavc1394-0.5.3 )
136 ios-vout? ( virtual/opengl )
137 jack? ( >=media-sound/jack-audio-connection-kit-0.99.0-r1 )
138 kate? ( >=media-libs/libkate-0.1.1 )
139 libass? ( >=media-libs/libass-0.9.8 media-libs/fontconfig )
140 libcaca? ( >=media-libs/libcaca-0.99_beta14 )
141 libnotify? ( x11-libs/libnotify x11-libs/gtk+:2 )
142 libproxy? ( net-libs/libproxy )
143 libsamplerate? ( media-libs/libsamplerate )
144 libtar? ( >=dev-libs/libtar-1.2.11-r3 )
145 libtiger? ( media-libs/libtiger )
146 linsys? ( >=media-libs/zvbi-0.2.28 )
147 lirc? ( app-misc/lirc )
148 live? ( >=media-plugins/live-2011.12.23 )
149 lua? ( >=dev-lang/lua-5.1 )
150 macosx-vout? ( virtual/opengl )
151 matroska? ( >=dev-libs/libebml-1.0.0 >=media-libs/libmatroska-1.0.0 )
152 modplug? ( >=media-libs/libmodplug-0.8.8.1 )
153 mp3? ( media-libs/libmad )
154 mpeg? ( >=media-libs/libmpeg2-0.3.2 )
155 mtp? ( >=media-libs/libmtp-1.0.0 )
156 musepack? ( >=media-sound/musepack-tools-444 )
157 ncurses? ( sys-libs/ncurses[unicode] )
158 ogg? ( media-libs/libogg )
159 opengl? ( virtual/opengl >=x11-libs/libX11-1.3.99.901 )
160 png? ( media-libs/libpng sys-libs/zlib )
161 portaudio? ( >=media-libs/portaudio-19_pre )
162 postproc? ( || ( media-video/ffmpeg media-libs/libpostproc ) )
163 projectm? ( media-libs/libprojectm )
164 pulseaudio? ( >=media-sound/pulseaudio-0.9.22 )
165 qt4? ( x11-libs/qt-gui:4 x11-libs/qt-core:4 )
166 samba? ( >=net-fs/samba-3.4.6[smbclient] )
167 schroedinger? ( >=media-libs/schroedinger-1.0.10 )
168 sdl? ( >=media-libs/libsdl-1.2.8
169 sdl-image? ( media-libs/sdl-image sys-libs/zlib ) )
170 shout? ( media-libs/libshout )
171 sid? ( media-libs/libsidplay:2 )
172 skins? ( x11-libs/libXext x11-libs/libXpm x11-libs/libXinerama )
173 speex? ( media-libs/speex )
174 sqlite? ( >=dev-db/sqlite-3.6.0:3 )
175 svg? ( >=gnome-base/librsvg-2.9.0 )
176 swscale? ( virtual/ffmpeg )
177 taglib? ( >=media-libs/taglib-1.5 sys-libs/zlib )
178 theora? ( >=media-libs/libtheora-1.0_beta3 )
179 truetype? ( media-libs/freetype virtual/ttf-fonts
180 !fontconfig? ( media-fonts/dejavu ) )
181 twolame? ( media-sound/twolame )
182 udev? ( >=sys-fs/udev-142 )
183 upnp? ( net-libs/libupnp )
184 v4l? ( media-libs/libv4l )
185 vaapi? ( x11-libs/libva )
186 vcdx? ( >=dev-libs/libcdio-0.78.2 >=media-video/vcdimager-0.7.22 )
187 vorbis? ( media-libs/libvorbis )
188 win32codecs? ( media-libs/win32codecs )
189 X? ( x11-libs/libX11 )
190 x264? ( >=media-libs/x264-0.0.20090923 )
191 xcb? ( >=x11-libs/libxcb-1.6 >=x11-libs/xcb-util-0.3.4 )
192 xml? ( dev-libs/libxml2 )
193 xosd? ( x11-libs/xosd )
194 zvbi? ( >=media-libs/zvbi-0.2.25 )
195 "
196
197 DEPEND="${RDEPEND}
198 alsa? ( >=media-sound/alsa-headers-1.0.23 )
199 fbosd? ( sys-kernel/linux-headers )
200 kde? ( >=kde-base/kdelibs-4 )
201 xcb? ( x11-proto/xproto )
202 app-arch/xz-utils
203 virtual/pkgconfig"
204
205 REQUIRED_USE="
206 aalib? ( X )
207 bidi? ( truetype )
208 cddb? ( cdda )
209 dvb? ( dvbpsi )
210 dxva2? ( avcodec )
211 egl? ( X )
212 avcodec? ( ffmpeg )
213 avformat? ( ffmpeg )
214 swscale? ( ffmpeg )
215 fontconfig? ( truetype )
216 gnutls? ( gcrypt )
217 libcaca? ( X )
218 libtar? ( skins )
219 libtiger? ( kate )
220 media-library? ( sqlite )
221 qt4? ( X )
222 sdl? ( X )
223 skins? ( truetype qt4 X )
224 switcher? ( avcodec )
225 vaapi? ( avcodec X )
226 vlm? ( encode )
227 xosd? ( X )
228 xv? ( xcb )
229 "
230
231 S="${WORKDIR}/${MY_P}"
232
233 src_unpack() {
234 unpack ${A}
235 if [ "${PV%9999}" != "${PV}" ] ; then
236 git-2_src_unpack
237 fi
238 }
239
240 src_prepare() {
241 # Make it build with libtool 1.5
242 rm -f m4/lt* m4/libtool.m4
243
244 EPATCH_SUFFIX="patch" epatch "${WORKDIR}/patches"
245 eautoreconf
246 }
247
248 src_configure() {
249 # needs libresid-builder from libsidplay:2 which is in another directory...
250 # FIXME!
251 use sid && append-ldflags "-L/usr/$(get_libdir)/sidplay/builders/"
252
253 econf \
254 --docdir=/usr/share/doc/${PF} \
255 $(use_enable a52) \
256 $(use_enable aalib aa) \
257 $(use_enable aac faad) \
258 $(use_enable alsa) \
259 $(use_enable altivec) \
260 $(use_enable atmo) \
261 $(use_enable audioqueue) \
262 $(use_enable avahi bonjour) \
263 $(use_enable avcodec) \
264 $(use_enable avformat) \
265 $(use_enable bidi fribidi) \
266 $(use_enable bluray) \
267 $(use_enable cdda vcd) \
268 $(use_enable cddb libcddb) \
269 $(use_enable dbus) $(use_enable dbus dbus-control) \
270 $(use_enable dirac) \
271 $(use_enable direct2d) \
272 $(use_enable directfb) \
273 $(use_enable directx) \
274 $(use_enable dc1394) \
275 $(use_enable debug) \
276 $(use_enable dshow) \
277 $(use_enable dts dca) \
278 $(use_enable dvbpsi) \
279 $(use_enable dvd dvdread) $(use_enable dvd dvdnav) \
280 $(use_enable dxva2) \
281 $(use_enable egl) \
282 $(use_enable encode sout) \
283 $(use_enable fbosd) \
284 $(use_enable flac) \
285 $(use_enable fluidsynth) \
286 $(use_enable fontconfig) \
287 $(use_enable gcrypt libgcrypt) \
288 $(use_enable gme) \
289 $(use_enable gnome gnomevfs) \
290 $(use_enable gnutls) \
291 $(use_enable growl) \
292 $(use_enable httpd) \
293 $(use_enable ieee1394 dv) \
294 $(use_enable ios-vout) \
295 $(use_enable jack) \
296 $(use_enable kate) \
297 $(use_with kde kde-solid) \
298 $(use_enable libass) \
299 $(use_enable libcaca caca) \
300 $(use_enable libnotify notify) \
301 $(use_enable libproxy) \
302 $(use_enable libsamplerate samplerate) \
303 $(use_enable libtar) \
304 $(use_enable libtiger tiger) \
305 $(use_enable linsys) \
306 $(use_enable lirc) \
307 $(use_enable live live555) \
308 $(use_enable lua) \
309 $(use_enable macosx-audio) \
310 $(use_enable macosx-dialog-provider) \
311 $(use_enable macosx-eyetv) \
312 $(use_enable macosx-qtkit) \
313 $(use_enable macosx-quartztext) \
314 $(use_enable macosx-vout) \
315 $(use_enable matroska mkv) \
316 $(use_enable media-library) \
317 $(use_enable mmx) \
318 $(use_enable modplug mod) \
319 $(use_enable mp3 mad) \
320 $(use_enable mpeg libmpeg2) \
321 $(use_enable mtp) \
322 $(use_enable musepack mpc) \
323 $(use_enable ncurses) \
324 $(use_enable neon) \
325 $(use_enable ogg) \
326 $(use_enable omxil) \
327 $(use_enable opengl glx) \
328 $(use_enable optimisememory optimize-memory) \
329 $(use_enable oss) \
330 $(use_enable png) \
331 $(use_enable portaudio) \
332 $(use_enable postproc) \
333 $(use_enable projectm) \
334 $(use_enable pulseaudio pulse) \
335 $(use_enable pvr) \
336 $(use_enable qt4) \
337 $(use_enable rtsp realrtsp) \
338 $(use_enable run-as-root) \
339 $(use_enable samba smb) \
340 $(use_enable schroedinger) \
341 $(use_enable sdl) \
342 $(use_enable sdl-image) \
343 $(use_enable shine) \
344 $(use_enable sid) \
345 $(use_enable shout) \
346 $(use_enable skins skins2) \
347 $(use_enable speex) \
348 $(use_enable sqlite) \
349 $(use_enable sse) \
350 $(use_enable svg) \
351 $(use_enable switcher) \
352 $(use_enable swscale) \
353 $(use_enable taglib) \
354 $(use_enable theora) \
355 $(use_enable truetype freetype) \
356 $(use_enable twolame) \
357 $(use_enable udev) \
358 $(use_enable upnp) \
359 $(use_enable v4l v4l2) \
360 $(use_enable vaapi libva) \
361 $(use_enable vcdx) \
362 $(use_enable vlm) \
363 $(use_enable vorbis) \
364 $(use_enable waveout) \
365 $(use_enable win32codecs loader) \
366 $(use_enable wingdi) \
367 $(use_enable wma-fixed) \
368 $(use_with X x) \
369 $(use_enable x264) \
370 $(use_enable xcb) \
371 $(use_enable xml libxml2) \
372 $(use_enable xosd) \
373 $(use_enable xv xvideo) \
374 $(use_enable zvbi) $(use_enable !zvbi telx) \
375 --disable-optimizations \
376 --without-tuning \
377 --enable-fast-install
378 }
379
380 src_install() {
381 emake DESTDIR="${D}" install || die "make install failed"
382
383 dodoc AUTHORS THANKS NEWS README \
384 doc/fortunes.txt doc/intf-vcd.txt
385
386 # Punt useless libtool's .la files
387 find "${D}" -name '*.la' -delete
388 }
389
390 pkg_postinst() {
391 if [ "$ROOT" = "/" ] && [ -x "/usr/$(get_libdir)/vlc/vlc-cache-gen" ] ; then
392 einfo "Running /usr/$(get_libdir)/vlc/vlc-cache-gen on /usr/$(get_libdir)/vlc/plugins/"
393 "/usr/$(get_libdir)/vlc/vlc-cache-gen" -f "/usr/$(get_libdir)/vlc/plugins/"
394 else
395 ewarn "We cannot run vlc-cache-gen (most likely ROOT!=/)"
396 ewarn "Please run /usr/$(get_libdir)/vlc/vlc-cache-gen manually"
397 ewarn "If you do not do it, vlc will take a long time to load."
398 fi
399 }
Report Message
Find on MARC Find on Google Groups