[gentoo-commits] gentoo-x86 commit in dev-lisp/ecls: ChangeLog ecls-11.1.1.ebuild

[Andrey Grozin (grozin)]

grozin      11/01/17 15:53:31

  Modified:             ChangeLog
  Added:                ecls-11.1.1.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.0_alpha15/cvs/Linux i686)

Revision  Changes    Path
1.38                 dev-lisp/ecls/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lisp/ecls/ChangeLog?rev=1.38&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lisp/ecls/ChangeLog?rev=1.38&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lisp/ecls/ChangeLog?r1=1.37&r2=1.38

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-lisp/ecls/ChangeLog,v
retrieving revision 1.37
retrieving revision 1.38
diff -u -r1.37 -r1.38
--- ChangeLog	17 Dec 2010 20:18:31 -0000	1.37
+++ ChangeLog	17 Jan 2011 15:53:31 -0000	1.38
@@ -1,6 +1,12 @@
 # ChangeLog for dev-lisp/ecls
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lisp/ecls/ChangeLog,v 1.37 2010/12/17 20:18:31 ulm Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-lisp/ecls/ChangeLog,v 1.38 2011/01/17 15:53:31 grozin Exp $
+
+*ecls-11.1.1 (17 Jan 2011)
+
+  17 Jan 2011; Andrey Grozin <grozin@g.o>
+  +files/11.1.1-headers-gentoo.patch, +ecls-11.1.1.ebuild:
+  Version bump
 
   17 Dec 2010; Ulrich Mueller <ulm@g.o> ecls-9.12.3.ebuild,
   ecls-10.2.1.ebuild, ecls-10.4.1.ebuild:



1.1                  dev-lisp/ecls/ecls-11.1.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lisp/ecls/ecls-11.1.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lisp/ecls/ecls-11.1.1.ebuild?rev=1.1&content-type=text/plain

Index: ecls-11.1.1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-lisp/ecls/ecls-11.1.1.ebuild,v 1.1 2011/01/17 15:53:31 grozin Exp $

EAPI=3
inherit eutils multilib

MY_P=ecl-${PV}

DESCRIPTION="ECL is an embeddable Common Lisp implementation."
HOMEPAGE="http://common-lisp.net/project/ecl/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"

LICENSE="BSD LGPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~sparc ~x86"
IUSE="debug gengc precisegc threads +unicode X"

RDEPEND="dev-libs/gmp
		virtual/libffi
		>=dev-libs/boehm-gc-7.1[threads?]"
DEPEND="${RDEPEND}
		app-text/texi2html"
PDEPEND="dev-lisp/gentoo-init"

S="${WORKDIR}"/${MY_P}

pkg_setup() {
	if use gengc || use precisegc; then
		ewarn "USE flags gengc and precisegc are experimental"
		ewarn "Don't use them if you want a stable ecl"
	fi
}

src_prepare() {
	epatch "${FILESDIR}"/${PV}-headers-gentoo.patch
}

src_configure() {
	econf \
		--with-system-gmp \
		--enable-boehm=system \
		--enable-longdouble \
		$(use_enable gengc) \
		$(use_enable precisegc) \
		$(use_with debug debug-cflags) \
		$(use_enable threads) \
		$(use_with threads __thread) \
		$(use_enable unicode) \
		$(use_with X x) \
		$(use_with X clx)
}

src_compile() {
	#parallel fails
	emake -j1 || die "Compilation failed"
}

src_install () {
	emake DESTDIR="${D}" install || die "Installation failed"

	dodoc ANNOUNCEMENT Copyright
	dodoc "${FILESDIR}"/README.Gentoo
	pushd build/doc
	newman ecl.man ecl.1
	newman ecl-config.man ecl-config.1
	popd
}