[gentoo-commits] repo/gentoo:master commit in: sys-libs/libosinfo/

[Mart Raudsepp]

commit:     05873a71376180c0070e85a3f4b4b57c7382706f
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Sun Mar 31 07:04:23 2019 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Sun Mar 31 07:04:23 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=05873a71

sys-libs/libosinfo: bump to 1.4.0

Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 sys-libs/libosinfo/Manifest               |  1 +
 sys-libs/libosinfo/libosinfo-1.4.0.ebuild | 62 +++++++++++++++++++++++++++++++
 2 files changed, 63 insertions(+)

diff --git a/sys-libs/libosinfo/Manifest b/sys-libs/libosinfo/Manifest
index 1aa0a38c917..74cc06728b6 100644
--- a/sys-libs/libosinfo/Manifest
+++ b/sys-libs/libosinfo/Manifest
@@ -1,2 +1,3 @@
 DIST libosinfo-1.2.0.tar.gz 916787 BLAKE2B 652910ca1e70071d88adb771e458f0c19159a772eec1178c94ea5f65c5045bb00e4b1354b1ce4229d28821b6b1557424e419c1505b721883731a36b0761a1b5d SHA512 d98a107a08c5e2cddd746631b3ceac4278184ea5561ad2372d772b8ae253dc1363f217778d105387e5b5c5e86be9607668aa94929ad9b4ee48ab7abf50fb6a01
 DIST libosinfo-1.3.0.tar.gz 977090 BLAKE2B fdfe29dbf01e00608374baf2fb6b5257dff5eb8870375769c572b4dacf2bd7f6e1907083e6c36bfb1a76e9e994bb19b093c6fc63ce8e7170ab8073f6d53c573b SHA512 652f2927e901afe9772d4f28be5bb59802cf149c6c8eea4256a999f5012bfaaac81b51c56a94b32c82ef3462ff1f26baf84bf9329e5b1136e2b49ed4a0658982
+DIST libosinfo-1.4.0.tar.gz 1075852 BLAKE2B 93129a29ea3a1a3aa69fdceabcf6f41393c8e1dd3f92872d97dcc23a3316b0e4d16ede104da9a3ea0c49d352ba88e05ba5a38806c8c039fe92217e4b6e3140ab SHA512 531b7acf811add53252e52917f8b13b409dbe7a4bc5837dcbe34e729b0f294e760d5a57c5c1c56f1f65217b7fc6e285a56a6fa49d36f02cf696b7cc181db1fe5

diff --git a/sys-libs/libosinfo/libosinfo-1.4.0.ebuild b/sys-libs/libosinfo/libosinfo-1.4.0.ebuild
new file mode 100644
index 00000000000..2e817e59d14
--- /dev/null
+++ b/sys-libs/libosinfo/libosinfo-1.4.0.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2 udev vala
+
+DESCRIPTION="GObject library for managing information about real and virtual OSes"
+HOMEPAGE="https://libosinfo.org/"
+SRC_URI="https://releases.pagure.org/libosinfo/${P}.tar.gz"
+
+LICENSE="GPL-2+ LGPL-2.1+"
+SLOT="0"
+
+IUSE="+introspection +vala test"
+REQUIRED_USE="vala? ( introspection )"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+# Unsure about osinfo-db-tools rdep, but at least fedora does it too
+RDEPEND="
+	>=dev-libs/glib-2.38.0:2
+	>=dev-libs/libxml2-2.6.0
+	>=dev-libs/libxslt-1.0.0
+	sys-apps/hwids[pci,usb]
+	sys-apps/osinfo-db-tools
+	sys-apps/osinfo-db
+	introspection? ( >=dev-libs/gobject-introspection-0.9.7:= )
+"
+# perl dep is for pod2man, and configure.ac checks for it too now
+# Tests can use net-misc/curl, but they are automatically skipped if curl is not found, and
+# if it is found, then those tests are skipped at runtime if LIBOSINFO_NETWORK_TESTS is unset.
+# Due to potential network-sandbox we aren't enabling them (and one of them fails at 1.2.0).
+DEPEND="${RDEPEND}
+	dev-lang/perl
+	dev-libs/gobject-introspection-common
+	dev-util/glib-utils
+	>=dev-util/gtk-doc-am-1.10
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	test? (
+		>=sys-apps/osinfo-db-20190218
+	)
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	gnome2_src_prepare
+	use vala && vala_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--with-usb-ids-path=/usr/share/misc/usb.ids \
+		--with-pci-ids-path=/usr/share/misc/pci.ids \
+		--disable-static \
+		$(use_enable test tests) \
+		$(use_enable introspection) \
+		$(use_enable vala) \
+		--disable-coverage
+}