[gentoo-commits] gentoo-x86 commit in media-sound/pulseaudio: pulseaudio-9999.ebuild pulseaudio-4.0-r1.ebuild ChangeLog

[Michal Gorny (mgorny)]

mgorny      13/11/30 16:12:45

  Modified:             pulseaudio-9999.ebuild ChangeLog
  Added:                pulseaudio-4.0-r1.ebuild
  Log:
  Introduce multilib support, bug #484252.
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

Revision  Changes    Path
1.39                 media-sound/pulseaudio/pulseaudio-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/pulseaudio/pulseaudio-9999.ebuild?rev=1.39&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/pulseaudio/pulseaudio-9999.ebuild?rev=1.39&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/pulseaudio/pulseaudio-9999.ebuild?r1=1.38&r2=1.39

Index: pulseaudio-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/pulseaudio-9999.ebuild,v
retrieving revision 1.38
retrieving revision 1.39
diff -u -r1.38 -r1.39
--- pulseaudio-9999.ebuild	9 Aug 2013 19:19:40 -0000	1.38
+++ pulseaudio-9999.ebuild	30 Nov 2013 16:12:45 -0000	1.39
@@ -1,10 +1,10 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/pulseaudio-9999.ebuild,v 1.38 2013/08/09 19:19:40 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/pulseaudio-9999.ebuild,v 1.39 2013/11/30 16:12:45 mgorny Exp $
 
 EAPI="5"
 
-inherit autotools eutils flag-o-matic user versionator git-2 udev
+inherit autotools eutils flag-o-matic multilib-minimal user versionator git-2 udev
 
 DESCRIPTION="A networked sound server with an advanced plugin system"
 HOMEPAGE="http://www.pulseaudio.org/"
@@ -22,24 +22,24 @@
 gtk ipv6 jack libsamplerate lirc neon +orc oss qt4 realtime ssl systemd
 system-wide tcpd test +udev +webrtc-aec +X xen"
 
-RDEPEND=">=media-libs/libsndfile-1.0.20
+RDEPEND=">=media-libs/libsndfile-1.0.20[${MULTILIB_USEDEP}]
 	X? (
-		>=x11-libs/libX11-1.4.0
-		>=x11-libs/libxcb-1.6
+		>=x11-libs/libX11-1.4.0[${MULTILIB_USEDEP}]
+		>=x11-libs/libxcb-1.6[${MULTILIB_USEDEP}]
 		>=x11-libs/xcb-util-0.3.1
-		x11-libs/libSM
-		x11-libs/libICE
-		x11-libs/libXtst
+		x11-libs/libSM[${MULTILIB_USEDEP}]
+		x11-libs/libICE[${MULTILIB_USEDEP}]
+		x11-libs/libXtst[${MULTILIB_USEDEP}]
 	)
-	caps? ( sys-libs/libcap )
+	caps? ( sys-libs/libcap[${MULTILIB_USEDEP}] )
 	libsamplerate? ( >=media-libs/libsamplerate-0.1.1-r1 )
 	alsa? ( >=media-libs/alsa-lib-1.0.19 )
-	glib? ( >=dev-libs/glib-2.4.0 )
+	glib? ( >=dev-libs/glib-2.4.0[${MULTILIB_USEDEP}] )
 	avahi? ( >=net-dns/avahi-0.6.12[dbus] )
 	jack? ( >=media-sound/jack-audio-connection-kit-0.117 )
-	tcpd? ( sys-apps/tcp-wrappers )
+	tcpd? ( sys-apps/tcp-wrappers[${MULTILIB_USEDEP}] )
 	lirc? ( app-misc/lirc )
-	dbus? ( >=sys-apps/dbus-1.0.0 )
+	dbus? ( >=sys-apps/dbus-1.0.0[${MULTILIB_USEDEP}] )
 	gtk? ( x11-libs/gtk+:3 )
 	gnome? ( >=gnome-base/gconf-2.4.0 )
 	bluetooth? (
@@ -47,7 +47,7 @@
 		>=sys-apps/dbus-1.0.0
 		media-libs/sbc
 	)
