chainsaw    08/01/31 14:54:18

  Modified:             ChangeLog
  Added:                alsa-utils-1.0.16_rc1.ebuild
  Log:
  Version bump, for bug #207427.
  (Portage version: 2.1.4)

Revision  Changes    Path
1.223                media-sound/alsa-utils/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/alsa-utils/ChangeLog?rev=1.223&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/alsa-utils/ChangeLog?rev=1.223&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/alsa-utils/ChangeLog?r1=1.222&r2=1.223

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/alsa-utils/ChangeLog,v
retrieving revision 1.222
retrieving revision 1.223
diff -u -r1.222 -r1.223
--- ChangeLog	29 Dec 2007 06:37:59 -0000	1.222
+++ ChangeLog	31 Jan 2008 14:54:17 -0000	1.223
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/alsa-utils
-# Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/alsa-utils/ChangeLog,v 1.222 2007/12/29 06:37:59 robbat2 Exp $
+# Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/alsa-utils/ChangeLog,v 1.223 2008/01/31 14:54:17 chainsaw Exp $
+
+*alsa-utils-1.0.16_rc1 (31 Jan 2008)
+
+  31 Jan 2008; Tony Vroon <chainsaw@g.o>
+  +alsa-utils-1.0.16_rc1.ebuild:
+  Version bump, for bug #207427.
 
   29 Dec 2007; Robin H. Johnson <robbat2@g.o> files/alsasound.confd,
   files/alsasound.initd:



1.1                  media-sound/alsa-utils/alsa-utils-1.0.16_rc1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/alsa-utils/alsa-utils-1.0.16_rc1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/alsa-utils/alsa-utils-1.0.16_rc1.ebuild?rev=1.1&content-type=text/plain

Index: alsa-utils-1.0.16_rc1.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/alsa-utils/alsa-utils-1.0.16_rc1.ebuild,v 1.1 2008/01/31 14:54:17 chainsaw Exp $

WANT_AUTOMAKE="latest"
WANT_AUTOCONF="latest"

inherit eutils autotools

MY_P="${P/_rc/rc}"

DESCRIPTION="Advanced Linux Sound Architecture Utils (alsactl, alsamixer, etc.)"
HOMEPAGE="http://www.alsa-project.org/"
SRC_URI="mirror://alsaproject/utils/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0.9"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86"
IUSE="nls midi"

DEPEND=">=sys-libs/ncurses-5.1
	dev-util/dialog
	>=media-libs/alsa-lib-${PV}"
RDEPEND="${DEPEND}
	virtual/modutils
	sys-apps/pciutils"

S="${WORKDIR}/${MY_P}"

pkg_setup() {
	if use midi && ! built_with_use --missing true media-libs/alsa-lib midi; then
		eerror ""
		eerror "To be able to build alsa-utils with midi support you need"
		eerror "to have built media-libs/alsa-lib with midi USE flag."
		die "Missing midi USE flag on media-libs/alsa-lib"
	fi
}

src_unpack() {
	unpack ${A}
	cd "${S}"

	epatch "${FILESDIR}/${PN}-1.0.11_rc2-nls.patch"
	epatch "${FILESDIR}/${PN}-1.0.11_rc5-alsaconf-redirect.patch"
	epatch "${FILESDIR}/${PN}-1.0.15_rc1-seq.patch"

	AT_M4DIR="m4" eautoreconf
}

src_compile() {
	econf \
		$(use_enable nls) \
		$(use_enable midi sequencer) \
		|| die "configure failed"

	emake || die "make failed"
}

src_install() {
	local ALSA_UTILS_DOCS="ChangeLog README TODO
		seq/aconnect/README.aconnect
		seq/aseqnet/README.aseqnet"

	emake DESTDIR="${D}" install || die "Installation Failed"

	dodoc ${ALSA_UTILS_DOCS}
	newdoc alsamixer/README README.alsamixer

	newinitd "${FILESDIR}/alsasound.initd" alsasound
	newconfd "${FILESDIR}/alsasound.confd" alsasound
	insinto /etc/modules.d
	newins "${FILESDIR}/alsa-modules.conf-rc" alsa

	keepdir /var/lib/alsa
}

pkg_postinst() {
	echo
	elog "To take advantage of the init script, and automate the process of"
	elog "loading and unloading the ALSA sound drivers as well as"
	elog "storing and restoring sound-card mixer levels you should"
	elog "add alsasound to the boot runlevel. You can do this as"
	elog "root like so:"
	elog "	# rc-update add alsasound boot"
	echo
}



-- 
gentoo-commits@g.o mailing list