Gentoo Logo
Gentoo Spaceship




Note: Due to technical difficulties, the Archives are currently not up to date. GMANE provides an alternative service for most mailing lists.
c.f. bug 424647
List Archive: gentoo-commits
Navigation:
Lists: gentoo-commits: < Prev By Thread Next > < Prev By Date Next >
Headers:
To: gentoo-commits@g.o
From: "Alexandre Rostovtsev (tetromino)" <tetromino@g.o>
Subject: gentoo-x86 commit in dev-libs/libxml2: ChangeLog libxml2-2.8.0-r1.ebuild libxml2-2.8.0.ebuild
Date: Sat, 26 May 2012 07:58:15 +0000 (UTC)
tetromino    12/05/26 07:58:15

  Modified:             ChangeLog
  Added:                libxml2-2.8.0-r1.ebuild
  Removed:              libxml2-2.8.0.ebuild
  Log:
  Prevent libxml2's python module from linking to out-of-build-tree libxml2 library by hacking the relink_command entry in its build-time .la file. Fixes bug #417539 ("'LIBXML2_2.7.9' not found" errors). Forced to drop hppa and amd64-fbsd keywords, bug #417569. Drop broken 2.8.0 ebuild.
  
  (Portage version: 2.2.0_alpha108/cvs/Linux x86_64)

Revision  Changes    Path
1.346                dev-libs/libxml2/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libxml2/ChangeLog?rev=1.346&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libxml2/ChangeLog?rev=1.346&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libxml2/ChangeLog?r1=1.345&r2=1.346

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/libxml2/ChangeLog,v
retrieving revision 1.345
retrieving revision 1.346
diff -u -r1.345 -r1.346
--- ChangeLog	25 May 2012 07:13:52 -0000	1.345
+++ ChangeLog	26 May 2012 07:58:15 -0000	1.346
@@ -1,6 +1,15 @@
 # ChangeLog for dev-libs/libxml2
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/libxml2/ChangeLog,v 1.345 2012/05/25 07:13:52 tetromino Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libxml2/ChangeLog,v 1.346 2012/05/26 07:58:15 tetromino Exp $
+
+*libxml2-2.8.0-r1 (26 May 2012)
+
+  26 May 2012; Alexandre Rostovtsev <tetromino@g.o>
+  -libxml2-2.8.0.ebuild, +libxml2-2.8.0-r1.ebuild:
+  Prevent libxml2's python module from linking to out-of-build-tree libxml2
+  library by hacking the relink_command entry in its build-time .la file. Fixes
+  bug #417539 ("'LIBXML2_2.7.9' not found" errors). Forced to drop hppa and
+  amd64-fbsd keywords, bug #417569. Drop broken 2.8.0 ebuild.
 
 *libxml2-2.8.0 (25 May 2012)
 



1.1                  dev-libs/libxml2/libxml2-2.8.0-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libxml2/libxml2-2.8.0-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libxml2/libxml2-2.8.0-r1.ebuild?rev=1.1&content-type=text/plain

Index: libxml2-2.8.0-r1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/libxml2/libxml2-2.8.0-r1.ebuild,v 1.1 2012/05/26 07:58:15 tetromino Exp $

EAPI="4"
PYTHON_DEPEND="python? 2"
PYTHON_USE_WITH="xml"
PYTHON_USE_WITH_OPT="python"
SUPPORT_PYTHON_ABIS="1"
RESTRICT_PYTHON_ABIS="3.* *-jython 2.7-pypy-*"

inherit libtool flag-o-matic eutils python autotools prefix

DESCRIPTION="Version 2 of the library to manipulate XML files"
HOMEPAGE="http://www.xmlsoft.org/"

LICENSE="MIT"
SLOT="2"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~hppa-hpux ~ia64-hpux ~x86-interix ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris ~x86-winnt"
IUSE="debug doc examples icu ipv6 lzma python readline static-libs test"