-	asyncns? ( net-libs/libasyncns )
+	asyncns? ( net-libs/libasyncns[${MULTILIB_USEDEP}] )
 	udev? ( >=virtual/udev-143[hwdb(+)] )
 	realtime? ( sys-auth/rtkit )
 	equalizer? ( sci-libs/fftw:3.0 )
@@ -58,7 +58,9 @@
 	webrtc-aec? ( media-libs/webrtc-audio-processing )
 	xen? ( app-emulation/xen )
 	systemd? ( >=sys-apps/systemd-39 )
-	dev-libs/json-c
+	dev-libs/json-c[${MULTILIB_USEDEP}]
+	abi_x86_32? ( !<=app-emulation/emul-linux-x86-soundlibs-20131008-r1
+		!app-emulation/emul-linux-x86-soundlibs[-abi_x86_32(-)] )
 	>=sys-devel/libtool-2.2.4" # it's a valid RDEPEND, libltdl.so is used
 
 DEPEND="${RDEPEND}
@@ -66,8 +68,8 @@
 	doc? ( app-doc/doxygen )
 	test? ( dev-libs/check )
 	X? (
-		x11-proto/xproto
-		>=x11-libs/libXtst-1.0.99.2
+		x11-proto/xproto[${MULTILIB_USEDEP}]
+		>=x11-libs/libXtst-1.0.99.2[${MULTILIB_USEDEP}]
 	)
 	dev-libs/libatomic_ops
 	virtual/pkgconfig
@@ -107,47 +109,93 @@
 	epatch_user
 }
 
