Gentoo Logo
Gentoo Spaceship




Note: Due to technical difficulties, the Archives are currently not up to date. GMANE provides an alternative service for most mailing lists.
c.f. bug 424647
List Archive: gentoo-commits
Navigation:
Lists: gentoo-commits: < Prev By Thread Next > < Prev By Date Next >
Headers:
To: gentoo-commits@g.o
From: "Samuli Suominen (drac)" <drac@g.o>
Subject: gentoo-x86 commit in x11-misc/xscreensaver: ChangeLog xscreensaver-5.06.ebuild
Date: Mon, 04 Aug 2008 21:59:52 +0000
drac        08/08/04 21:59:52

  Modified:             ChangeLog
  Added:                xscreensaver-5.06.ebuild
  Log:
  Version bump. Upstream applied most of our patchset. Fix building with --without-xinerama-ext by renaming misnamed ifdef.
  (Portage version: 2.2_rc6/cvs/Linux 2.6.24-gentoo-r3 x86_64)

Revision  Changes    Path
1.235                x11-misc/xscreensaver/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-misc/xscreensaver/ChangeLog?rev=1.235&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-misc/xscreensaver/ChangeLog?rev=1.235&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-misc/xscreensaver/ChangeLog?r1=1.234&r2=1.235

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-misc/xscreensaver/ChangeLog,v
retrieving revision 1.234
retrieving revision 1.235
diff -u -r1.234 -r1.235
--- ChangeLog	7 May 2008 19:06:28 -0000	1.234
+++ ChangeLog	4 Aug 2008 21:59:51 -0000	1.235
@@ -1,6 +1,14 @@
 # ChangeLog for x11-misc/xscreensaver
 # Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/xscreensaver/ChangeLog,v 1.234 2008/05/07 19:06:28 drac Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/xscreensaver/ChangeLog,v 1.235 2008/08/04 21:59:51 drac Exp $
+
+*xscreensaver-5.06 (04 Aug 2008)
+
+  04 Aug 2008; Samuli Suominen <drac@g.o>
+  +files/5.06/01_all_default_settings.patch,
+  +files/5.06/02_all_xinerama_function.patch, +xscreensaver-5.06.ebuild:
+  Version bump. Upstream applied most of our patchset. Fix building with
+  --without-xinerama-ext by renaming misnamed ifdef.
 
 *xscreensaver-5.05-r1 (07 May 2008)
 



1.1                  x11-misc/xscreensaver/xscreensaver-5.06.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-misc/xscreensaver/xscreensaver-5.06.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-misc/xscreensaver/xscreensaver-5.06.ebuild?rev=1.1&content-type=text/plain

Index: xscreensaver-5.06.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-misc/xscreensaver/xscreensaver-5.06.ebuild,v 1.1 2008/08/04 21:59:51 drac Exp $

inherit autotools eutils flag-o-matic multilib pam

DESCRIPTION="A modular screen saver and locker for the X Window System"
SRC_URI="http://www.jwz.org/xscreensaver/${P}.tar.gz"
HOMEPAGE="http://www.jwz.org/xscreensaver"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="jpeg new-login opengl pam suid xinerama"

RDEPEND="x11-libs/libXmu
	x11-libs/libXxf86vm
	x11-libs/libXrandr
	x11-libs/libXxf86misc
	x11-libs/libXt
	x11-libs/libX11
	x11-libs/libXext
	x11-apps/xwininfo
	x11-apps/appres
	media-libs/netpbm
	>=dev-libs/libxml2-2.5
	>=x11-libs/gtk+-2
	>=gnome-base/libglade-1.99
	pam? ( virtual/pam )
	jpeg? ( media-libs/jpeg )
	opengl? ( virtual/opengl )
	xinerama? ( x11-libs/libXinerama )
	new-login? ( gnome-base/gdm )"
DEPEND="${RDEPEND}
	x11-proto/xf86vidmodeproto
	x11-proto/xextproto
	x11-proto/scrnsaverproto
	x11-proto/recordproto
	x11-proto/xf86miscproto
	sys-devel/bc
	dev-util/pkgconfig
	sys-devel/gettext
	dev-util/intltool
	xinerama? ( x11-proto/xineramaproto )"

src_unpack() {
	unpack ${A}
	cd "${S}"
	EPATCH_SUFFIX="patch" epatch "${FILESDIR}"/${PV}
	eautoreconf # bug 113681
}

src_compile() {
	if use ppc || use ppc64; then
		# Still fails to build "flurry" screensaver.
		filter-flags -mabi=altivec
		filter-flags -maltivec
		append-flags -U__VEC__
	fi

	unset BC_ENV_ARGS

	econf \
		--with-x-app-defaults=/usr/share/X11/app-defaults \
		--with-hackdir=/usr/$(get_libdir)/misc/${PN} \
		--with-configdir=/usr/share/${PN}/config \
		--x-libraries=/usr/$(get_libdir) \
		--x-includes=/usr/include \
		--with-dpms-ext \
		--with-xf86vmode-ext \
		--with-xf86gamma-ext \
		--with-randr-ext \
		--with-proc-interrupts \
		--with-xpm \
		--with-xshm-ext \
		--with-xdbe-ext \
		--enable-locking \
		--without-kerberos \
		--without-gle \
		--with-gtk \
		--with-pixbuf \
		$(use_with suid setuid-hacks) \
		$(use_with new-login login-manager) \
		$(use_with xinerama xinerama-ext) \
		$(use_with pam) \
		$(use_with opengl gl) \
		$(use_with jpeg)

	emake -j1 || die "emake failed." # bug 155049
}

src_install() {
	emake install_prefix="${D}" install || die "emake install failed."

	dodoc README{,.hacking}

	use pam && fperms 755 /usr/bin/${PN}
	pamd_mimic_system ${PN} auth

	# bug 135549
	rm -f "${D}"/usr/share/${PN}/config/{electricsheep,fireflies}.xml
	dodir /usr/share/man/man6x
	mv "${D}"/usr/share/man/man6/worm.6 \
		"${D}"/usr/share/man/man6x/worm.6x
}





Navigation:
Lists: gentoo-commits: < Prev By Thread Next > < Prev By Date Next >
Previous by thread:
gentoo-x86 commit in x11-misc/xscreensaver/files/5.06: - New directory
Next by thread:
gentoo-x86 commit in x11-misc/xscreensaver/files/5.06: 01_all_default_settings.patch 02_all_xinerama_function.patch
Previous by date:
gentoo-x86 commit in x11-misc/xscreensaver/files/5.06: - New directory
Next by date:
gentoo-x86 commit in x11-misc/xscreensaver/files/5.06: 01_all_default_settings.patch 02_all_xinerama_function.patch


Updated Jul 17, 2010

Summary: Archive of the gentoo-commits mailing list.

Donate to support our development efforts.

Copyright 2001-2013 Gentoo Foundation, Inc. Questions, Comments? Contact us.