[gentoo-commits] repo/gentoo:master commit in: dev-python/tagpy/

[Sam James]

commit:     05d2ea32ee1fd071ef5f93cbfef593f829dac08a
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Tue May 31 00:33:08 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Tue May 31 01:56:41 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=05d2ea32

dev-python/tagpy: update EAPI 7 -> 8

Closes: https://bugs.gentoo.org/845891
Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-python/tagpy/tagpy-2018.1-r3.ebuild | 50 +++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

diff --git a/dev-python/tagpy/tagpy-2018.1-r3.ebuild b/dev-python/tagpy/tagpy-2018.1-r3.ebuild
new file mode 100644
index 000000000000..fdcb87a4585e
--- /dev/null
+++ b/dev-python/tagpy/tagpy-2018.1-r3.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+DISTUTILS_IN_SOURCE_BUILD=1
+inherit edo distutils-r1
+
+DESCRIPTION="Python Bindings for TagLib"
+HOMEPAGE="
+	https://mathema.tician.de//software/tagpy
+	https://pypi.org/project/tagpy/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="examples"
+
+RDEPEND="
+	>=dev-libs/boost-1.70:=[python,threads(+),${PYTHON_USEDEP}]
+	>=media-libs/taglib-1.8"
+DEPEND="${RDEPEND}"
+
+PATCHES=( "${FILESDIR}"/${P}-taglib-1.8.patch )
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	cp "${FILESDIR}"/${P}-readme.rst README.rst || die
+	distutils-r1_python_prepare_all
+}
+
+python_configure() {
+	local boostpy_ver="${EPYTHON#python}"
+
+	edo "${EPYTHON}" configure.py \
+		--taglib-inc-dir="${ESYSROOT}"/usr/include/taglib \
+		--boost-python-libname="boost_python${boostpy_ver/\.}"
+}
+
+python_install_all() {
+	if use examples; then
+		docinto examples
+		dodoc -r test/.
+	fi
+
+	distutils-r1_python_install_all
+}