[gentoo-commits] gentoo-x86 commit in dev-util/ccache: ccache-3.1.3.ebuild ChangeLog

[Mike Frysinger (vapier)]

vapier      10/11/28 18:05:36

  Modified:             ChangeLog
  Added:                ccache-3.1.3.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha5/cvs/Linux x86_64)

Revision  Changes    Path
1.70                 dev-util/ccache/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/ccache/ChangeLog?rev=1.70&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/ccache/ChangeLog?rev=1.70&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/ccache/ChangeLog?r1=1.69&r2=1.70

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/ccache/ChangeLog,v
retrieving revision 1.69
retrieving revision 1.70
diff -u -r1.69 -r1.70
--- ChangeLog	21 Nov 2010 20:34:23 -0000	1.69
+++ ChangeLog	28 Nov 2010 18:05:36 -0000	1.70
@@ -1,6 +1,11 @@
 # ChangeLog for dev-util/ccache
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/ccache/ChangeLog,v 1.69 2010/11/21 20:34:23 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/ccache/ChangeLog,v 1.70 2010/11/28 18:05:36 vapier Exp $
+
+*ccache-3.1.3 (28 Nov 2010)
+
+  28 Nov 2010; Mike Frysinger <vapier@g.o> +ccache-3.1.3.ebuild:
+  Version bump.
 
 *ccache-3.1.2 (21 Nov 2010)
 



1.1                  dev-util/ccache/ccache-3.1.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/ccache/ccache-3.1.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/ccache/ccache-3.1.3.ebuild?rev=1.1&content-type=text/plain

Index: ccache-3.1.3.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/ccache/ccache-3.1.3.ebuild,v 1.1 2010/11/28 18:05:36 vapier Exp $

inherit multilib

DESCRIPTION="fast compiler cache"
HOMEPAGE="http://ccache.samba.org/"
SRC_URI="http://samba.org/ftp/ccache/${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE=""

RDEPEND="sys-libs/zlib"
DEPEND="${RDEPEND}"

src_unpack() {
	unpack ${A}
	cd "${S}"
	# make sure we always use system zlib
	rm -rf zlib
}

src_install() {
	emake install DESTDIR="${D}" || die
	dodoc AUTHORS.txt MANUAL.txt NEWS.txt README.txt

	dobin "${FILESDIR}"/ccache-config || die
	dosed "/^LIBDIR=/s:lib:$(get_libdir):" /usr/bin/ccache-config

	diropts -m0700
	dodir /root/.ccache
	keepdir /root/.ccache
}

pkg_postinst() {
	"${ROOT}"/usr/bin/ccache-config --install-links
	"${ROOT}"/usr/bin/ccache-config --install-links ${CHOST}

	# nuke broken symlinks from previous versions that shouldn't exist
	rm -f "${ROOT}/usr/$(get_libdir)/ccache/bin/${CHOST}-cc"
	[[ -d "${ROOT}/usr/$(get_libdir)/ccache.backup" ]] && \
		rm -rf "${ROOT}/usr/$(get_libdir)/ccache.backup"

	elog "To use ccache with **non-Portage** C compiling, add"
	elog "/usr/$(get_libdir)/ccache/bin to the beginning of your path, before /usr/bin."
	elog "Portage 2.0.46-r11+ will automatically take advantage of ccache with"
	elog "no additional steps.  If this is your first install of ccache, type"
	elog "something like this to set a maximum cache size of 2GB:"
	elog "# ccache -M 2G"
	elog
	elog "If you are upgrading from an older version than 3.x you should clear"
	elog "all of your caches like so:"
	elog "# CCACHE_DIR='${CCACHE_DIR:-${PORTAGE_TMPDIR}/ccache}' ccache -C"
}