[gentoo-commits] repo/gentoo:master commit in: x11-libs/libxkbcommon/

[Lars Wendler]

commit:     fb85029427f30e8c88ee8f0681300f46a0ab3951
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Tue Jun 30 08:20:44 2020 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Tue Jun 30 08:21:19 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=fb850294

x11-libs/libxkbcommon: Revbump to re-add "static-libs" USE flag

Package-Manager: Portage-2.3.103, Repoman-2.3.23
Signed-off-by: Lars Wendler <polynomial-c <AT> gentoo.org>

 .../libxkbcommon/libxkbcommon-0.10.0-r1.ebuild     | 56 ++++++++++++++++++++++
 1 file changed, 56 insertions(+)

diff --git a/x11-libs/libxkbcommon/libxkbcommon-0.10.0-r1.ebuild b/x11-libs/libxkbcommon/libxkbcommon-0.10.0-r1.ebuild
new file mode 100644
index 00000000000..15fdecd2c42
--- /dev/null
+++ b/x11-libs/libxkbcommon/libxkbcommon-0.10.0-r1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+if [[ ${PV} = *9999* ]]; then
+	GIT_ECLASS="git-r3"
+	EGIT_REPO_URI="https://github.com/xkbcommon/${PN}"
+else
+	SRC_URI="https://xkbcommon.org/download/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86"
+fi
+
+inherit meson multilib-minimal ${GIT_ECLASS}
+
+DESCRIPTION="keymap handling library for toolkits and window systems"
+HOMEPAGE="https://xkbcommon.org/ https://github.com/xkbcommon/libxkbcommon/"
+LICENSE="MIT"
+IUSE="X doc static-libs test"
+RESTRICT="!test? ( test )"
+SLOT="0"
+
+BDEPEND="
+	sys-devel/bison
+	doc? ( app-doc/doxygen )"
+RDEPEND="X? ( >=x11-libs/libxcb-1.10:=[${MULTILIB_USEDEP},xkb] )"
+DEPEND="${RDEPEND}
+	X? ( x11-base/xorg-proto )"
+
+src_unpack() {
+	default
+	[[ $PV = 9999* ]] && git-r3_src_unpack
+}
+
+multilib_src_configure() {
+	local emesonargs=(
+		-Ddefault_library="$(usex static-libs both shared)"
+		-Dxkb-config-root="${EPREFIX}/usr/share/X11/xkb"
+		-Denable-wayland=false # Demo applications
+		$(meson_use X enable-x11)
+		$(meson_use doc enable-docs)
+	)
+	meson_src_configure
+}
+
+multilib_src_compile() {
+	meson_src_compile
+}
+
+multilib_src_test() {
+	meson_src_test
+}
+
+multilib_src_install() {
+	meson_src_install
+}