[gentoo-commits] gentoo-x86 commit in games-simulation/openttd: ChangeLog openttd-0.7.0.ebuild

[Michael Sterrett (mr_bones_)]

mr_bones_    09/04/02 18:14:03

  Modified:             ChangeLog
  Added:                openttd-0.7.0.ebuild
  Log:
  version bump - ebuild and patch submitted by scarabeus
  (Portage version: 2.1.6.7/cvs/Linux i686)

Revision  Changes    Path
1.68                 games-simulation/openttd/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-simulation/openttd/ChangeLog?rev=1.68&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-simulation/openttd/ChangeLog?rev=1.68&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-simulation/openttd/ChangeLog?r1=1.67&r2=1.68

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-simulation/openttd/ChangeLog,v
retrieving revision 1.67
retrieving revision 1.68
diff -u -r1.67 -r1.68
--- ChangeLog	2 Feb 2009 15:14:49 -0000	1.67
+++ ChangeLog	2 Apr 2009 18:14:03 -0000	1.68
@@ -1,6 +1,12 @@
 # ChangeLog for games-simulation/openttd
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-simulation/openttd/ChangeLog,v 1.67 2009/02/02 15:14:49 ranger Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-simulation/openttd/ChangeLog,v 1.68 2009/04/02 18:14:03 mr_bones_ Exp $
+
+*openttd-0.7.0 (02 Apr 2009)
+
+  02 Apr 2009; Michael Sterrett <mr_bones_@g.o>
+  +files/openttd-0.7.0-build.patch, +openttd-0.7.0.ebuild:
+  version bump - ebuild and patch submitted by scarabeus
 
   02 Feb 2009; Brent Baude <ranger@g.o> openttd-0.6.3.ebuild:
   Marking openttd-0.6.3 ppc64 for bug 233929



1.1                  games-simulation/openttd/openttd-0.7.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-simulation/openttd/openttd-0.7.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-simulation/openttd/openttd-0.7.0.ebuild?rev=1.1&content-type=text/plain

Index: openttd-0.7.0.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-simulation/openttd/openttd-0.7.0.ebuild,v 1.1 2009/04/02 18:14:03 mr_bones_ Exp $

EAPI=2
inherit eutils games

DESCRIPTION="OpenTTD is a clone of Transport Tycoon Deluxe"
HOMEPAGE="http://www.openttd.org/"
SRC_URI="http://binaries.openttd.org/releases/${PV}/${P}-source.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="alsa debug dedicated iconv icu +png +truetype zlib"
RESTRICT="test"

DEPEND="
	!dedicated? (
		media-libs/libsdl[X]
		icu? ( dev-libs/icu )
		truetype? (
			media-libs/fontconfig
			media-libs/freetype:2
			sys-libs/zlib
		)
	)
	iconv? ( virtual/libiconv )
	png? ( media-libs/libpng )
	zlib? ( sys-libs/zlib )"
RDEPEND="${DEPEND}
	!dedicated? (
		alsa? ( media-sound/alsa-utils[midi] )
	)"

PATCHES=( "${FILESDIR}"/${P}-build.patch )

src_configure() {
	local myopts

	use debug && myopts="${myopts} --enable-debug=3"

	if use dedicated ; then
		myopts="${myopts} --enable-dedicated"
	else
		use alsa && myopts="${myopts} --with-midi=/usr/bin/aplaymidi"
		myopts="${myopts}
			$(use_with truetype freetype)
			$(use_with icu)
			--with-sdl"
	fi
	if use png || { use !dedicated && use truetype; } || use zlib ; then
		myopts="${myopts} --with-zlib"
	else
		myopts="${myopts} --without-zlib"
	fi

	# there is an allegro interface available as well as sdl, but
	# the configure for it looks broken so the sdl interface is
	# always built instead.
	myopts="${myopts} --without-allegro"

	# configure is a hand-written sh-script, so econf will not work
	./configure \
		--disable-strip \
		--prefix-dir=/usr \
		--binary-dir="${GAMES_BINDIR}" \
		--data-dir="${GAMES_DATADIR}/${PN}" \
		--install-dir="${D}" \
		--doc-dir=share/doc/${PF} \
		--menu-group="Game;Simulation;" \
		${myopts} \
		$(use_with iconv) \
		$(use_with png) \
		|| die "configure failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	if use dedicated ; then
		newinitd "${FILESDIR}"/${PN}.initd ${PN}
		rm -rf "${D}"/usr/share/{applications,icons,pixmaps}
	fi
	rm -f "${D}"/usr/share/doc/${PF}/COPYING
	prepalldocs
	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst

	elog
	elog "In order to play, you must copy the following 6 files from "
	elog "a version of TTD to ${GAMES_DATADIR}/${PN}/data/."
	elog
	elog "From the WINDOWS version you need: "
	elog "  sample.cat trg1r.grf trgcr.grf trghr.grf trgir.grf trgtr.grf"
	elog "OR from the DOS version you need: "
	elog "  SAMPLE.CAT TRG1.GRF TRGC.GRF TRGH.GRF TRGI.GRF TRGT.GRF"
	elog
	elog "File names are case sensitive so make sure they are "
	elog "correct for whichever version you have."
	elog

	if use dedicated ; then
		ewarn "Warning: The init script will kill all running openttd"
		ewarn "processes when run, including any running client sessions!"
	else
		if use alsa ; then
			elog "You have emerged with 'aplaymidi' for playing MIDI."
			elog "You have to set the environment variable ALSA_OUTPUT_PORTS."
			elog "Available ports can be listed by using 'aplaymidi -l'."
		else
			elog "alsa not in USE so music will not be played during the game."
		fi
	fi
}