[gentoo-commits] repo/gentoo:master commit in: gnome-extra/gnome-contacts/

[Matt Turner]

commit:     6c89771e90a526e1967a504e0c99c47133d7c794
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Sat Oct  1 20:28:38 2022 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Sat Oct  1 20:35:13 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6c89771e

gnome-extra/gnome-contacts: Version bump to 43.0

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 gnome-extra/gnome-contacts/Manifest                |  1 +
 .../gnome-contacts/gnome-contacts-43.0.ebuild      | 70 ++++++++++++++++++++++
 2 files changed, 71 insertions(+)

diff --git a/gnome-extra/gnome-contacts/Manifest b/gnome-extra/gnome-contacts/Manifest
index fe35fda7a160..1ed058e144ea 100644
--- a/gnome-extra/gnome-contacts/Manifest
+++ b/gnome-extra/gnome-contacts/Manifest
@@ -1,2 +1,3 @@
 DIST gnome-contacts-41.0.tar.xz 275248 BLAKE2B c0611a131ce1ebb74b96e96e2e1b9370526b56c49ee43876273fdf5b2f3b333ad2aad85c50ddcebaac85ee8c996037fec3209c6765cab7b37b49ced04a82a7a8 SHA512 310f333c0863d8e58c2280b994071b2655eee7224ab80a468ffc7acc61834d3f6dbb794bbdc5b8d4428226bab96f3ea65b8bed39df79d88704e38b51a8f4b05f
 DIST gnome-contacts-42.0.tar.xz 343312 BLAKE2B a86bc70301a4f04bf7be426802e75d412abfa468555172233c5b540fcc0e630c433607ebe2a5dbffa58d49ab23773deb6099f88fdfa06f44f767d3fce57821bc SHA512 09a0d70a1550136717c4f837f2e4526928559de4bccedb71b34a216d99c36886bfd5786fcc3487198c488b4778046453d0069da55ab283ef87513c2d668a11cd
+DIST gnome-contacts-43.0.tar.xz 380348 BLAKE2B be226024dd8369a3c3df9766d6860912fee5a698ee4e0754d773afe16d7f787f3d8a73485c9a31b091514b7de3a835e3f4e37b6c11fc746e1a5f681e07af58fc SHA512 ee2cfc4ad2318f27b0e6597eae501a6e2240b4de8ceb7982c4942a6ff50ce6cd56d06f5d324ac04f82dd8e7086dc82426fb3aab9c194cbfa490b5bab98ba0469

diff --git a/gnome-extra/gnome-contacts/gnome-contacts-43.0.ebuild b/gnome-extra/gnome-contacts/gnome-contacts-43.0.ebuild
new file mode 100644
index 000000000000..cd2c165900dc
--- /dev/null
+++ b/gnome-extra/gnome-contacts/gnome-contacts-43.0.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit gnome.org gnome2-utils meson python-any-r1 vala xdg
+
+DESCRIPTION="GNOME contact management application"
+HOMEPAGE="https://wiki.gnome.org/Design/Apps/Contacts"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~sparc ~x86"
+
+VALA_DEPEND="
+	$(vala_depend)
+	>=dev-libs/gobject-introspection-1.54
+	dev-libs/folks[vala(+)]
+	net-libs/gnome-online-accounts[vala]
+	gnome-extra/evolution-data-server[gtk,vala]
+	>=dev-libs/libportal-0.6:=[vala]
+"
+RDEPEND="
+	>=dev-libs/folks-0.11.4:=[eds]
+	>=dev-libs/libgee-0.10:0.8=
+	>=dev-libs/glib-2.58:2
+	net-libs/gnome-online-accounts:=
+	>=gui-libs/gtk-4.6:4
+	>=gui-libs/libadwaita-1.2:1
+	>=gnome-extra/evolution-data-server-3.30:=[gnome-online-accounts]
+	>=dev-libs/libportal-0.6:=
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	${PYTHON_DEPS}
+	${VALA_DEPEND}
+	app-text/docbook-xml-dtd:4.2
+	app-text/docbook-xsl-stylesheets
+	dev-libs/appstream-glib
+	dev-libs/libxml2:2
+	dev-libs/libxslt
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+	vala_setup
+	xdg_environment_reset
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dcamera=true # Ignored
+		-Dmanpage=true
+		-Ddocs=false
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}