caster      09/05/31 18:49:34

  Modified:             ChangeLog
  Added:                freemind-0.9.0_rc4.ebuild
  Removed:              freemind-0.9.0_rc1.ebuild
  Log:
  Version bump.
  (Portage version: 2.2_rc33/cvs/Linux x86_64)

Revision  Changes    Path
1.46                 app-misc/freemind/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/freemind/ChangeLog?rev=1.46&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/freemind/ChangeLog?rev=1.46&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/freemind/ChangeLog?r1=1.45&r2=1.46

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/freemind/ChangeLog,v
retrieving revision 1.45
retrieving revision 1.46
diff -u -r1.45 -r1.46
--- ChangeLog	28 Mar 2009 11:17:59 -0000	1.45
+++ ChangeLog	31 May 2009 18:49:34 -0000	1.46
@@ -1,6 +1,12 @@
 # ChangeLog for app-misc/freemind
-# Copyright 2000-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/freemind/ChangeLog,v 1.45 2009/03/28 11:17:59 caster Exp $
+# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-misc/freemind/ChangeLog,v 1.46 2009/05/31 18:49:34 caster Exp $
+
+*freemind-0.9.0_rc4 (31 May 2009)
+
+  31 May 2009; Vlastimil Babka <caster@g.o>
+  -freemind-0.9.0_rc1.ebuild, +freemind-0.9.0_rc4.ebuild:
+  Version bump.
 
 *freemind-0.9.0_rc3 (28 Mar 2009)
 



1.1                  app-misc/freemind/freemind-0.9.0_rc4.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/freemind/freemind-0.9.0_rc4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/freemind/freemind-0.9.0_rc4.ebuild?rev=1.1&content-type=text/plain

Index: freemind-0.9.0_rc4.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/freemind/freemind-0.9.0_rc4.ebuild,v 1.1 2009/05/31 18:49:34 caster Exp $

EAPI=2

# will handle rewriting myself
JAVA_PKG_BSFIX="off"
WANT_ANT_TASKS="ant-nodeps ant-trax"
inherit java-pkg-2 java-ant-2 eutils

MY_PV=${PV//beta/Beta_}
MY_PV=${MY_PV//rc/RC_}

DESCRIPTION="Mind-mapping software written in Java"
HOMEPAGE="http://freemind.sourceforge.net"
SRC_URI="mirror://sourceforge/${PN}/${PN}-src-${MY_PV}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="doc groovy latex pdf svg"
COMMON_DEP="dev-java/jgoodies-forms:0
	dev-java/jibx:0
	>=dev-java/simplyhtml-0.13.1:0
	dev-java/commons-lang:2.1
	dev-java/javahelp:0
	groovy? ( dev-java/groovy:1 )
	latex? ( dev-java/hoteqn:0 )
	pdf? ( dev-java/batik:1.6
		>=dev-java/fop-0.93:0 )
	svg? ( dev-java/batik:1.6
		>=dev-java/fop-0.93:0 )"
DEPEND=">=virtual/jdk-1.4
	dev-java/xsd2jibx:0
	app-arch/unzip
	${COMMON_DEP}"
RDEPEND=">=virtual/jre-1.4
	${COMMON_DEP}"

S="${WORKDIR}/${PN}"

java_prepare() {
	# kill the jarbundler taskdef
	epatch "${FILESDIR}/${PN}-0.9.0_rc1-build.xml.patch"

	use groovy || rm plugins/build_scripting.xml || die
	use latex || rm plugins/build_latex.xml || die
	if ! use pdf && ! use svg ; then
		rm plugins/build_svg.xml || die
	fi

	local xml
	for xml in $(find . -name 'build*.xml'); do
		java-ant_rewrite-classpath ${xml}
		java-ant_bsfix_one ${xml}
	done

	rm -v lib/*.jar lib/*.zip lib/*/*.jar \
		plugins/*/*.jar plugins/*/*/*.jar || die
}

src_compile() {
	local jibxlibs="$(java-pkg_getjars --build-only --with-dependencies xsd2jibx)"
	local gcp="jgoodies-forms,jibx,commons-lang-2.1,javahelp,simplyhtml"
	use groovy && gcp="${gcp},groovy-1"
	use latex && gcp="${gcp},hoteqn"
	if use pdf || use svg ; then
		gcp="${gcp},batik-1.6,fop"
	fi
	local gcp="$(java-pkg_getjars --with-dependencies ${gcp}):lib/bindings.jar"
	ANT_TASKS="${WANT_ANT_TASKS} jibx xsd2jibx" eant -Djibxlibs="${jibxlibs}" \
		-Dgentoo.classpath="${gcp}" dist browser $(use_doc doc)
}

src_install() {
	cd "${WORKDIR}/bin/dist"
	local dest="/usr/share/${PN}/"

	java-pkg_dojar lib/*.jar

	insinto "${dest}"
	doins -r accessories browser/ doc/ plugins/ patterns.xml || die

	use doc && java-pkg_dojavadoc doc/javadoc

	java-pkg_dolauncher ${PN} --java_args "-Dfreemind.base.dir=${dest}" \
		--pwd "${dest}" --main freemind.main.FreeMindStarter

	newicon "${S}/images/FreeMindWindowIcon.png" freemind.png

	make_desktop_entry freemind Freemind freemind Utility
}