[gentoo-commits] gentoo-x86 commit in x11-libs/vte: vte-0.36.2.ebuild ChangeLog

[Pacho Ramos (pacho)]

pacho       14/05/31 09:14:12

  Modified:             ChangeLog
  Added:                vte-0.36.2.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

Revision  Changes    Path
1.387                x11-libs/vte/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/vte/ChangeLog?rev=1.387&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/vte/ChangeLog?rev=1.387&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/vte/ChangeLog?r1=1.386&r2=1.387

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-libs/vte/ChangeLog,v
retrieving revision 1.386
retrieving revision 1.387
diff -u -r1.386 -r1.387
--- ChangeLog	27 Apr 2014 21:51:38 -0000	1.386
+++ ChangeLog	31 May 2014 09:14:12 -0000	1.387
@@ -1,6 +1,11 @@
 # ChangeLog for x11-libs/vte
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/vte/ChangeLog,v 1.386 2014/04/27 21:51:38 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/vte/ChangeLog,v 1.387 2014/05/31 09:14:12 pacho Exp $
+
+*vte-0.36.2 (31 May 2014)
+
+  31 May 2014; Pacho Ramos <pacho@g.o> +vte-0.36.2.ebuild:
+  Version bump
 
 *vte-0.36.0 (27 Apr 2014)
 



1.1                  x11-libs/vte/vte-0.36.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/vte/vte-0.36.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/vte/vte-0.36.2.ebuild?rev=1.1&content-type=text/plain

Index: vte-0.36.2.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-libs/vte/vte-0.36.2.ebuild,v 1.1 2014/05/31 09:14:12 pacho Exp $

EAPI="5"
GCONF_DEBUG="yes"

inherit eutils gnome2

DESCRIPTION="Library providing a virtual terminal emulator widget"
HOMEPAGE="https://wiki.gnome.org/action/show/Apps/Terminal/VTE"

LICENSE="LGPL-2+"
SLOT="2.90"
IUSE="debug glade +introspection"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~arm-linux ~x86-linux ~x64-solaris ~x86-solaris"

PDEPEND="=x11-libs/gnome-pty-helper-${PV}"
RDEPEND="
	>=dev-libs/glib-2.31.13:2
	>=x11-libs/gtk+-3.1.9:3[introspection?]
	>=x11-libs/pango-1.22.0

	sys-libs/ncurses
	x11-libs/libX11
	x11-libs/libXft

	glade? ( >=dev-util/glade-3.9:3.10 )
	introspection? ( >=dev-libs/gobject-introspection-0.9.0 )
"
DEPEND="${RDEPEND}
	>=dev-util/gtk-doc-am-1.13
	>=dev-util/intltool-0.35
	sys-devel/gettext
	virtual/pkgconfig
"

src_prepare() {
	# https://bugzilla.gnome.org/show_bug.cgi?id=663779
	epatch "${FILESDIR}/${PN}-0.30.1-alt-meta.patch"

	gnome2_src_prepare
}

src_configure() {
	local myconf=""

	if [[ ${CHOST} == *-interix* ]]; then
		myconf="${myconf} --disable-Bsymbolic"

		# interix stropts.h is empty...
		export ac_cv_header_stropts_h=no
	fi

	# Python bindings are via gobject-introspection
	# Ex: from gi.repository import Vte
	# Do not disable gnome-pty-helper, bug #401389
	gnome2_src_configure \
		--disable-deprecation \
		--disable-static \
		$(use_enable debug) \
		$(use_enable glade glade-catalogue) \
		$(use_enable introspection)
}

src_install() {
	DOCS="AUTHORS ChangeLog HACKING NEWS README"
	gnome2_src_install
	rm -v "${ED}usr/libexec/gnome-pty-helper" || die
}