[gentoo-commits] gentoo-x86 commit in app-admin/sysstat: ChangeLog sysstat-10.0.3.ebuild

[Jeroen Roovers (jer)]

jer         11/11/29 16:20:50

  Modified:             ChangeLog
  Added:                sysstat-10.0.3.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha79/cvs/Linux x86_64)

Revision  Changes    Path
1.211                app-admin/sysstat/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/sysstat/ChangeLog?rev=1.211&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/sysstat/ChangeLog?rev=1.211&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/sysstat/ChangeLog?r1=1.210&r2=1.211

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-admin/sysstat/ChangeLog,v
retrieving revision 1.210
retrieving revision 1.211
diff -u -r1.210 -r1.211
--- ChangeLog	3 Oct 2011 19:04:36 -0000	1.210
+++ ChangeLog	29 Nov 2011 16:20:50 -0000	1.211
@@ -1,6 +1,11 @@
 # ChangeLog for app-admin/sysstat
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/sysstat/ChangeLog,v 1.210 2011/10/03 19:04:36 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/sysstat/ChangeLog,v 1.211 2011/11/29 16:20:50 jer Exp $
+
+*sysstat-10.0.3 (29 Nov 2011)
+
+  29 Nov 2011; Jeroen Roovers <jer@g.o> +sysstat-10.0.3.ebuild:
+  Version bump.
 
   03 Oct 2011; Jeroen Roovers <jer@g.o> sysstat-10.0.2.ebuild:
   Stable for HPPA (bug #384867).



1.1                  app-admin/sysstat/sysstat-10.0.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/sysstat/sysstat-10.0.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/sysstat/sysstat-10.0.3.ebuild?rev=1.1&content-type=text/plain

Index: sysstat-10.0.3.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-admin/sysstat/sysstat-10.0.3.ebuild,v 1.1 2011/11/29 16:20:50 jer Exp $

EAPI="4"

inherit eutils multilib

DESCRIPTION="System performance tools for Linux"
HOMEPAGE="http://pagesperso-orange.fr/sebastien.godard/"
SRC_URI="${HOMEPAGE}${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
IUSE="cron debug +doc isag nls lm_sensors"

SYSSTAT_LINGUAS="
	af cs da de eo es eu fi fr id it ja ky lv mt nb nl nn pl pt pt_BR ro ru sk
	sv uk vi zh_CN zh_TW
"

for SYSSTAT_LINGUA in ${SYSSTAT_LINGUAS}; do
	IUSE="${IUSE} linguas_${SYSSTAT_LINGUA}"
done

RDEPEND="
	cron? ( sys-process/cronbase )
	isag? (
		dev-lang/tk
		dev-vcs/rcs
		sci-visualization/gnuplot
	)
	nls? ( virtual/libintl )
	lm_sensors? ( sys-apps/lm_sensors )
"
DEPEND="${RDEPEND}
	nls? ( sys-devel/gettext )"

src_prepare() {
	local po_count li_count lingua NLSDIR="${S}/nls"

	count() { echo ${#}; }
	po_count=$(count ${NLSDIR}/*.po)
	li_count=$(count ${SYSSTAT_LINGUAS})
	[[ ${po_count} = ${li_count} ]] \
		|| die "Number of LINGUAS does not match number of .po files"
	unset count

	einfo "Keeping these locales: ${LINGUAS}."
	for lingua in ${SYSSTAT_LINGUAS}; do
		if ! use linguas_${lingua}; then
			rm -f "${NLSDIR}/${lingua}.po" || die
		fi
	done
	epatch "${FILESDIR}"/${PN}-10.0.0-flags.patch
}

src_configure() {
	local myconf=""
	use doc || myconf="--disable-documentation"
	sa_lib_dir=/usr/$(get_libdir)/sa \
		econf ${myconf} \
			rcdir="Gentoo-does-not-use-rc.d" \
			$(use_enable cron install-cron) \
			$(use_enable debug debuginfo) \
			$(use_enable isag install-isag) \
			$(use_enable nls) \
			$(use_enable lm_sensors sensors) \
			conf_dir=/etc
}

src_compile() {
	emake LFLAGS="${LDFLAGS}"
}

src_install() {
	keepdir /var/log/sa

	use cron && dodir /etc/cron.{daily,hourly}

	emake \
		DESTDIR="${D}" \
		DOC_DIR=/usr/share/doc/${PF} \
		install

	dodoc contrib/sargraph/sargraph

	newinitd "${FILESDIR}"/sysstat.init.d sysstat

	use doc && rm -f "${D}"usr/share/doc/${PF}/COPYING
}