[gentoo-commits] gentoo-x86 commit in media-gfx/hugin: ChangeLog hugin-2010.4.0_beta1.ebuild

[Markus Meier (maekke)]

maekke      10/11/27 15:21:15

  Modified:             ChangeLog
  Added:                hugin-2010.4.0_beta1.ebuild
  Log:
  version bump to 2010.4 beta1
  
  (Portage version: 2.1.9.24/cvs/Linux i686)

Revision  Changes    Path
1.101                media-gfx/hugin/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/hugin/ChangeLog?rev=1.101&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/hugin/ChangeLog?rev=1.101&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/hugin/ChangeLog?r1=1.100&r2=1.101

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/hugin/ChangeLog,v
retrieving revision 1.100
retrieving revision 1.101
diff -u -r1.100 -r1.101
--- ChangeLog	8 Nov 2010 22:10:44 -0000	1.100
+++ ChangeLog	27 Nov 2010 15:21:15 -0000	1.101
@@ -1,6 +1,11 @@
 # ChangeLog for media-gfx/hugin
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/hugin/ChangeLog,v 1.100 2010/11/08 22:10:44 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/hugin/ChangeLog,v 1.101 2010/11/27 15:21:15 maekke Exp $
+
+*hugin-2010.4.0_beta1 (27 Nov 2010)
+
+  27 Nov 2010; Markus Meier <maekke@g.o> +hugin-2010.4.0_beta1.ebuild:
+  version bump to 2010.4 beta1
 
   08 Nov 2010; Markus Meier <maekke@g.o> hugin-2010.0.0.ebuild,
   hugin-2010.2.0.ebuild:



1.1                  media-gfx/hugin/hugin-2010.4.0_beta1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/hugin/hugin-2010.4.0_beta1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/hugin/hugin-2010.4.0_beta1.ebuild?rev=1.1&content-type=text/plain

Index: hugin-2010.4.0_beta1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-gfx/hugin/hugin-2010.4.0_beta1.ebuild,v 1.1 2010/11/27 15:21:15 maekke Exp $

EAPI=2
WX_GTK_VER="2.8"

inherit cmake-utils wxwidgets versionator

DESCRIPTION="GUI for the creation & processing of panoramic images"
HOMEPAGE="http://hugin.sf.net"
SRC_URI="mirror://sourceforge/${PN}/${P/_beta/beta}.tar.bz2"
LICENSE="GPL-2 SIFT"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"

LANGS=" bg ca cs de en_GB es fi fr hu it ja ko nl pl pt_BR ru sk sl sv uk zh_CN zh_TW"
IUSE="lapack sift $(echo ${LANGS//\ /\ linguas_})"

CDEPEND="
	!!dev-util/cocom
	app-arch/zip
	>=dev-libs/boost-1.35.0-r5
	>=media-gfx/enblend-3.0_p20080807
	media-gfx/exiv2
	media-libs/freeglut
	>=media-libs/libpano13-2.9.17
	media-libs/libpng
	media-libs/openexr
	media-libs/tiff
	sys-libs/zlib
	virtual/jpeg
	x11-libs/wxGTK:2.8[opengl,-odbc]
	lapack? ( virtual/lapack )
	sift? ( media-gfx/autopano-sift-C )"
RDEPEND="${CDEPEND}
	media-libs/exiftool"
DEPEND="${CDEPEND}
	dev-util/pkgconfig"

S=${WORKDIR}/${PN}-$(get_version_component_range 1-3)

pkg_setup() {
	DOCS="authors.txt README TODO"
	mycmakeargs=( $(cmake-utils_use_enable lapack LAPACK) )
}

src_install() {
	cmake-utils_src_install

	for lang in ${LANGS} ; do
		case ${lang} in
			ca) dir=ca_ES;;
			cs) dir=cs_CZ;;
			*) dir=${lang};;
		esac
		use linguas_${lang} || rm -r "${D}"/usr/share/locale/${dir}
	done
}

pkg_postinst() {
	elog "Please note that the sift USE-flag has been disabled by default"
	elog "as hugin ships its own control point generator with 2010.4"
}