[gentoo-commits] gentoo-x86 commit in sci-chemistry/openbabel: openbabel-2.2.3.ebuild ChangeLog

[Marcus Hanwell (cryos)]

cryos       09/08/01 15:22:51

  Modified:             ChangeLog
  Added:                openbabel-2.2.3.ebuild
  Log:
  Version bump.
  (Portage version: 2.2_rc33/cvs/Linux x86_64)

Revision  Changes    Path
1.28                 sci-chemistry/openbabel/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-chemistry/openbabel/ChangeLog?rev=1.28&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-chemistry/openbabel/ChangeLog?rev=1.28&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-chemistry/openbabel/ChangeLog?r1=1.27&r2=1.28

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-chemistry/openbabel/ChangeLog,v
retrieving revision 1.27
retrieving revision 1.28
diff -u -r1.27 -r1.28
--- ChangeLog	24 Jul 2009 19:00:34 -0000	1.27
+++ ChangeLog	1 Aug 2009 15:22:51 -0000	1.28
@@ -1,6 +1,11 @@
 # ChangeLog for sci-chemistry/openbabel
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/openbabel/ChangeLog,v 1.27 2009/07/24 19:00:34 cryos Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/openbabel/ChangeLog,v 1.28 2009/08/01 15:22:51 cryos Exp $
+
+*openbabel-2.2.3 (01 Aug 2009)
+
+  01 Aug 2009; Marcus D. Hanwell <cryos@g.o> +openbabel-2.2.3.ebuild:
+  Version bump.
 
 *openbabel-2.2.2-r1 (24 Jul 2009)
 



1.1                  sci-chemistry/openbabel/openbabel-2.2.3.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-chemistry/openbabel/openbabel-2.2.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-chemistry/openbabel/openbabel-2.2.3.ebuild?rev=1.1&content-type=text/plain

Index: openbabel-2.2.3.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/openbabel/openbabel-2.2.3.ebuild,v 1.1 2009/08/01 15:22:51 cryos Exp $

EAPI=1

inherit eutils

DESCRIPTION="interconverts file formats used in molecular modeling"
HOMEPAGE="http://openbabel.sourceforge.net/"
SRC_URI="mirror://sourceforge/openbabel/${P}.tar.gz"

KEYWORDS="~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
SLOT="0"
LICENSE="GPL-2"
IUSE="doc python swig"

RDEPEND="!sci-chemistry/babel
	>=dev-libs/libxml2-2.6.5
	sys-libs/zlib
	python? ( dev-lang/python )"

DEPEND="${RDEPEND}
	>=dev-libs/boost-1.35.0
	dev-lang/perl
	python? ( swig? ( >=dev-lang/swig-1.3.38 ) )
	doc? ( app-doc/doxygen )"

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}/${PN}-2.2.0-doxyfile.patch"
}

src_compile() {
	local swigconf=""
	if use swig; then
		swigconf="--enable-maintainer-mode"
	fi
	econf ${swigconf} || die "econf failed"
	emake || die "emake failed"
	if use doc ; then
		emake docs || die "make docs failed"
	fi
	if use swig; then
		emake scripts/python/openbabel_python.cpp \
			|| die "Failed to make SWIG python bindings"
	fi
	if use python; then
		cd "${S}/scripts/python"
		python setup.py build || die "Python build failed."
	fi
}

src_test() {
	emake check || die "make check failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "make install failed"
	# Now to install the Python bindings if necessary
	if use python; then
		cd "${S}/scripts/python"
		python ./setup.py install --root="${D}" --optimize=1 \
			|| die "Python bindings install failed"
		if use doc; then
			docinto python
			dodoc README
			docinto python/html
			dodoc *.html
		fi
	fi
	# And the documentation
	docinto
	cd "${S}"
	dodoc AUTHORS ChangeLog NEWS README THANKS
	cd doc
	dohtml *.html *.png
	dodoc *.inc README* *.inc *.mol2
	if use doc ; then
		dodir /usr/share/doc/${PF}/API/html
		insinto /usr/share/doc/${PF}/API/html
		cd API/html
		doins *
	fi
}