Gentoo Archives: gentoo-commits

From: "Thomas Beierlein (tomjbe)" <tomjbe@g.o>
To: gentoo-commits@l.g.o
Subject: [gentoo-commits] gentoo-x86 commit in media-radio/unixcw: ChangeLog unixcw-3.0.2.ebuild
Date: Thu, 21 Jun 2012 06:11:16
Message-Id: 20120621061100.B79052004C@flycatcher.gentoo.org
tomjbe      12/06/21 06:11:00

  Modified:             ChangeLog
  Added:                unixcw-3.0.2.ebuild
  Log:
  Version bump
  
  (Portage version: 2.1.10.65/cvs/Linux x86_64)

Revision  Changes    Path
1.6                  media-radio/unixcw/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-radio/unixcw/ChangeLog?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-radio/unixcw/ChangeLog?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-radio/unixcw/ChangeLog?r1=1.5&r2=1.6

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-radio/unixcw/ChangeLog,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- ChangeLog	3 May 2012 03:48:56 -0000	1.5
+++ ChangeLog	21 Jun 2012 06:11:00 -0000	1.6
@@ -1,6 +1,13 @@
 # ChangeLog for media-radio/unixcw
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-radio/unixcw/ChangeLog,v 1.5 2012/05/03 03:48:56 jdhore Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-radio/unixcw/ChangeLog,v 1.6 2012/06/21 06:11:00 tomjbe Exp $
+
+*unixcw-3.0.2 (21 Jun 2012)
+
+  21 Jun 2012; Thomas Beierlein <tomjbe@g.o> +unixcw-3.0.2.ebuild,
+  +files/unixcw-3.0.2-config.patch, +files/unixcw-3.0.2-destdir.patch,
+  +files/unixcw-3.0.2-parallel-make.patch, +files/unixcw-3.0.2-qt4.patch:
+  Version bump
 
   03 May 2012; Jeff Horelick <jdhore@g.o> unixcw-2.3-r6.ebuild:
   dev-util/pkgconfig -> virtual/pkgconfig



1.1                  media-radio/unixcw/unixcw-3.0.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-radio/unixcw/unixcw-3.0.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-radio/unixcw/unixcw-3.0.2.ebuild?rev=1.1&content-type=text/plain

Index: unixcw-3.0.2.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-radio/unixcw/unixcw-3.0.2.ebuild,v 1.1 2012/06/21 06:11:00 tomjbe Exp $

EAPI=4

inherit autotools eutils flag-o-matic multilib

DESCRIPTION="A package of programs that fit together to form a morse code tutor program."
HOMEPAGE="http://unixcw.sourceforge.net"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ppc ~x86"
IUSE="ncurses suid qt4"

RDEPEND="ncurses? ( sys-libs/ncurses )
	qt4? ( x11-libs/qt-gui:4[qt3support] )"
DEPEND="${RDEPEND}
	virtual/pkgconfig
	!<=app-misc/cw-1.0.16-r1"

src_prepare() {
	append-cflags -std=gnu99
	epatch \
		"${FILESDIR}"/${P}-config.patch \
 		"${FILESDIR}"/${P}-destdir.patch \
		"${FILESDIR}"/${P}-parallel-make.patch \
		"${FILESDIR}"/${P}-qt4.patch
	eautoreconf
}

src_configure() {
	econf --libdir=/usr/$(get_libdir) \
		$(use_enable ncurses) \
		$(use_enable qt4)
}

src_install() {
	emake DESTDIR="${D}" install
	dodoc README
	if ! use suid ; then
		fperms 711 /usr/bin/cw
		if use ncurses ; then
			fperms 711 /usr/bin/cwcp
		fi
		if use qt4 ; then
			fperms 711 /usr/bin/xcwcp
		fi
	fi
}

pkg_postinst() {
	if use suid ; then
		ewarn "You have choosen to install 'cw', 'cwcp' and 'xcwcp' setuid"
		ewarn "by setting USE=suid."
		ewarn "Be aware that this is a security risk and not recommended."
		ewarn ""
		ewarn "These files do only need root access if you want to use the"
		ewarn "PC speaker for morse sidetone output. You can alternativly"
		ewarn "drop USE=suid and use sudo."
	else
		elog "Be aware that 'cw', 'cwcp' and 'xcwcp' needs root access if"
		elog "you want to use the PC speaker for morse sidetone output."
		elog "You can call the programs via sudo for that (see 'man sudo')."
	fi
}