[gentoo-commits] gentoo-x86 commit in dev-libs/openct: metadata.xml openct-0.6.20-r2.ebuild ChangeLog openct-0.6.20-r1.ebuild

[Diego Petteno (flameeyes)]

flameeyes    12/06/19 13:56:54

  Modified:             metadata.xml ChangeLog
  Added:                openct-0.6.20-r2.ebuild
  Removed:              openct-0.6.20-r1.ebuild
  Log:
  Update init script to use checkpath instead of using keepdir in the ebuild; add an udev USE flag to not install the rules; use EAPI=4; use append-cppflags for -DDEBUG_IFDH.
  
  (Portage version: 2.2.0_alpha110/cvs/Linux x86_64)

Revision  Changes    Path
1.7                  dev-libs/openct/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/openct/metadata.xml?rev=1.7&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/openct/metadata.xml?rev=1.7&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/openct/metadata.xml?r1=1.6&r2=1.7

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/openct/metadata.xml,v
retrieving revision 1.6
retrieving revision 1.7
diff -u -r1.6 -r1.7
--- metadata.xml	13 Apr 2011 18:07:51 -0000	1.6
+++ metadata.xml	19 Jun 2012 13:56:54 -0000	1.7
@@ -11,5 +11,9 @@
     <flag name="debug">
       Add debug output to the driver library for pcsc-lite.
     </flag>
+
+    <flag name="udev">
+      Install rules for <pkg>sys-fs/udev</pkg> to auto-start openct.
+    </flag>
   </use>
 </pkgmetadata>



1.98                 dev-libs/openct/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/openct/ChangeLog?rev=1.98&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/openct/ChangeLog?rev=1.98&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/openct/ChangeLog?r1=1.97&r2=1.98

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/openct/ChangeLog,v
retrieving revision 1.97
retrieving revision 1.98
diff -u -r1.97 -r1.98
--- ChangeLog	6 Jun 2012 03:45:11 -0000	1.97
+++ ChangeLog	19 Jun 2012 13:56:54 -0000	1.98
@@ -1,6 +1,14 @@
 # ChangeLog for dev-libs/openct
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/openct/ChangeLog,v 1.97 2012/06/06 03:45:11 zmedico Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/openct/ChangeLog,v 1.98 2012/06/19 13:56:54 flameeyes Exp $
+
+*openct-0.6.20-r2 (19 Jun 2012)
+
+  19 Jun 2012; Diego E. Pettenò <flameeyes@g.o> +files/openct.rc.2,
+  +openct-0.6.20-r2.ebuild, -openct-0.6.20-r1.ebuild, metadata.xml:
+  Update init script to use checkpath instead of using keepdir in the ebuild;
+  add an udev USE flag to not install the rules; use EAPI=4; use append-cppflags
+  for -DDEBUG_IFDH.
 
   06 Jun 2012; Zac Medico <zmedico@g.o> openct-0.6.20-r1.ebuild,
   openct-0.6.20.ebuild:



1.1                  dev-libs/openct/openct-0.6.20-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/openct/openct-0.6.20-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/openct/openct-0.6.20-r2.ebuild?rev=1.1&content-type=text/plain

Index: openct-0.6.20-r2.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/openct/openct-0.6.20-r2.ebuild,v 1.1 2012/06/19 13:56:54 flameeyes Exp $

EAPI=4

inherit eutils flag-o-matic multilib user

DESCRIPTION="library for accessing smart card terminals"
HOMEPAGE="http://www.opensc-project.org/openct/"

SRC_URI="http://www.opensc-project.org/files/${PN}/${P}.tar.gz"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"

LICENSE="LGPL-2.1"
SLOT="0"
IUSE="doc pcsc-lite usb debug +udev"

# libtool is required at runtime for libltdl
RDEPEND="pcsc-lite? ( >=sys-apps/pcsc-lite-1.7.2-r1 )
	usb? ( virtual/libusb:0 )
	sys-devel/libtool"

DEPEND="${RDEPEND}
	doc? ( app-doc/doxygen )"

# udev is not required at all at build-time as it's only a matter of
# installing the rules; add openrc for the checkpath used in the new
# init script
RDEPEND="${RDEPEND}
	udev? ( >=sys-fs/udev-096 )
	sys-apps/openrc"

pkg_setup() {
	enewgroup openct
	enewuser openctd
}

src_configure() {
	use debug && append-cppflags -DDEBUG_IFDH

	econf \
		--docdir="/usr/share/doc/${PF}" \
		--htmldir="/usr/share/doc/${PF}/html" \
		--localstatedir=/var \
		--with-udev="/$(get_libdir)/udev" \
		--enable-non-privileged \
		--with-daemon-user=openctd \
		--with-daemon-groups=usb \
		--enable-shared --disable-static \
		$(use_enable doc) \
		$(use_enable doc api-doc) \
		$(use_enable pcsc-lite pcsc) \
		$(use_with pcsc-lite bundle /usr/$(get_libdir)/readers/usb) \
		$(use_enable usb)
}

src_install() {
	emake DESTDIR="${D}" install
	find "${D}" -name '*.la' -delete
	rm "${D}"/usr/$(get_libdir)/openct-ifd.*

	if use udev; then
		insinto /lib/udev/rules.d/
		newins etc/openct.udev 70-openct.rules
	fi

	newinitd "${FILESDIR}"/openct.rc.2 openct
}

pkg_postinst() {
	elog
	elog "You need to edit /etc/openct.conf to enable serial readers."
	elog
	elog "You should add \"openct\" to your default runlevel. To do so"
	elog "type \"rc-update add openct default\"."
	elog
	elog "You need to be a member of the (newly created) group openct to"
	elog "access smart card readers connected to this system. Set users'"
	elog "groups with usermod -G.  root always has access."
	elog
}