[gentoo-commits] repo/gentoo:master commit in: dev-util/scanmem/

[Lars Wendler]

commit:     7fac6e5a953a57866dc7c3928a3d16892513dda9
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Thu Aug  1 03:25:34 2019 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Thu Aug  1 03:25:55 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7fac6e5a

dev-util/scanmem: Bump to version 0.17

Closes: https://bugs.gentoo.org/645536
Package-Manager: Portage-2.3.69, Repoman-2.3.16
Signed-off-by: Lars Wendler <polynomial-c <AT> gentoo.org>

 dev-util/scanmem/Manifest            |  1 +
 dev-util/scanmem/scanmem-0.17.ebuild | 58 ++++++++++++++++++++++++++++++++++++
 2 files changed, 59 insertions(+)

diff --git a/dev-util/scanmem/Manifest b/dev-util/scanmem/Manifest
index ae50e589dbd..df1de638310 100644
--- a/dev-util/scanmem/Manifest
+++ b/dev-util/scanmem/Manifest
@@ -1 +1,2 @@
 DIST scanmem-0.16.1.tar.gz 202133 BLAKE2B bb07234aaf1f93dba5f7feb0af0efcdadb7cd7cabfce2d62f19da01ba947cf9f4ba91024db2379e218b91953679a77080a4fa711ceaca659ac7b3f01645e3f93 SHA512 5e0a97e020a8a392aed75e2654cc6bcfad68590b9caab43444e57c3180be45ce1269f5acb02355bee57ff8bb5b9349b4f65e0fe96655206a812ea645796b153b
+DIST scanmem-0.17.tar.gz 220489 BLAKE2B b1ae07f96fd736e9ca6a5d55ad2d6b06b7d0dc4828915e0f2adaa2d58b053d9734ccd7425fb5391289249f838773cf3f9a81dbe76bacd42f41203d27dcffed05 SHA512 6d74f3d1d3492d41cabc342cfd1189815536dcbd57857d8a92e05c5dcaebcb9b1df886aee706c56eaf3344737070ea0fe852eef164ef3fe7907f66c626d8523e

diff --git a/dev-util/scanmem/scanmem-0.17.ebuild b/dev-util/scanmem/scanmem-0.17.ebuild
new file mode 100644
index 00000000000..542361fbb18
--- /dev/null
+++ b/dev-util/scanmem/scanmem-0.17.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python{2_7,3_{5,6,7}} )
+
+inherit autotools eutils python-single-r1
+
+DESCRIPTION="Locate and modify variables in executing processes"
+HOMEPAGE="https://github.com/scanmem/scanmem"
+SRC_URI="https://github.com/scanmem/scanmem/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gui static-libs"
+
+DEPEND="sys-libs/readline:0="
+RDEPEND="${DEPEND}
+	gui? (
+		${PYTHON_DEPS}
+		dev-python/pygobject:3
+		sys-auth/polkit
+	)"
+
+REQUIRED_USE="gui? ( ${PYTHON_REQUIRED_USE} )"
+
+pkg_setup() {
+	use gui && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	sed -i "/CFLAGS/d" Makefile.am || die
+
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--with-readline
+		$(use_enable gui)
+		$(use_enable static-libs static)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	if use gui ; then
+		docinto gui
+		dodoc gui/{README,TODO}
+		python_fix_shebang "${ED}"
+	fi
+	find "${ED}" -type f -name "*.la" -delete || die
+}