[gentoo-commits] gentoo-x86 commit in sci-mathematics/flint: flint-2.4.5.ebuild ChangeLog

[Thomas Kahle (tomka)]

tomka       15/04/02 12:27:59

  Modified:             ChangeLog
  Added:                flint-2.4.5.ebuild
  Log:
  Bump to 2.4.5 (542682)
  
  (Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key 565C32BC)

Revision  Changes    Path
1.11                 sci-mathematics/flint/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-mathematics/flint/ChangeLog?rev=1.11&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-mathematics/flint/ChangeLog?rev=1.11&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-mathematics/flint/ChangeLog?r1=1.10&r2=1.11

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-mathematics/flint/ChangeLog,v
retrieving revision 1.10
retrieving revision 1.11
diff -u -r1.10 -r1.11
--- ChangeLog	25 Nov 2014 23:27:26 -0000	1.10
+++ ChangeLog	2 Apr 2015 12:27:59 -0000	1.11
@@ -1,6 +1,11 @@
 # ChangeLog for sci-mathematics/flint
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-mathematics/flint/ChangeLog,v 1.10 2014/11/25 23:27:26 hasufell Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sci-mathematics/flint/ChangeLog,v 1.11 2015/04/02 12:27:59 tomka Exp $
+
+*flint-2.4.5 (02 Apr 2015)
+
+  02 Apr 2015; Thomas Kahle <tomka@g.o> +flint-2.4.5.ebuild:
+  Bump to 2.4.5 (542682)
 
   25 Nov 2014; Julian Ospald <hasufell@g.o> metadata.xml:
   drop maintainership



1.1                  sci-mathematics/flint/flint-2.4.5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-mathematics/flint/flint-2.4.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-mathematics/flint/flint-2.4.5.ebuild?rev=1.1&content-type=text/plain

Index: flint-2.4.5.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-mathematics/flint/flint-2.4.5.ebuild,v 1.1 2015/04/02 12:27:59 tomka Exp $

EAPI="5"

inherit eutils multilib toolchain-funcs

DESCRIPTION="Fast Library for Number Theory"
HOMEPAGE="http://www.flintlib.org/"
SRC_URI="http://www.flintlib.org/${P}.tar.gz"

RESTRICT="mirror"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc gc ntl static-libs test"

RDEPEND="dev-libs/gmp
	dev-libs/mpfr
	gc? ( dev-libs/boehm-gc )
	ntl? ( dev-libs/ntl )"
DEPEND="${RDEPEND}
	doc? (
		app-text/texlive-core
		dev-texlive/texlive-latex
		dev-texlive/texlive-latexextra
	)"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-2.4.3-libdir.patch \
		"${FILESDIR}"/${PN}-2.4.3-whitespaces.patch \
		"${FILESDIR}"/${PN}-2.4.3-cflags-ldflags.patch \
		"${FILESDIR}"/${PN}-2.4.4-test.patch
}

src_configure() {
	./configure \
		--prefix="${EPREFIX}/usr" \
		--with-gmp="${EPREFIX}/usr" \
		--with-mpfr="${EPREFIX}/usr" \
		$(usex ntl "--with-ntl=${EPREFIX}/usr" "") \
		$(use_enable static-libs static) \
		$(usex gc "--with-gc=${EPREFIX}/usr" "") \
		CC=$(tc-getCC) \
		CXX=$(tc-getCXX) \
		AR=$(tc-getAR) \
		|| die
}

src_compile() {
	emake verbose

	if use doc ; then
		emake -C doc/latex
	fi
}

src_test() {
	emake AT= QUIET_CC= QUIET_CXX= QUIET_AR= check
}

src_install() {
	emake DESTDIR="${D}" LIBDIR="$(get_libdir)" install
	einstalldocs
	use doc && dodoc doc/latex/flint-manual.pdf
}