[gentoo-commits] gentoo-x86 commit in sys-apps/sandbox: sandbox-1.6-r2.ebuild ChangeLog

[Mike Frysinger (vapier)]

vapier      09/04/02 03:04:57

  Modified:             ChangeLog
  Added:                sandbox-1.6-r2.ebuild
  Log:
  Disable pthread locks to make 1.6 regression free #264476.
  (Portage version: 2.2_rc28/cvs/Linux x86_64)

Revision  Changes    Path
1.112                sys-apps/sandbox/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/sandbox/ChangeLog?rev=1.112&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/sandbox/ChangeLog?rev=1.112&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/sandbox/ChangeLog?r1=1.111&r2=1.112

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/sandbox/ChangeLog,v
retrieving revision 1.111
retrieving revision 1.112
diff -u -r1.111 -r1.112
--- ChangeLog	31 Mar 2009 11:56:19 -0000	1.111
+++ ChangeLog	2 Apr 2009 03:04:56 -0000	1.112
@@ -1,6 +1,12 @@
 # ChangeLog for sys-apps/sandbox
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/sandbox/ChangeLog,v 1.111 2009/03/31 11:56:19 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/sandbox/ChangeLog,v 1.112 2009/04/02 03:04:56 vapier Exp $
+
+*sandbox-1.6-r2 (02 Apr 2009)
+
+  02 Apr 2009; Mike Frysinger <vapier@g.o>
+  +files/sandbox-1.6-disable-pthread.patch, +sandbox-1.6-r2.ebuild:
+  Disable pthread locks to make 1.6 regression free #264476.
 
 *sandbox-1.6-r1 (31 Mar 2009)
 



1.1                  sys-apps/sandbox/sandbox-1.6-r2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/sandbox/sandbox-1.6-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/sandbox/sandbox-1.6-r2.ebuild?rev=1.1&content-type=text/plain

Index: sandbox-1.6-r2.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/sandbox/sandbox-1.6-r2.ebuild,v 1.1 2009/04/02 03:04:56 vapier Exp $

#
# don't monkey with this ebuild unless contacting portage devs.
# period.
#

inherit eutils flag-o-matic eutils toolchain-funcs multilib

DESCRIPTION="sandbox'd LD_PRELOAD hack"
HOMEPAGE="http://www.gentoo.org/"
SRC_URI="mirror://gentoo/${P}.tar.lzma
	http://dev.gentoo.org/~vapier/dist/${P}.tar.lzma"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~sparc-fbsd ~x86 ~x86-fbsd"
IUSE=""

DEPEND="app-arch/lzma-utils"
RDEPEND=""

EMULTILIB_PKG="true"
has sandbox_death_notice ${EBUILD_DEATH_HOOKS} || EBUILD_DEATH_HOOKS="${EBUILD_DEATH_HOOKS} sandbox_death_notice"

sandbox_death_notice() {
	ewarn "If configure failed with a 'cannot run C compiled programs' error, try this:"
	ewarn "FEATURES=-sandbox emerge sandbox"
}

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/${P}-disable-qa-static.patch
	epatch "${FILESDIR}"/${P}-disable-pthread.patch
	epatch "${FILESDIR}"/0001-libsandbox-handle-more-at-functions.patch
}

src_compile() {
	filter-lfs-flags #90228

	local OABI=${ABI}
	for ABI in $(get_install_abis) ; do
		mkdir "${WORKDIR}/build-${ABI}"
		cd "${WORKDIR}/build-${ABI}"

		multilib_toolchain_setup ${ABI}

		einfo "Configuring sandbox for ABI=${ABI}..."
		ECONF_SOURCE="../${P}/" \
		econf ${myconf} || die
		einfo "Building sandbox for ABI=${ABI}..."
		emake || die
	done
	ABI=${OABI}
}

src_test() {
	local OABI=${ABI}
	for ABI in $(get_install_abis) ; do
		cd "${WORKDIR}/build-${ABI}"
		einfo "Checking sandbox for ABI=${ABI}..."
		emake check || die "make check failed for ${ABI}"
	done
	ABI=${OABI}
}

src_install() {
	local OABI=${ABI}
	for ABI in $(get_install_abis) ; do
		cd "${WORKDIR}/build-${ABI}"
		einfo "Installing sandbox for ABI=${ABI}..."
		emake DESTDIR="${D}" install || die "make install failed for ${ABI}"
	done
	ABI=${OABI}

	doenvd "${FILESDIR}"/09sandbox

	keepdir /var/log/sandbox
	fowners root:portage /var/log/sandbox
	fperms 0770 /var/log/sandbox

	cd "${S}"
	dodoc AUTHORS ChangeLog* NEWS README
}

pkg_preinst() {
	chown root:portage "${D}"/var/log/sandbox
	chmod 0770 "${D}"/var/log/sandbox

	local old=$(find "${ROOT}"/lib* -maxdepth 1 -name 'libsandbox*')
	if [[ -n ${old} ]] ; then
		elog "Removing old sandbox libraries for you:"
		elog ${old//${ROOT}}
		find "${ROOT}"/lib* -maxdepth 1 -name 'libsandbox*' -exec rm -fv {} \;
	fi
}