[gentoo-commits] gentoo-x86 commit in x11-misc/xaos: ChangeLog metadata.xml xaos-3.4-r1.ebuild

[Sebastien Fabbro (bicatali)]

bicatali    09/03/28 12:55:30

  Modified:             ChangeLog metadata.xml
  Added:                xaos-3.4-r1.ebuild
  Log:
  Fixed for forced stripping (bug #252099), png magic (bug #263310), added gtk driver, desktop files, and some patch from debian
  (Portage version: 2.2_rc27/cvs/Linux x86_64)

Revision  Changes    Path
1.29                 x11-misc/xaos/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-misc/xaos/ChangeLog?rev=1.29&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-misc/xaos/ChangeLog?rev=1.29&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-misc/xaos/ChangeLog?r1=1.28&r2=1.29

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-misc/xaos/ChangeLog,v
retrieving revision 1.28
retrieving revision 1.29
diff -u -r1.28 -r1.29
--- ChangeLog	31 Jul 2008 22:36:54 -0000	1.28
+++ ChangeLog	28 Mar 2009 12:55:30 -0000	1.29
@@ -1,6 +1,15 @@
 # ChangeLog for x11-misc/xaos
-# Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/xaos/ChangeLog,v 1.28 2008/07/31 22:36:54 markusle Exp $
+# Copyright 2002-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/xaos/ChangeLog,v 1.29 2009/03/28 12:55:30 bicatali Exp $
+
+*xaos-3.4-r1 (28 Mar 2009)
+
+  28 Mar 2009; Sébastien Fabbro <bicatali@g.o>
+  +files/xaos-3.4-include.patch, +files/xaos-3.4-makefile.patch,
+  +files/xaos-3.4-png.patch, +files/xaos-3.4-x11.patch, +files/xaos.png,
+  metadata.xml, +xaos-3.4-r1.ebuild:
+  Fixed for forced stripping (bug #252099), png magic (bug #263310), added
+  gtk driver, desktop files, and some patch from debian
 
   31 Jul 2008; Markus Dittrich <markusle@g.o> xaos-3.4.ebuild:
   Force the use of sci-libs/gsl to avoid accidental generation of x86



1.2                  x11-misc/xaos/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-misc/xaos/metadata.xml?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-misc/xaos/metadata.xml?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-misc/xaos/metadata.xml?r1=1.1&r2=1.2

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-misc/xaos/metadata.xml,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- metadata.xml	8 Jan 2004 02:42:13 -0000	1.1
+++ metadata.xml	28 Mar 2009 12:55:30 -0000	1.2
@@ -2,4 +2,12 @@
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
 <herd>sci</herd>
+<longdescription lang="en">
+  XaoS is a fast, portable real-time interactive fractal zoomer. It
+  displays the Mandelbrot set (among other escape time fractals) and
+  allows you zoom smoothly into the fractal. Various coloring modes are
+  provided for both the points inside and outside the selected set. XaoS
+  supports switching between Julia and Mandelbrot fractal types and
+  on-the-fly plane switching.
+</longdescription>
 </pkgmetadata>



1.1                  x11-misc/xaos/xaos-3.4-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-misc/xaos/xaos-3.4-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-misc/xaos/xaos-3.4-r1.ebuild?rev=1.1&content-type=text/plain

Index: xaos-3.4-r1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-misc/xaos/xaos-3.4-r1.ebuild,v 1.1 2009/03/28 12:55:30 bicatali Exp $

EAPI=2
inherit eutils autotools

MY_PN=XaoS
MY_P=${MY_PN}-${PV}

DESCRIPTION="A very fast real-time fractal zoomer"
HOMEPAGE="http://xaos.sf.net/"
SRC_URI="mirror://sourceforge/xaos/${MY_P}.tar.gz"

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~amd64 ~ppc ~sparc ~x86"
IUSE="aalib doc gtk nls png svga threads X"

RDEPEND="sys-libs/zlib
	sci-libs/gsl
	aalib? ( media-libs/aalib )
	gtk? ( >=x11-libs/gtk+-2 )
	png? ( media-libs/libpng )
	svga? ( media-libs/svgalib )
	X? ( x11-libs/libX11
		 x11-libs/libXxf86dga
		 x11-libs/libXext
		 x11-libs/libXxf86vm )"
# xaos has ggi support, but it doesn't build
#	ggi?   ( media-libs/libggi )

DEPEND="${RDEPEND}
	dev-util/pkgconfig
	doc? ( virtual/latex-base )
	X? ( x11-proto/xf86vidmodeproto
		 x11-proto/xextproto
		 x11-proto/xf86dgaproto
		 x11-proto/xproto )"

S="${WORKDIR}/${MY_P}"

src_prepare() {
	epatch "${FILESDIR}"/${P}-makefile.patch
	epatch "${FILESDIR}"/${P}-png.patch
	epatch "${FILESDIR}"/${P}-include.patch
	epatch "${FILESDIR}"/${P}-x11.patch
	eautoreconf
}

src_configure() {
	# use gsl and not nasm (see bug #233318)
	econf \
		--with-sffe=yes \
		--with-ggi-driver=no \
		--with-i386asm=no \
		--with-gsl=yes \
		$(use_enable nls) \
		$(use_with png) \
		$(use_with aalib aa-driver) \
		$(use_with gtk gtk-driver) \
		$(use_with svga svga-driver) \
		$(use_with threads pthread) \
		$(use_with X x11-driver) \
		$(use_with X x)
}

src_compile() {
	emake || die "emake failed"
	if use doc; then
		cd "${S}"/doc
		emake xaos.dvi || die
		dvipdf xaos.dvi || die
		cd "${S}"/help
		emake html || die
	fi
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc ChangeLog* TODO RELEASE_NOTES \
		doc/README{,.bugs} doc/{AUTHORS,PROBLEMS,SPONSORS}
	if use doc; then
		insinto /usr/share/doc/${PF}
		doins doc/xaos.pdf || die
		dohtml help/* || die
	fi
	local driver="x11"
	use gtk && driver="\"GTK+ Driver\""
	make_desktop_entry "xaos -driver ${driver}" "XaoS Fractal Zoomer" \
		xaos "Application;Education;Math;Graphics;"
	doicon "${FILESDIR}"/${PN}.png
}