XSTS_HOME="http://www.w3.org/XML/2004/xml-schema-test-suite"
XSTS_NAME_1="xmlschema2002-01-16"
XSTS_NAME_2="xmlschema2004-01-14"
XSTS_TARBALL_1="xsts-2002-01-16.tar.gz"
XSTS_TARBALL_2="xsts-2004-01-14.tar.gz"

SRC_URI="ftp://xmlsoft.org/${PN}/${PN}-${PV/_rc/-rc}.tar.gz
	test? (
		${XSTS_HOME}/${XSTS_NAME_1}/${XSTS_TARBALL_1}
		${XSTS_HOME}/${XSTS_NAME_2}/${XSTS_TARBALL_2} )"

RDEPEND="sys-libs/zlib
	icu? ( dev-libs/icu )
	lzma? ( app-arch/xz-utils )
	readline? ( sys-libs/readline )"

DEPEND="${RDEPEND}
	python? ( dev-util/fix-la-relink-command )
	hppa? ( >=sys-devel/binutils-2.15.92.0.2 )"

S="${WORKDIR}/${PN}-${PV%_rc*}"

pkg_setup() {
	use python && python_pkg_setup
}

src_unpack() {
	# ${A} isn't used to avoid unpacking of test tarballs into $WORKDIR,
	# as they are needed as tarballs in ${S}/xstc instead and not unpacked
	unpack ${P/_rc/-rc}.tar.gz
	cd "${S}"

	if use test; then
		cp "${DISTDIR}/${XSTS_TARBALL_1}" \
			"${DISTDIR}/${XSTS_TARBALL_2}" \
			"${S}"/xstc/ \
			|| die "Failed to install test tarballs"
	fi
}

src_prepare() {
	# Patches needed for prefix support
	epatch "${FILESDIR}"/${PN}-2.7.1-catalog_path.patch
	epatch "${FILESDIR}"/${PN}-2.8.0_rc1-winnt.patch

	eprefixify catalog.c xmlcatalog.c runtest.c xmllint.c

	epunt_cxx

	epatch "${FILESDIR}/${PN}-2.7.8-disable_static_modules.patch"

	# Please do not remove, as else we get references to PORTAGE_TMPDIR
	# in /usr/lib/python?.?/site-packages/libxml2mod.la among things.
	# We now need to run eautoreconf at the end to prevent maintainer mode.
#	elibtoolize

	# Python bindings are built/tested/installed manually.
	sed -e "s/@PYTHON_SUBDIR@//" -i Makefile.am || die "sed 1 failed"

	# Use Gentoo's python-config naming scheme
	sed -e 's/python$PYTHON_VERSION-config/python-config-$PYTHON_VERSION/' \
		-i configure.in || die "sed 2 failed"

	eautoreconf
}

src_configure() {
	# USE zlib support breaks gnome2
	# (libgnomeprint for instance fails to compile with
	# fresh install, and existing) - <azarah@g.o> (22 Dec 2002).

	# The meaning of the 'debug' USE flag does not apply to the --with-debug
	# switch (enabling the libxml2 debug module). See bug #100898.

	# --with-mem-debug causes unusual segmentation faults (bug #105120).

	local myconf=(
		--with-html-subdir=${PF}/html
		--docdir="${EPREFIX}/usr/share/doc/${PF}"
		$(use_with debug run-debug)
		$(use_with icu)
		$(use_with lzma)
		$(use_with python)
		$(use_with readline)
		$(use_with readline history)
		$(use_enable ipv6)
		$(use_enable static-libs static) )

	# filter seemingly problematic CFLAGS (#26320)
	filter-flags -fprefetch-loop-arrays -funroll-loops

	econf "${myconf[@]}"
}

src_compile() {
	default

	if use python; then
		python_copy_sources python
		building() {
			emake PYTHON_INCLUDES="${EPREFIX}$(python_get_includedir)" \
				PYTHON_SITE_PACKAGES="${EPREFIX}$(python_get_sitedir)"
		}
		python_execute_function -s --source-dir python building
	fi
}

