[gentoo-commits] repo/gentoo:master commit in: x11-libs/libvdpau/

[Jeroen Roovers]

commit:     6571257c67a8e9f3fd5eb8ef5e9c5a0dab9ac7f1
Author:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
AuthorDate: Thu Feb 28 22:10:53 2019 +0000
Commit:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
CommitDate: Thu Feb 28 22:11:09 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6571257c

x11-libs/libvdpau: Add live ebuild

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Jeroen Roovers <jer <AT> gentoo.org>

 x11-libs/libvdpau/libvdpau-99999.ebuild | 56 +++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)

diff --git a/x11-libs/libvdpau/libvdpau-99999.ebuild b/x11-libs/libvdpau/libvdpau-99999.ebuild
new file mode 100644
index 00000000000..ecc84d2648b
--- /dev/null
+++ b/x11-libs/libvdpau/libvdpau-99999.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+VIRTUALX_REQUIRED="test"
+inherit flag-o-matic git-r3 meson virtualx multilib-minimal
+
+DESCRIPTION="VDPAU wrapper and trace libraries"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/VDPAU"
+EGIT_REPO_URI="https://gitlab.freedesktop.org/vdpau/${PN}/"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS=""
+IUSE="doc dri"
+
+RDEPEND="
+	>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+	dri? ( >=x11-libs/libXext-1.3.2[${MULTILIB_USEDEP}] )
+"
+DEPEND="
+	${RDEPEND}
+	virtual/pkgconfig
+	doc? (
+		app-doc/doxygen
+		media-gfx/graphviz
+		virtual/latex-base
+		)
+	dri? ( x11-base/xorg-proto )
+"
+
+src_prepare() {
+	sed -i -e "/^docdir/s|${PN}|${PF}|g" doc/meson.build || die
+	default
+}
+
+multilib_src_configure() {
+	append-cppflags -D_GNU_SOURCE
+	local emesonargs=(
+		-Ddri2=$(usex dri true false)
+		-Ddocumentation=$(usex doc true false)
+	)
+	meson_src_configure
+}
+
+multilib_src_compile() {
+	meson_src_compile
+}
+multilib_src_test() {
+	virtx meson_src_test
+}
+
+multilib_src_install() {
+	meson_src_install
+	find "${ED}" -name '*.la' -delete || die
+}