[gentoo-commits] repo/gentoo:master commit in: dev-libs/amdgpu-pro-opencl/

[Marek Szuba]

commit:     1f58f4a0d43c422105595eecca1ab7d926128960
Author:     Marek Szuba <marecki <AT> gentoo <DOT> org>
AuthorDate: Wed Aug  2 19:44:50 2017 +0000
Commit:     Marek Szuba <marecki <AT> gentoo <DOT> org>
CommitDate: Wed Aug  2 19:45:22 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1f58f4a0

dev-libs/amdgpu-pro-opencl: bump to 17.30-458935

Package-Manager: Portage-2.3.6, Repoman-2.3.1

 dev-libs/amdgpu-pro-opencl/Manifest                |  1 +
 .../amdgpu-pro-opencl-17.30.458935.ebuild          | 77 ++++++++++++++++++++++
 2 files changed, 78 insertions(+)

diff --git a/dev-libs/amdgpu-pro-opencl/Manifest b/dev-libs/amdgpu-pro-opencl/Manifest
index 728950f3c6a..9982e892fe7 100644
--- a/dev-libs/amdgpu-pro-opencl/Manifest
+++ b/dev-libs/amdgpu-pro-opencl/Manifest
@@ -1 +1,2 @@
 DIST amdgpu-pro-17.10-429170.tar.xz 121382128 SHA256 cb1ea7f9756f197a976138d2c00f239ae4ee43b839fbb1ea57f8770957d4afd6 SHA512 2d9d0a97478564e259dc8494083df8dc13e3bc664384978aff369070b1105703653d8dc4dca38e94dc8bdf3ddfb5c6f4de39cec5a9b263423de8fb91fd0117c6 WHIRLPOOL 1e07579d2c9d5d8a796973658cbb6627418b133a630ca5e977f93da0d27b900da2078d2ea8b35a13071b0b05e3d5e7f47e17d61042dcca60709f6599c18380a2
+DIST amdgpu-pro-17.30-458935.tar.xz 393634984 SHA256 3652a5c9476a650a3e3cd89bcd7ac119ed7d16a570501eeeea6a902cbc6f9488 SHA512 3f517ce13e102edb820f8f9538e0894c794d767816f99774fbfec342adb6912712664f069db2542412baabb24ee198204f38757407c29aff238ed1772dc3caab WHIRLPOOL 29a5b06657767255ace0529467ca56a904a021254f7dab854b1fd3ac843108ac346d3c4e97e10ef53844152de116581bff7c3aa8f4f066a08becb88e59918da3

diff --git a/dev-libs/amdgpu-pro-opencl/amdgpu-pro-opencl-17.30.458935.ebuild b/dev-libs/amdgpu-pro-opencl/amdgpu-pro-opencl-17.30.458935.ebuild
new file mode 100644
index 00000000000..6d8da00df44
--- /dev/null
+++ b/dev-libs/amdgpu-pro-opencl/amdgpu-pro-opencl-17.30.458935.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit unpacker versionator
+
+SUPER_PN='amdgpu-pro'
+MY_PV=$(replace_version_separator 2 '-')
+
+DESCRIPTION="Proprietary OpenCL implementation for AMD GPUs"
+HOMEPAGE="https://support.amd.com/en-us/kb-articles/Pages/AMDGPU-PRO-Driver-for-Linux-Release-Notes.aspx"
+SRC_URI="${SUPER_PN}-${MY_PV}.tar.xz"
+
+LICENSE="AMD-GPU-PRO-EULA"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RESTRICT="mirror fetch strip"
+
+DEPEND="dev-util/patchelf"
+RDEPEND="dev-libs/ocl-icd"
+
+QA_PREBUILT="/opt/${SUPER_PN}/lib*/*"
+
+S="${WORKDIR}/${SUPER_PN}-${MY_PV}"
+
+pkg_nofetch() {
+	local pkgver=$(get_version_component_range 1-2)
+	einfo "Please download the AMDGPU-Pro Driver ${pkgver} for Ubuntu from"
+	einfo "    ${HOMEPAGE}"
+	einfo "The archive should then be placed into ${DISTDIR}."
+}
+
+src_unpack() {
+	default
+
+	local libdrm_ver="2.4.70"
+	local patchlevel=$(get_version_component_range 3)
+	cd "${S}" || die
+	unpack_deb opencl-${SUPER_PN}-icd_${MY_PV}_amd64.deb
+	unpack_deb libdrm-${SUPER_PN}-amdgpu1_${libdrm_ver}-${patchlevel}_amd64.deb
+}
+
+src_prepare() {
+	default
+
+	cd "${S}/opt/${SUPER_PN}/lib/x86_64-linux-gnu" || die
+	patchelf --set-rpath '$ORIGIN' libamdocl64.so || die "Failed to fix library rpath"
+}
+
+src_install() {
+
+	into "/opt/${SUPER_PN}"
+	dolib opt/${SUPER_PN}/lib/x86_64-linux-gnu/*
+
+	insinto /etc/OpenCL/vendors/
+	echo "/opt/${SUPER_PN}/$(get_libdir)/libamdocl64.so" > "${SUPER_PN}.icd" || die "Failed to generate ICD file"
+	doins "${SUPER_PN}.icd"
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		ewarn "Please note that using proprietary OpenCL libraries together with the"
+		ewarn "Open Source amdgpu stack is not officially supported by AMD. Do not ask them"
+		ewarn "for support in case of problems with this package."
+		ewarn ""
+		ewarn "Furthermore, if you have the whole AMDGPU-Pro stack installed this package"
+		ewarn "will almost certainly conflict with it. This might change once AMDGPU-Pro"
+		ewarn "has become officially supported by Gentoo."
+	fi
+
+	elog "AMD OpenCL driver relies on dev-libs/ocl-icd to work. To enable it, please run"
+	elog ""
+	elog "    eselect opencl set ocl-icd"
+	elog ""
+}