-src_configure() {
+multilib_src_configure() {
+	local myconf=()
+
 	if use gdbm; then
-		myconf+=" --with-database=gdbm"
+		myconf+=( --with-database=gdbm )
 	#elif use tdb; then
-	#	myconf+=" --with-database=tdb"
+	#	myconf+=( --with-database=tdb )
 	else
-		myconf+=" --with-database=simple"
+		myconf+=( --with-database=simple )
+	fi
+
+	myconf+=(
+		--enable-largefile
+		$(use_enable glib glib2)
+		--disable-solaris
+		$(use_enable asyncns)
+		$(use_enable oss oss-output)
+		$(use_enable alsa)
+		$(use_enable lirc)
+		$(use_enable neon neon-opt)
+		$(use_enable tcpd tcpwrap)
+		$(use_enable jack)
+		$(use_enable avahi)
+		$(use_enable dbus)
+		$(use_enable gnome gconf)
+		$(use_enable gtk gtk3)
+		$(use_enable libsamplerate samplerate)
+		$(use_enable bluetooth bluez)
+		$(use_enable X x11)
+		$(use_enable test default-build-tests)
+		$(use_enable udev)
+		$(use_enable systemd)
+		$(use_enable ipv6)
+		$(use_enable ssl openssl)
+		$(use_enable webrtc-aec)
+		$(use_enable xen)
+		$(use_with caps)
+		$(use_with equalizer fftw)
+		--disable-adrian-aec
+		--disable-esound
+		--localstatedir="${EPREFIX}"/var
+		--with-udev-rules-dir="${EPREFIX}/$(udev_get_udevdir)"/rules.d
+	)
+
+	if ! multilib_build_binaries; then
+		# disable all the modules and stuff
+		myconf+=(
+			--disable-oss-output
+			--disable-alsa
+			--disable-lirc
+			--disable-jack
+			--disable-avahi
+			--disable-gconf
+			--disable-gtk3
+			--disable-samplerate
+			--disable-bluez
+			--disable-udev
+			--disable-systemd
+			--disable-openssl
+			--disable-webrtc-aec
+			--disable-xen
+			--without-fftw
+
+			# tests involve random modules, so just do them for the native
+			--disable-default-build-tests
+
+			# hack around unnecessary checks
+			# (results don't matter, we're not building anything using it)
+			ac_cv_lib_ltdl_lt_dladvise_init=yes
+			--with-database=simple
+		)
 	fi
 
-	econf \
-		--enable-largefile \
-		$(use_enable glib glib2) \
-		--disable-solaris \
-		$(use_enable asyncns) \
-		$(use_enable oss oss-output) \
-		$(use_enable alsa) \
-		$(use_enable lirc) \
-		$(use_enable neon neon-opt) \
-		$(use_enable tcpd tcpwrap) \
-		$(use_enable jack) \
-		$(use_enable avahi) \
-		$(use_enable dbus) \
-		$(use_enable gnome gconf) \
-		$(use_enable gtk gtk3) \
-		$(use_enable libsamplerate samplerate) \
-		$(use_enable bluetooth bluez) \
-		$(use_enable X x11) \
-		$(use_enable test default-build-tests) \
-		$(use_enable udev) \
-		$(use_enable systemd) \
-		$(use_enable ipv6) \
-		$(use_enable ssl openssl) \
-		$(use_enable webrtc-aec) \
-		$(use_enable xen) \
-		$(use_with caps) \
-		$(use_with equalizer fftw) \
-		--disable-adrian-aec \
-		--disable-esound \
-		--localstatedir="${EPREFIX}"/var \
-		--with-udev-rules-dir="${EPREFIX}/$(udev_get_udevdir)"/rules.d \
-		${myconf}
+	ECONF_SOURCE=${S} \
+	econf "${myconf[@]}"
+}
+
+multilib_src_compile() {
+	if multilib_build_binaries; then
+		emake
+	else
+		emake -C src libpulse{,-simple,-mainloop-glib}.la
+	fi
+}
+
+src_compile() {
+	multilib-minimal_src_compile
 
 	if use doc; then
 		pushd doxygen
@@ -156,16 +204,28 @@
 	fi
 }
 
-src_test() {
+multilib_src_test() {
 	# We avoid running the toplevel check target because that will run
 	# po/'s tests too, and they are broken. Officially, it should work
 	# with intltool 0.41, but that doesn't look like a stable release.
-	emake -C src check
+	if multilib_build_binaries; then
+		emake -C src check
+	fi
 }
 
-src_install() {
-	emake -j1 DESTDIR="${D}" install
+multilib_src_install() {
+	if multilib_build_binaries; then
+		emake -j1 DESTDIR="${D}" install
+	else
+		emake DESTDIR="${D}" install-pkgconfigDATA
+		emake DESTDIR="${D}" -C src \
+			install-libLTLIBRARIES \
+			lib_LTLIBRARIES="libpulse.la libpulse-simple.la libpulse-mainloop-glib.la" \
+			install-pulseincludeHEADERS
+	fi
+}
 
+multilib_src_install_all() {
 	# Drop the script entirely if X is disabled
 	use X || rm "${ED}"/usr/bin/start-pulseaudio-x11
 
@@ -201,7 +261,7 @@
 	# Create the state directory
 	use prefix || diropts -o pulse -g pulse -m0755
 
-	find "${D}" -name '*.la' -delete
+	prune_libtool_files --all
 }
 
 pkg_postinst() {



1.308                media-sound/pulseaudio/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/pulseaudio/ChangeLog?rev=1.308&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/pulseaudio/ChangeLog?rev=1.308&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/pulseaudio/ChangeLog?r1=1.307&r2=1.308

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/ChangeLog,v
retrieving revision 1.307
retrieving revision 1.308
diff -u -r1.307 -r1.308
--- ChangeLog	23 Nov 2013 21:41:38 -0000	1.307
+++ ChangeLog	30 Nov 2013 16:12:45 -0000	1.308
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/pulseaudio
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/ChangeLog,v 1.307 2013/11/23 21:41:38 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/ChangeLog,v 1.308 2013/11/30 16:12:45 mgorny Exp $
+
+*pulseaudio-4.0-r1 (30 Nov 2013)
+
+  30 Nov 2013; Michał Górny <mgorny@g.o> +pulseaudio-4.0-r1.ebuild,
+  pulseaudio-9999.ebuild:
+  Introduce multilib support, bug #484252.
 
   23 Nov 2013; Pacho Ramos <pacho@g.o> pulseaudio-4.0.ebuild:
   amd64 stable, bug #477662



1.1                  media-sound/pulseaudio/pulseaudio-4.0-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/pulseaudio/pulseaudio-4.0-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/pulseaudio/pulseaudio-4.0-r1.ebuild?rev=1.1&content-type=text/plain

Index: pulseaudio-4.0-r1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/pulseaudio-4.0-r1.ebuild,v 1.1 2013/11/30 16:12:45 mgorny Exp $

EAPI="5"

inherit eutils flag-o-matic multilib-minimal user versionator udev

DESCRIPTION="A networked sound server with an advanced plugin system"
HOMEPAGE="http://www.pulseaudio.org/"

SRC_URI="http://freedesktop.org/software/pulseaudio/releases/${P}.tar.xz"

# libpulse-simple and libpulse link to libpulse-core; this is daemon's
# library and can link to gdbm and other GPL-only libraries. In this
# cases, we have a fully GPL-2 package. Leaving the rest of the
# GPL-forcing USE flags for those who use them.
LICENSE="!gdbm? ( LGPL-2.1 ) gdbm? ( GPL-2 )"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux"
IUSE="+alsa +asyncns avahi bluetooth +caps dbus doc equalizer +gdbm +glib gnome
gtk ipv6 jack libsamplerate lirc neon +orc oss qt4 realtime ssl systemd
system-wide tcpd test +udev +webrtc-aec +X xen"

RDEPEND=">=media-libs/libsndfile-1.0.20[${MULTILIB_USEDEP}]
	X? (
		>=x11-libs/libX11-1.4.0[${MULTILIB_USEDEP}]
		>=x11-libs/libxcb-1.6[${MULTILIB_USEDEP}]
		>=x11-libs/xcb-util-0.3.1
		x11-libs/libSM[${MULTILIB_USEDEP}]
		x11-libs/libICE[${MULTILIB_USEDEP}]
		x11-libs/libXtst[${MULTILIB_USEDEP}]
	)
	caps? ( sys-libs/libcap[${MULTILIB_USEDEP}] )
	libsamplerate? ( >=media-libs/libsamplerate-0.1.1-r1 )
	alsa? ( >=media-libs/alsa-lib-1.0.19 )
	glib? ( >=dev-libs/glib-2.4.0[${MULTILIB_USEDEP}] )
	avahi? ( >=net-dns/avahi-0.6.12[dbus] )
	jack? ( >=media-sound/jack-audio-connection-kit-0.117 )
	tcpd? ( sys-apps/tcp-wrappers[${MULTILIB_USEDEP}] )
	lirc? ( app-misc/lirc )
	dbus? ( >=sys-apps/dbus-1.0.0[${MULTILIB_USEDEP}] )
	gtk? ( x11-libs/gtk+:3 )
	gnome? ( >=gnome-base/gconf-2.4.0 )
	bluetooth? (
		>=net-wireless/bluez-4.99
		>=sys-apps/dbus-1.0.0
		media-libs/sbc
	)
	asyncns? ( net-libs/libasyncns[${MULTILIB_USEDEP}] )
	udev? ( >=virtual/udev-143[hwdb(+)] )
	realtime? ( sys-auth/rtkit )
	equalizer? ( sci-libs/fftw:3.0 )
	orc? ( >=dev-lang/orc-0.4.9 )
	ssl? ( dev-libs/openssl )
	>=media-libs/speex-1.2_rc1
	gdbm? ( sys-libs/gdbm )
	webrtc-aec? ( media-libs/webrtc-audio-processing )
	xen? ( app-emulation/xen )
	systemd? ( >=sys-apps/systemd-39 )
	dev-libs/json-c[${MULTILIB_USEDEP}]
	abi_x86_32? ( !<=app-emulation/emul-linux-x86-soundlibs-20131008-r1
		!app-emulation/emul-linux-x86-soundlibs[-abi_x86_32(-)] )
	>=sys-devel/libtool-2.2.4" # it's a valid RDEPEND, libltdl.so is used

DEPEND="${RDEPEND}
	sys-devel/m4
	doc? ( app-doc/doxygen )
	test? ( dev-libs/check )
	X? (
		x11-proto/xproto[${MULTILIB_USEDEP}]
		>=x11-libs/libXtst-1.0.99.2[${MULTILIB_USEDEP}]
	)
	dev-libs/libatomic_ops
	virtual/pkgconfig
	system-wide? ( || ( dev-util/unifdef sys-freebsd/freebsd-ubin ) )
	dev-util/intltool"
# This is a PDEPEND to avoid a circular dep
PDEPEND="alsa? ( media-plugins/alsa-plugins[pulseaudio] )"

# alsa-utils dep is for the alsasound init.d script (see bug #155707)
# bluez dep is for the bluetooth init.d script
# PyQt4 dep is for the qpaeq script
RDEPEND="${RDEPEND}
	equalizer? ( qt4? ( dev-python/PyQt4[dbus] ) )
	X? ( gnome-extra/gnome-audio )
	system-wide? (
		sys-apps/openrc
		alsa? ( media-sound/alsa-utils )
		bluetooth? ( >=net-wireless/bluez-4 )
	)"

# See "*** BLUEZ support not found (requires D-Bus)" in configure.ac
REQUIRED_USE="bluetooth? ( dbus )"

pkg_setup() {
	enewgroup audio 18 # Just make sure it exists

	if use system-wide; then
		enewgroup pulse-access
		enewgroup pulse
		enewuser pulse -1 -1 /var/run/pulse pulse,audio
	fi
}

src_prepare() {
	epatch_user
}

multilib_src_configure() {
	local myconf=()

	if use gdbm; then
		myconf+=( --with-database=gdbm )
	#elif use tdb; then
	#	myconf+=( --with-database=tdb )
	else
		myconf+=( --with-database=simple )
	fi

	myconf+=(
		--enable-largefile
		$(use_enable glib glib2)
		--disable-solaris
		$(use_enable asyncns)
		$(use_enable oss oss-output)
		$(use_enable alsa)
		$(use_enable lirc)
		$(use_enable neon neon-opt)
		$(use_enable tcpd tcpwrap)
		$(use_enable jack)
		$(use_enable avahi)
		$(use_enable dbus)
		$(use_enable gnome gconf)
		$(use_enable gtk gtk3)
		$(use_enable libsamplerate samplerate)
		$(use_enable bluetooth bluez)
		$(use_enable X x11)
		$(use_enable test default-build-tests)
		$(use_enable udev)
		$(use_enable systemd)
		$(use_enable ipv6)
		$(use_enable ssl openssl)
		$(use_enable webrtc-aec)
		$(use_enable xen)
		$(use_with caps)
		$(use_with equalizer fftw)
		--disable-adrian-aec
		--disable-esound
		--localstatedir="${EPREFIX}"/var
		--with-udev-rules-dir="${EPREFIX}/$(udev_get_udevdir)"/rules.d
	)

	if ! multilib_build_binaries; then
		# disable all the modules and stuff
		myconf+=(
			--disable-oss-output
			--disable-alsa
			--disable-lirc
			--disable-jack
			--disable-avahi
			--disable-gconf
			--disable-gtk3
			--disable-samplerate
			--disable-bluez
			--disable-udev
			--disable-systemd
			--disable-openssl
			--disable-webrtc-aec
			--disable-xen
			--without-fftw

			# tests involve random modules, so just do them for the native
			--disable-default-build-tests

			# hack around unnecessary checks
			# (results don't matter, we're not building anything using it)
			ac_cv_lib_ltdl_lt_dladvise_init=yes
			--with-database=simple
		)
	fi

	ECONF_SOURCE=${S} \
	econf "${myconf[@]}"
}

multilib_src_compile() {
	if multilib_build_binaries; then
		emake
	else
		emake -C src libpulse{,-simple,-mainloop-glib}.la
	fi
}

src_compile() {
	multilib-minimal_src_compile

	if use doc; then
		pushd doxygen
		doxygen doxygen.conf
		popd
	fi
}

multilib_src_test() {
	# We avoid running the toplevel check target because that will run
	# po/'s tests too, and they are broken. Officially, it should work
	# with intltool 0.41, but that doesn't look like a stable release.
	if multilib_build_binaries; then
		emake -C src check
	fi
}

multilib_src_install() {
	if multilib_build_binaries; then
		emake -j1 DESTDIR="${D}" install
	else
		emake DESTDIR="${D}" install-pkgconfigDATA
		emake DESTDIR="${D}" -C src \
			install-libLTLIBRARIES \
			lib_LTLIBRARIES="libpulse.la libpulse-simple.la libpulse-mainloop-glib.la" \
			install-pulseincludeHEADERS
	fi
}

multilib_src_install_all() {
	# Drop the script entirely if X is disabled
	use X || rm "${ED}"/usr/bin/start-pulseaudio-x11

	if use system-wide; then
		newconfd "${FILESDIR}/pulseaudio.conf.d" pulseaudio

		use_define() {
			local define=${2:-$(echo $1 | tr '[:lower:]' '[:upper:]')}

			use "$1" && echo "-D$define" || echo "-U$define"
		}

		unifdef $(use_define avahi) \
			$(use_define alsa) \
			$(use_define bluetooth) \
			$(use_define udev) \
			"${FILESDIR}/pulseaudio.init.d-5" \
			> "${T}/pulseaudio"

		doinitd "${T}/pulseaudio"
	fi

	use avahi && sed -i -e '/module-zeroconf-publish/s:^#::' "${ED}/etc/pulse/default.pa"

	dodoc README todo

	if use doc; then
		pushd doxygen/html
		dohtml *
		popd
	fi

	# Create the state directory
	use prefix || diropts -o pulse -g pulse -m0755

	prune_libtool_files --all
}

pkg_postinst() {
	if use system-wide; then
		elog "PulseAudio in Gentoo can use a system-wide pulseaudio daemon."
		elog "This support is enabled by starting the pulseaudio init.d ."
		elog "To be able to access that you need to be in the group pulse-access."
		elog "If you choose to use this feature, please make sure that you"
		elog "really want to run PulseAudio this way:"
		elog "   http://pulseaudio.org/wiki/WhatIsWrongWithSystemMode"
		elog "For more information about system-wide support, please refer to:"
		elog "	 http://pulseaudio.org/wiki/SystemWideInstance"
		if use gnome ; then
			elog
			elog "By enabling gnome USE flag, you enabled gconf support. Please note"
			elog "that you might need to remove the gnome USE flag or disable the"
			elog "gconf module on /etc/pulse/system.pa to be able to use PulseAudio"
			elog "with a system-wide instance."
		fi
	fi
	if use bluetooth; then
		elog
		elog "The Bluetooth proximity module is not enabled in the default"
		elog "configuration file. If you do enable it, you'll have to have"
		elog "your Bluetooth controller enabled and inserted at bootup or"
		elog "PulseAudio will refuse to start."
	fi
	if use equalizer && ! use qt4; then
		elog "You've enabled the 'equalizer' USE-flag but not the 'qt4' USE-flag."
		elog "This will build the equalizer module, but the 'qpaeq' tool"
		elog "which is required to set equalizer levels will not work."
	fi
}