[gentoo-commits] gentoo-x86 commit in x11-libs/gtksourceview: gtksourceview-3.12.2.ebuild ChangeLog

[Pacho Ramos (pacho)]

pacho       14/05/31 09:55:48

  Modified:             ChangeLog
  Added:                gtksourceview-3.12.2.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

Revision  Changes    Path
1.262                x11-libs/gtksourceview/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/gtksourceview/ChangeLog?rev=1.262&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/gtksourceview/ChangeLog?rev=1.262&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/gtksourceview/ChangeLog?r1=1.261&r2=1.262

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-libs/gtksourceview/ChangeLog,v
retrieving revision 1.261
retrieving revision 1.262
diff -u -r1.261 -r1.262
--- ChangeLog	27 Apr 2014 21:50:03 -0000	1.261
+++ ChangeLog	31 May 2014 09:55:48 -0000	1.262
@@ -1,6 +1,11 @@
 # ChangeLog for x11-libs/gtksourceview
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/gtksourceview/ChangeLog,v 1.261 2014/04/27 21:50:03 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/gtksourceview/ChangeLog,v 1.262 2014/05/31 09:55:48 pacho Exp $
+
+*gtksourceview-3.12.2 (31 May 2014)
+
+  31 May 2014; Pacho Ramos <pacho@g.o> +gtksourceview-3.12.2.ebuild:
+  Version bump
 
 *gtksourceview-3.12.1 (27 Apr 2014)
 



1.1                  x11-libs/gtksourceview/gtksourceview-3.12.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/gtksourceview/gtksourceview-3.12.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/gtksourceview/gtksourceview-3.12.2.ebuild?rev=1.1&content-type=text/plain

Index: gtksourceview-3.12.2.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-libs/gtksourceview/gtksourceview-3.12.2.ebuild,v 1.1 2014/05/31 09:55:48 pacho Exp $

EAPI="5"
GCONF_DEBUG="no"

inherit gnome2 virtualx

DESCRIPTION="A text widget implementing syntax highlighting and other features"
HOMEPAGE="https://wiki.gnome.org/Projects/GtkSourceView"

LICENSE="GPL-2+ LGPL-2.1+"
SLOT="3.0/2"
IUSE="glade +introspection"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x86-solaris"

# Note: has native OSX support, prefix teams, attack!
RDEPEND="
	>=dev-libs/glib-2.37.3:2
	>=dev-libs/libxml2-2.6:2
	>=x11-libs/gtk+-3.11:3[introspection?]
	glade? ( >=dev-util/glade-3.9:3.10 )
	introspection? ( >=dev-libs/gobject-introspection-0.9.0 )
"
DEPEND="${RDEPEND}
	dev-util/gtk-doc-am
	>=dev-util/intltool-0.50
	>=sys-devel/gettext-0.17
	virtual/pkgconfig
"

src_configure() {
	gnome2_src_configure \
		--disable-deprecations \
		--enable-providers \
		$(use_enable glade glade-catalog) \
		$(use_enable introspection)
}

src_test() {
	Xemake check
}

src_install() {
	DOCS="AUTHORS HACKING MAINTAINERS NEWS README"
	gnome2_src_install

	insinto /usr/share/${PN}-3.0/language-specs
	doins "${FILESDIR}"/2.0/gentoo.lang
}