[gentoo-commits] repo/gentoo:master commit in: gnome-extra/sushi/

[Matt Turner]

commit:     36b7e73d42da07969b203c2be804888578d1a73a
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Sat Jul  2 03:12:38 2022 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Sat Jul  2 03:12:38 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=36b7e73d

gnome-extra/sushi: Version bump to 42.0

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 gnome-extra/sushi/Manifest          |  1 +
 gnome-extra/sushi/sushi-42.0.ebuild | 52 +++++++++++++++++++++++++++++++++++++
 2 files changed, 53 insertions(+)

diff --git a/gnome-extra/sushi/Manifest b/gnome-extra/sushi/Manifest
index 094e396a405b..87c0a3812b48 100644
--- a/gnome-extra/sushi/Manifest
+++ b/gnome-extra/sushi/Manifest
@@ -1 +1,2 @@
 DIST sushi-41.2.tar.xz 81252 BLAKE2B 811b02e0738aa3aba22d71545e888ec0334779591a56d6a28f3942d5d79fb9fece2fdffe0203757ba0806352584a50228b669fc0969f7ad75265fc40a3a1cd67 SHA512 c47b22a013fe31de6943d8af0f333b8050a8f0ecb0e827ea71666cd0175d5cc99336eb7ad96b21ba7aaf87f23d01b4f37a1ca8c0fc644fa89aa8960699b61f43
+DIST sushi-42.0.tar.xz 81668 BLAKE2B c37290fa9b2040d2f0a2e7519c654d5e78125b469c34eb24cfe6d9b37a9a00857215f149c33aa2d753734b33187f47da7bf73ebbe23ebad5551abffe20291a3d SHA512 203510d793be56b73e59553ead555d863919b4f8ebe9f0b46d01a887685fc0d210b81b739bd7dca221a91d3c9d4c2885b84851c2445a1ab00720e1fd2f59c817

diff --git a/gnome-extra/sushi/sushi-42.0.ebuild b/gnome-extra/sushi/sushi-42.0.ebuild
new file mode 100644
index 000000000000..a9e7cb992539
--- /dev/null
+++ b/gnome-extra/sushi/sushi-42.0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit gnome.org meson xdg
+
+DESCRIPTION="A quick previewer for Nautilus, the GNOME file manager"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/sushi"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~sparc ~x86"
+IUSE="office wayland +X"
+REQUIRED_USE="|| ( wayland X )"
+
+# Optional app-office/libreoffice support (OOo to pdf and then preview)
+DEPEND="
+	media-libs/libepoxy
+	>=app-text/evince-3.0[introspection]
+	media-libs/freetype:2
+	>=x11-libs/gdk-pixbuf-2.23.0[introspection]
+	>=dev-libs/glib-2.29.14:2
+	media-libs/gstreamer:1.0[introspection]
+	media-libs/gst-plugins-base:1.0[introspection]
+	>=x11-libs/gtk+-3.13.2:3[introspection,wayland?,X?]
+	>=x11-libs/gtksourceview-4.0.3:4[introspection]
+	>=media-libs/harfbuzz-0.9.9:=
+	>=dev-libs/gobject-introspection-1.54:=
+	>=net-libs/webkit-gtk-2.34:4[introspection]
+	>=dev-libs/gjs-1.40
+"
+RDEPEND="${DEPEND}
+	>=gnome-base/nautilus-3.1.90
+	media-plugins/gst-plugins-gtk:1.0[wayland?,X?]
+	office? ( app-office/libreoffice )
+"
+BDEPEND="
+	dev-util/glib-utils
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_configure() {
+	meson_src_configure \
+		$(meson_feature wayland) \
+		$(meson_feature X X11)
+}
+
+src_compile() {
+	local -x GST_PLUGIN_SYSTEM_PATH_1_0=
+	meson_src_compile
+}