src_test() {
	default

	if use python; then
		testing() {
			emake test
		}
		python_execute_function -s --source-dir python testing
	fi
}

src_install() {
	emake DESTDIR="${D}" \
		EXAMPLES_DIR="${EPREFIX}"/usr/share/doc/${PF}/examples \
		install || die "Installation failed"

	# on windows, xmllint is installed by interix libxml2 in parent prefix.
	# this is the version to use. the native winnt version does not support
	# symlinks, which makes repoman fail if the portage tree is linked in
	# from another location (which is my default). -- mduft
	if [[ ${CHOST} == *-winnt* ]]; then
		rm -rf "${ED}"/usr/bin/xmllint
		rm -rf "${ED}"/usr/bin/xmlcatalog
	fi

	if use python; then
		installation() {
			# bug #417539
			fix-la-relink-command . || die "fix-la-relink-command failed"
			emake DESTDIR="${D}" \
				PYTHON_SITE_PACKAGES="${EPREFIX}$(python_get_sitedir)" \
				docsdir="${EPREFIX}"/usr/share/doc/${PF}/python \
				exampledir="${EPREFIX}"/usr/share/doc/${PF}/python/examples \
				install
		}
		python_execute_function -s --source-dir python installation

		python_clean_installation_image
	fi

	rm -rf "${ED}"/usr/share/doc/${P}
	dodoc AUTHORS ChangeLog Copyright NEWS README* TODO*

	if ! use python; then
		rm -rf "${ED}"/usr/share/doc/${PF}/python
		rm -rf "${ED}"/usr/share/doc/${PN}-python-${PV}
	fi

	if ! use doc; then
		rm -rf "${ED}"/usr/share/gtk-doc
		rm -rf "${ED}"/usr/share/doc/${PF}/html
	fi

	if ! use examples; then
		rm -rf "${ED}/usr/share/doc/${PF}/examples"
		rm -rf "${ED}/usr/share/doc/${PF}/python/examples"
	fi

	# Always remove useless .la files
	find "${D}" -name '*.la' -exec rm -f {} + || die "la file removal failed"
}

pkg_postinst() {
	if use python; then
		python_mod_optimize drv_libxml2.py libxml2.py
	fi

	# We don't want to do the xmlcatalog during stage1, as xmlcatalog will not
	# be in / and stage1 builds to ROOT=/tmp/stage1root. This fixes bug #208887.
	if [ "${ROOT}" != "/" ]
	then
		elog "Skipping XML catalog creation for stage building (bug #208887)."
	else
		# need an XML catalog, so no-one writes to a non-existent one
		CATALOG="${EROOT}etc/xml/catalog"

		# we dont want to clobber an existing catalog though,
		# only ensure that one is there
		# <obz@g.o>
		if [ ! -e ${CATALOG} ]; then
			[ -d "${EROOT}etc/xml" ] || mkdir -p "${EROOT}etc/xml"
			"${EPREFIX}"/usr/bin/xmlcatalog --create > ${CATALOG}
			einfo "Created XML catalog in ${CATALOG}"
		fi
	fi
}

pkg_postrm() {
	if use python; then
		python_mod_cleanup drv_libxml2.py libxml2.py
	fi
}





Navigation:
Lists: gentoo-commits: < Prev By Thread Next > < Prev By Date Next >
Previous by thread:
gentoo-x86 commit in dev-util/source-highlight: ChangeLog source-highlight-3.1.6.ebuild
Next by thread:
gentoo-x86 commit in net-libs/libproxy/files: libproxy-0.4.7-gcc-4.7.patch
Previous by date:
gentoo-x86 commit in dev-util/source-highlight: ChangeLog source-highlight-3.1.6.ebuild
Next by date:
gentoo-x86 commit in net-libs/libproxy/files: libproxy-0.4.7-gcc-4.7.patch


Updated Jun 26, 2012

Summary: Archive of the gentoo-commits mailing list.

Donate to support our development efforts.

Copyright 2001-2013 Gentoo Foundation, Inc. Questions, Comments? Contact us.