[gentoo-commits] repo/gentoo:master commit in: dev-embedded/urjtag/

[Sven Wegener]

commit:     fb314e81beb8f3dcaa41b8db99b3b1e974708488
Author:     Sven Wegener <swegener <AT> gentoo <DOT> org>
AuthorDate: Thu Dec 31 13:05:39 2015 +0000
Commit:     Sven Wegener <swegener <AT> gentoo <DOT> org>
CommitDate: Thu Dec 31 13:09:51 2015 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=fb314e81

dev-embedded/urjtag: Revision bump, SLOT dep on libftdi, bug #503908

Signed-off-by: Sven Wegener <swegener <AT> gentoo.org>

 dev-embedded/urjtag/urjtag-0.10-r1.ebuild | 57 +++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)

diff --git a/dev-embedded/urjtag/urjtag-0.10-r1.ebuild b/dev-embedded/urjtag/urjtag-0.10-r1.ebuild
new file mode 100644
index 0000000..cfac982
--- /dev/null
+++ b/dev-embedded/urjtag/urjtag-0.10-r1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+# TODO: figure out htf to make python.eclass work
+
+EAPI="5"
+
+inherit eutils multilib
+if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="git://urjtag.git.sourceforge.net/gitroot/urjtag/urjtag"
+	EGIT_SOURCEDIR=${WORKDIR}
+	inherit git-r3 autotools
+	S=${WORKDIR}/${PN}
+else
+	SRC_URI="mirror://sourceforge/urjtag/${P}.tar.bz2"
+	KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+fi
+
+DESCRIPTION="tool for communicating over JTAG with flash chips, CPUs, and many more (fork of openwince jtag)"
+HOMEPAGE="http://urjtag.sourceforge.net/"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="ftd2xx ftdi readline usb"
+
+DEPEND="ftdi? ( dev-embedded/libftdi:0 )
+	ftd2xx? ( dev-embedded/libftd2xx )
+	readline? ( sys-libs/readline:= )
+	usb? ( virtual/libusb:0 )"
+RDEPEND="${DEPEND}
+	!dev-embedded/jtag"
+
+src_prepare() {
+	if [[ ${PV} == "9999" ]] ; then
+		mkdir -p m4
+		eautopoint
+		eautoreconf
+	fi
+}
+
+src_configure() {
+	use readline || export vl_cv_lib_readline=no
+	use ftd2xx && LDFLAGS="${LDFLAGS} -L/opt/$(get_libdir)"
+
+	econf \
+		--disable-werror \
+		--disable-python \
+		$(use_with ftdi libftdi) \
+		$(use_with ftd2xx) \
+		$(use_with usb libusb)
+}
+
+src_install() {
+	default
+	prune_libtool_files
+}