[gentoo-commits] gentoo-x86 commit in net-firewall/ufw: ufw-0.30.1-r4.ebuild ChangeLog ufw-0.30.1-r2.ebuild ufw-0.30.1-r3.ebuild

[Tomas Chvatal (scarabeus)]

scarabeus    12/02/28 11:42:23

  Modified:             ChangeLog
  Added:                ufw-0.30.1-r4.ebuild
  Removed:              ufw-0.30.1-r2.ebuild ufw-0.30.1-r3.ebuild
  Log:
  Update per proxy-maintainer request. Remove overshadowed versions.
  
  (Portage version: 2.2.0_alpha89/cvs/Linux x86_64)

Revision  Changes    Path
1.5                  net-firewall/ufw/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/ufw/ChangeLog?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/ufw/ChangeLog?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/ufw/ChangeLog?r1=1.4&r2=1.5

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-firewall/ufw/ChangeLog,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- ChangeLog	13 Sep 2011 06:35:49 -0000	1.4
+++ ChangeLog	28 Feb 2012 11:42:22 -0000	1.5
@@ -1,6 +1,13 @@
 # ChangeLog for net-firewall/ufw
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-firewall/ufw/ChangeLog,v 1.4 2011/09/13 06:35:49 pva Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-firewall/ufw/ChangeLog,v 1.5 2012/02/28 11:42:22 scarabeus Exp $
+
+*ufw-0.30.1-r4 (28 Feb 2012)
+
+  28 Feb 2012; Tomáš Chvátal <scarabeus@g.o>
+  +files/ufw-0.30.1-encoding.patch, +files/ufw-0.30.1-python-abis.patch,
+  +ufw-0.30.1-r4.ebuild, -ufw-0.30.1-r2.ebuild, -ufw-0.30.1-r3.ebuild:
+  Update per proxy-maintainer request. Remove overshadowed versions.
 
   13 Sep 2011; Peter Volkov <pva@g.o> ufw-0.30.1-r2.ebuild,
   ufw-0.30.1-r3.ebuild:



1.1                  net-firewall/ufw/ufw-0.30.1-r4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/ufw/ufw-0.30.1-r4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/ufw/ufw-0.30.1-r4.ebuild?rev=1.1&content-type=text/plain

Index: ufw-0.30.1-r4.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-firewall/ufw/ufw-0.30.1-r4.ebuild,v 1.1 2012/02/28 11:42:22 scarabeus Exp $

EAPI=4
PYTHON_DEPEND="2:2.5"
SUPPORT_PYTHON_ABIS="1"
RESTRICT_PYTHON_ABIS="3.*"

inherit versionator bash-completion-r1 eutils linux-info distutils

MY_PV_12=$(get_version_component_range 1-2)
DESCRIPTION="A program used to manage a netfilter firewall"
HOMEPAGE="http://launchpad.net/ufw"
SRC_URI="http://launchpad.net/ufw/${MY_PV_12}/${PV}/+download/${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="examples"

DEPEND="sys-devel/gettext"
RDEPEND=">=net-firewall/iptables-1.4"

# tests fail; upstream bug: https://bugs.launchpad.net/ufw/+bug/815982
RESTRICT="test"

pkg_pretend() {
	local CONFIG_CHECK="~PROC_FS ~NETFILTER_XT_MATCH_COMMENT ~IP6_NF_MATCH_HL \
		~NETFILTER_XT_MATCH_LIMIT ~NETFILTER_XT_MATCH_MULTIPORT \
		~NETFILTER_XT_MATCH_RECENT ~NETFILTER_XT_MATCH_STATE"

	if kernel_is -ge 2 6 39; then
		CONFIG_CHECK+=" ~NETFILTER_XT_MATCH_ADDRTYPE"
	else
		CONFIG_CHECK+=" ~IP_NF_MATCH_ADDRTYPE"
	fi

	check_extra_config
}

pkg_setup() {
	python_pkg_setup
}

src_prepare() {
	# Allow to remove unnecessary build time dependency
	# on net-firewall/iptables.
	epatch "${FILESDIR}"/${PN}-dont-check-iptables.patch
	# Move files away from /lib/ufw.
	epatch "${FILESDIR}"/${PN}-move-path.patch
	# Allows correct build with SUPPORT_PYTHON_ABIS="1" (see comment in the file).
	epatch "${FILESDIR}"/${P}-python-abis.patch
	# Fixes usage with ufw-frontends (bug ref. inside the patch).
	epatch "${FILESDIR}"/${P}-encoding.patch
	# Set as enabled by default. User can enable or disable
	# the service by adding or removing it to/from a runlevel.
	sed -i 's/^ENABLED=no/ENABLED=yes/' conf/ufw.conf \
		|| die "sed failed (ufw.conf)"
}

src_install() {
	newconfd "${FILESDIR}"/ufw.confd ufw
	newinitd "${FILESDIR}"/ufw-2.initd ufw

	# users normally would want it
	insinto /usr/share/doc/${PF}/logging
	doins -r "${FILESDIR}"/syslog-ng

	insinto /usr/share/doc/${PF}/logging/rsyslog
	doins "${FILESDIR}"/rsyslog/*
	doins doc/rsyslog.example

	if use examples; then
		insinto /usr/share/doc/${PF}/examples
		doins examples/*
	fi
	distutils_src_install
	domo locales/mo/*.mo
	rm -r "${ED}"usr/share/${PN}/messages || die
	newbashcomp shell-completion/bash ${PN}
}

pkg_postinst() {
	distutils_pkg_postinst
	if path_exists -o "${EROOT}"lib/ufw/user{,6}.rules; then
		ewarn "Attention!"
		ewarn "User configuration from /lib/ufw is now placed in /etc/ufw/user."
		ewarn "Please stop ufw, copy .rules files from ${EROOT}lib/ufw"
		ewarn "to ${EROOT}etc/ufw/user/ and start ufw again."
	fi
	echo
	elog "Remember to enable ufw add it to your boot sequence:"
	elog "-- # ufw enable"
	elog "-- # rc-update add ufw boot"
	echo
	elog "If you want to keep ufw logs in a separate file, take a look at"
	elog "/usr/share/doc/${PF}/logging."
}