[gentoo-commits] repo/gentoo:master commit in: media-sound/quodlibet/

[Miroslav Šulc]

commit:     5a963420f1ac9458d43392d41603b075857f102f
Author:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
AuthorDate: Wed Mar 30 06:34:20 2022 +0000
Commit:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
CommitDate: Wed Mar 30 06:34:36 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5a963420

media-sound/quodlibet: bump to 4.5.0

eapi8, added python3_10, changed to xdg, fixed desktop file location

Signed-off-by: Miroslav Šulc <fordfrog <AT> gentoo.org>

 media-sound/quodlibet/Manifest               |  1 +
 media-sound/quodlibet/quodlibet-4.5.0.ebuild | 58 ++++++++++++++++++++++++++++
 2 files changed, 59 insertions(+)

diff --git a/media-sound/quodlibet/Manifest b/media-sound/quodlibet/Manifest
index 1548175f9f99..b6fdddc08267 100644
--- a/media-sound/quodlibet/Manifest
+++ b/media-sound/quodlibet/Manifest
@@ -1 +1,2 @@
 DIST quodlibet-4.4.0.tar.gz 5126584 BLAKE2B b0d69ccacd009709148580619bdbafafb0c76acef791ab0025eda687cab4886b90f2d44fb6c37de80481e976ef4af466d209f7a7c6c53fc6794c26baa25d7bc0 SHA512 3a3c88c9283c3e14ee8b3504a9be9616a7773ce6819e832a76e1f926f9a1f86bbc68ae2dd98a2cf292ebc48216aca6e8a29e32f10d26b176effb62377183d13e
+DIST quodlibet-4.5.0.tar.gz 5585193 BLAKE2B e0b5ac89cc9fc8cab9beec3e32fe781b70d2704ae1f0304d0dd0250fb0d43ec0601a84c3940d143363e7294e68c5b5aa1bcf483ee0cd196fe0d61deb5da52b5a SHA512 4adc96b036bead26e8a0039bc0ecfa5e0a7a660647dd757afcb68887922fbb8c79f4ba3ae70f6870c17efc43da91a57f2050c15f7181317a1bfa1f841ddb91fe

diff --git a/media-sound/quodlibet/quodlibet-4.5.0.ebuild b/media-sound/quodlibet/quodlibet-4.5.0.ebuild
new file mode 100644
index 000000000000..ec3742406186
--- /dev/null
+++ b/media-sound/quodlibet/quodlibet-4.5.0.ebuild
@@ -0,0 +1,58 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8..10} )
+DISTUTILS_USE_SETUPTOOLS=no
+inherit distutils-r1 xdg
+
+DESCRIPTION="audio library tagger, manager, and player for GTK+"
+HOMEPAGE="https://quodlibet.readthedocs.io/"
+SRC_URI="https://github.com/${PN}/${PN}/archive/release-${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="+dbus gstreamer +udev"
+
+RDEPEND="dev-libs/keybinder:3[introspection]
+	dev-python/feedparser[${PYTHON_USEDEP}]
+	dev-python/pygobject:3[${PYTHON_USEDEP}]
+	>=media-libs/mutagen-1.32[${PYTHON_USEDEP}]
+	net-libs/libsoup[introspection]
+	x11-libs/gtk+[introspection]
+	gstreamer? (
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-base:1.0
+		media-libs/gst-plugins-good:1.0
+		media-plugins/gst-plugins-meta:1.0
+		)
+	!gstreamer? ( media-libs/xine-lib )
+	dbus? (
+		app-misc/media-player-info
+		dev-python/dbus-python[${PYTHON_USEDEP}]
+		)
+	udev? ( virtual/udev )"
+DEPEND="dev-util/intltool"
+
+S="${WORKDIR}/${PN}-release-${PV}"
+
+src_prepare() {
+	local qlconfig=quodlibet/config.py
+
+	if ! use gstreamer; then
+		sed -i -e '/backend/s:gstbe:xinebe:' ${qlconfig} || die
+	fi
+
+	sed -i -e '/gst_pipeline/s:"":"alsasink":' ${qlconfig} || die
+
+	distutils-r1_src_prepare
+}
+
+src_install() {
+	distutils-r1_src_install
+	dodoc README.rst
+
+	# fix location of desktop file
+	mv "${ED}/usr/share/appdata" "${ED}/usr/share/metainfo" || die "Failed to fix desktop file location"
+}