[gentoo-commits] gentoo-x86 commit in games-strategy/ufo-ai: ufo-ai-2.4.ebuild ChangeLog

[Tomas Chvatal (scarabeus)]

scarabeus    12/05/01 09:10:28

  Modified:             ChangeLog
  Added:                ufo-ai-2.4.ebuild
  Log:
  Version bump to the latest release. Upstream now use hand-crafted build system :/ Fix locale init.
  
  (Portage version: 2.2.0_alpha101/cvs/Linux x86_64)

Revision  Changes    Path
1.37                 games-strategy/ufo-ai/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/ufo-ai/ChangeLog?rev=1.37&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/ufo-ai/ChangeLog?rev=1.37&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/ufo-ai/ChangeLog?r1=1.36&r2=1.37

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-strategy/ufo-ai/ChangeLog,v
retrieving revision 1.36
retrieving revision 1.37
diff -u -r1.36 -r1.37
--- ChangeLog	22 Jan 2012 16:35:28 -0000	1.36
+++ ChangeLog	1 May 2012 09:10:28 -0000	1.37
@@ -1,6 +1,13 @@
 # ChangeLog for games-strategy/ufo-ai
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-strategy/ufo-ai/ChangeLog,v 1.36 2012/01/22 16:35:28 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-strategy/ufo-ai/ChangeLog,v 1.37 2012/05/01 09:10:28 scarabeus Exp $
+
+*ufo-ai-2.4 (01 May 2012)
+
+  01 May 2012; Tomáš Chvátal <scarabeus@g.o>
+  +files/ufo-ai-2.4-locale.patch, +ufo-ai-2.4.ebuild:
+  Version bump to the latest release. Upstream now use hand-crafted build system
+  :/ Fix locale init.
 
   22 Jan 2012; Samuli Suominen <ssuominen@g.o> ufo-ai-2.3.1-r1.ebuild:
   Fix building with sys-libs/zlib >= 1.2.5.1-r1 (OF change) wrt #383179



1.1                  games-strategy/ufo-ai/ufo-ai-2.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/ufo-ai/ufo-ai-2.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/ufo-ai/ufo-ai-2.4.ebuild?rev=1.1&content-type=text/plain

Index: ufo-ai-2.4.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-strategy/ufo-ai/ufo-ai-2.4.ebuild,v 1.1 2012/05/01 09:10:28 scarabeus Exp $

EAPI=3

inherit eutils flag-o-matic games

MY_P=${P/o-a/oa}

DESCRIPTION="UFO: Alien Invasion - X-COM inspired strategy game"
HOMEPAGE="http://ufoai.sourceforge.net/"
SRC_URI="mirror://sourceforge/ufoai/${MY_P}-source.tar.bz2
	mirror://sourceforge/ufoai/${MY_P}-data.tar
	http://mattn.ninex.info/1maps.pk3"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="debug dedicated editor"

# Dependencies and more instructions can be found here:
# http://ufoai.ninex.info/wiki/index.php/Compile_for_Linux
RDEPEND="!dedicated? (
		virtual/opengl
		virtual/glu
		media-libs/libsdl
		media-libs/sdl-image[jpeg,png]
		media-libs/sdl-ttf
		media-libs/sdl-mixer
		virtual/jpeg
		media-libs/libpng:0
		media-libs/libogg
		media-libs/libvorbis
		x11-proto/xf86vidmodeproto
	)
	net-misc/curl
	sys-devel/gettext
	sys-libs/zlib
	editor? (
		dev-libs/libxml2
		virtual/jpeg
		media-libs/openal
		x11-libs/gtkglext
		x11-libs/gtksourceview:2.0
	)"

DEPEND="${RDEPEND}"

S=${WORKDIR}/${MY_P}-source

src_prepare() {
	has_version '>=sys-libs/zlib-1.2.5.1-r1' && sed -i \
		-e '1i#define OF(x) x' src/common/ioapi.h

	epatch "${FILESDIR}"/${P}-locale.patch

	cp "${DISTDIR}"/1maps.pk3 "${WORKDIR}"/base/ || die
	mv "${WORKDIR}"/base/ "${S}"/ || die
}

src_configure() {
	local myconf
	# they are special and provide hand batched configure file
	myconf="
		--disable-dependency-tracking
		$(use_enable !debug release)
		$(use_enable editor ufo2map)
		$(use_enable editor uforadiant)
		--enable-ufoded
		--bindir="${GAMES_BINDIR}"
		--libdir="$(games_get_libdir)"
		--datadir="${GAMES_DATADIR}/${PN/-}"
		--localedir="${EPREFIX}/usr/share/locale/"
		--prefix="${GAMES_PREFIX}"
	"
	echo "./configure ${myconf}"
	./configure ${myconf} || die
}

src_compile() {
	emake || die
	emake lang || die

	if use editor; then
		emake uforadiant || die
	fi
}

src_install() {
	newicon src/ports/linux/ufo.png ${PN}.png || die
	dobin ufoded || die
	make_desktop_entry ufoded "UFO: Alien Invasion Server" ${PN}
	if ! use dedicated; then
		dobin ufo || die
		make_desktop_entry ufo "UFO: Alien Invasion" ${PN}
	fi

	if use editor; then
		dobin ufo2map ufomodel || die
	fi

	# install data
	insinto "${GAMES_DATADIR}"/${PN/-}
	doins -r base || die
	rm -rf "${ED}/${GAMES_DATADIR}/${PN/-}/base/game.so"
	dogameslib base/game.so

	# move translations where they belong
	dodir "${GAMES_DATADIR_BASE}/locale" || die
	mv "${ED}/${GAMES_DATADIR}/${PN/-}/base/i18n/"* \
		"${ED}/${GAMES_DATADIR_BASE}/locale/" || die
	rm -rf "${ED}/${GAMES_DATADIR}/${PN/-}/base/i18n/" || die

	prepgamesdirs
}