[gentoo-commits] gentoo-x86 commit in net-www/gnash: ChangeLog gnash-0.8.3.ebuild gnash-0.8.4.ebuild

[Peter Alfredsen (loki_val)]

loki_val    08/10/19 11:49:11

  Modified:             ChangeLog gnash-0.8.3.ebuild
  Added:                gnash-0.8.4.ebuild
  Log:
  Fix bug 242656 by restricting 0.8.3 to ffmpeg 20080326. Bump to 0.8.4, bug 241874, thanks to Mounir Lamouri. This version works much better than 0.8.3, but tests fail to compile.
  (Portage version: 2.2_rc12/cvs/Linux 2.6.27-rc8 x86_64)

Revision  Changes    Path
1.64                 net-www/gnash/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-www/gnash/ChangeLog?rev=1.64&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-www/gnash/ChangeLog?rev=1.64&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-www/gnash/ChangeLog?r1=1.63&r2=1.64

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-www/gnash/ChangeLog,v
retrieving revision 1.63
retrieving revision 1.64
diff -u -r1.63 -r1.64
--- ChangeLog	12 Oct 2008 16:05:34 -0000	1.63
+++ ChangeLog	19 Oct 2008 11:49:10 -0000	1.64
@@ -1,6 +1,14 @@
 # ChangeLog for net-www/gnash
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-www/gnash/ChangeLog,v 1.63 2008/10/12 16:05:34 bluebird Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-www/gnash/ChangeLog,v 1.64 2008/10/19 11:49:10 loki_val Exp $
+
+*gnash-0.8.4 (19 Oct 2008)
+
+  19 Oct 2008; Peter Alfredsen <loki_val@g.o> gnash-0.8.3.ebuild,
+  +gnash-0.8.4.ebuild:
+  Fix bug 242656 by restricting 0.8.3 to ffmpeg 20080326. Bump to 0.8.4, bug
+  241874, thanks to Mounir Lamouri. This version works much better than
+  0.8.3, but tests fail to compile.
 
   12 Oct 2008; Friedrich Oslage <bluebird@g.o> gnash-0.8.3.ebuild:
   Drop ~sparc keyword, until bug #240470 is fixed



1.7                  net-www/gnash/gnash-0.8.3.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-www/gnash/gnash-0.8.3.ebuild?rev=1.7&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-www/gnash/gnash-0.8.3.ebuild?rev=1.7&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-www/gnash/gnash-0.8.3.ebuild?r1=1.6&r2=1.7

Index: gnash-0.8.3.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-www/gnash/gnash-0.8.3.ebuild,v
retrieving revision 1.6
retrieving revision 1.7
diff -u -r1.6 -r1.7
--- gnash-0.8.3.ebuild	12 Oct 2008 16:05:34 -0000	1.6
+++ gnash-0.8.3.ebuild	19 Oct 2008 11:49:10 -0000	1.7
@@ -1,6 +1,6 @@
 # Copyright 1999-2008 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-www/gnash/gnash-0.8.3.ebuild,v 1.6 2008/10/12 16:05:34 bluebird Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-www/gnash/gnash-0.8.3.ebuild,v 1.7 2008/10/19 11:49:10 loki_val Exp $
 
 EAPI=1
 
@@ -59,7 +59,7 @@
 	ffmpeg? (
 		!gstreamer? (
 			media-libs/libsdl
-			>=media-video/ffmpeg-0.4.9_p20080326
+			=media-video/ffmpeg-0.4.9_p20080326
 		)
 	)
 
@@ -183,7 +183,7 @@
 		use ${gui/-*} && guis="${guis},${gui/*-}"
 	done
 	guis=${guis#,}
-	if [ -z ${gui} ]
+	if [ -z "${guis}" ]
 	then
 		guis="GTK2,KDE"
 	fi



1.1                  net-www/gnash/gnash-0.8.4.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-www/gnash/gnash-0.8.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-www/gnash/gnash-0.8.4.ebuild?rev=1.1&content-type=text/plain

Index: gnash-0.8.4.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-www/gnash/gnash-0.8.4.ebuild,v 1.1 2008/10/19 11:49:10 loki_val Exp $

EAPI=1

inherit autotools nsplugins kde-functions qt3 multilib

set-kdedir 3.5

DESCRIPTION="Gnash is a GNU Flash movie player that supports many SWF v7 features"
HOMEPAGE="http://www.gnu.org/software/gnash"
SRC_URI="mirror://gnu/${PN}/${PV}/${P}.tar.bz2"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="+agg -cairo dbus -fbcon -ffmpeg +gstreamer +gtk +kde +nsplugin -opengl -qt3 -sdl video_cards_i810"

RDEPEND="
	agg? ( >=x11-libs/agg-2.5 )
	opengl? (
		!agg? (
			virtual/opengl
			gtk? ( x11-libs/gtkglext )
		)
	)
	cairo? (
		!opengl? (
			!agg? (
				x11-libs/cairo
			)
		)
	)

	!agg? ( !cairo? ( !opengl? ( >=x11-libs/agg-2.5 ) ) )
	gtk? (
		x11-libs/gtk+:2
		x11-libs/pango
		dev-libs/glib
		dev-libs/atk
	)
	kde? ( kde-base/kdelibs:3.5 )
	qt3? ( x11-libs/qt:3 )
	sdl? ( media-libs/libsdl )
	!gtk? ( !kde? ( !qt3? ( !sdl? ( !fbcon? (
		x11-libs/gtk+:2
		x11-libs/pango
		dev-libs/glib
		dev-libs/atk
		kde-base/kdelibs:3.5
	) ) ) ) )
	dev-libs/libxml2
	sys-libs/zlib
	media-libs/jpeg
	media-libs/libpng
	net-misc/curl
	ffmpeg? (
		!gstreamer? (
			media-libs/libsdl
			>=media-video/ffmpeg-0.4.9_p20080326
		)
	)

	gstreamer? (
		media-plugins/gst-plugins-ffmpeg
		media-plugins/gst-plugins-mad
	)
	>=dev-libs/boost-1.35.0
	x11-libs/libX11
	x11-libs/libXi
	x11-libs/libXmu
	x11-libs/libXt
	x11-proto/xproto
	dbus? ( sys-apps/dbus )
	sys-devel/libtool
	"
DEPEND="${RDEPEND}
	dev-util/pkgconfig"

#Tests currently not functional. Compilation fails. Use youtube instead.
RESTRICT="test"

pkg_setup() {
	if use !gtk && use !kde && use !fbcon && use !qt3
	then
		einfo "No Graphical User Interface selected. Enabling kde and gtk"
		einfo "since they are the defaults."
		export defaultguis=1
	fi

	if use !agg && use !opengl && use cairo && use kde
	then
		eerror "The cairo renderer and the kde gui were selected"
		eerror "They are incompatible with each other"
		eerror "Disable one of them through the respective USE flag"
		die "cairo and kde USE flags enabled at the same time"
	fi

	if use !agg && use opengl && use fbcon
	then
		eerror "The opengl renderer and the fbcon gui were selected"
		eerror "They are incompatible with each other"
		eerror "Disable one of them through the respective USE flag"
		die "opengl and fbcon USE flags enabled at the same time"
	fi

	if use nsplugin && use !gtk && [ -z ${defaultguis} ]
	then
		eerror "The Firefox plugin was selected but not the GTK frontend."
		eerror "Disable the nsplugin USE flag or enable the gtk USE flag"
		die "nsplugin USE flag enabled with required gtk USE flag disabled"
	fi

	if use ffmpeg && use gstreamer
	then
		einfo "Only 1 audio output source can be compiled into ${PN}."
		einfo "Selecting gstreamer, since that's upstream default."
		einfo "To enable ffmpeg you must also disable gstreamer."
	fi

	if use agg
	then
		if use opengl || use cairo
		then
			einfo "Only 1 renderer can be activated at any one time."
			einfo "If more than one renderer is activated, the order of preference is:"
			einfo "agg > opengl > cairo"
		fi
	else
		if use !opengl && use !cairo
		then
			einfo "No renderer selected from agg, opengl, cairo"
			einfo "Default renderer agg selected."
		fi
	fi

	if use !ffmpeg && use !gstreamer
	then
		ewarn "You did not select any media: ffmpeg gstreamer"
		ewarn "You will not have sound!"
	fi

}

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/${PN}-0.8.3-boost-dynamic-link.patch
	eautoreconf
}

src_compile() {
	local myconf

	if use nsplugin ; then
		myconf="${myconf} --enable-npapi --with-npapi-plugindir=/opt/netscape/plugins"
	else
		myconf="${myconf} --disable-npapi"
	fi

#Select renderer.
	if use agg ; then
		myconf="${myconf} --enable-renderer=agg"
	elif use opengl ; then
		myconf="${myconf} --enable-renderer=ogl"
	elif use cairo ; then
		myconf="${myconf} --enable-renderer=cairo"
	else
		myconf="${myconf} --enable-renderer=agg"
	fi

#Select which Graphical User Interfaces to build.
	local	guis="" \
		gui=""
	for gui in fbcon-FB gtk-GTK2 kde-KDE qt3-QT sdl-SDL
	do
		use ${gui/-*} && guis="${guis},${gui/*-}"
	done
	guis=${guis#,}
	if [ -z "${guis}" ]
	then
		guis="GTK2,KDE"
	fi

#Select which extensions to build.
	local	extensions="FILEIO" \
		extension=""
	for extension in dbus-DBUS gtk-GTK2 test-DEJAGNU
	do
		use ${extension%-*} && extensions="${extensions},${extension#*-}"
	done

#Select audio output extension.
	if use gstreamer
	then
		myconf="${myconf} --enable-media=gst"
	elif use ffmpeg
	then
		myconf="${myconf} --enable-media=ffmpeg"
	else
		myconf="${myconf} --enable-media=none"
	fi

	econf \
		$(use_enable video_cards_i810 i810-lod-bias)	\
		--disable-testsuite				\
		--enable-shared					\
		--disable-allstatic				\
		--enable-sdkinstall				\
		--enable-gui=${guis}				\
		--enable-extensions=${extensions}		\
		--with-ffmpeg-incl=/usr/include			\
		--with-kde-pluginprefix=${KDEDIR}		\
		--without-included-ltdl				\
		--with-ltdl-include=/usr/include		\
		--with-ltdl-lib=/usr/$(get_libdir)		\
		--with-plugins-install=system			\
		${myconf} \
		|| die "econf failed"
	emake || die "emake failed"
}

src_test() {
	cd testsuite
	make check || die  "make check failed"
	./anaylse-results.sh > TESTRESULTS.txt
	cat TESTRESULTS.txt
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	if use nsplugin
	then
		emake DESTDIR="${D}" install-plugin \
			|| die "emake install-plugin failed"
		inst_plugin /opt/netscape/plugins/libgnashplugin.so
	else
		rm -rf "${D}/opt"
	fi

	if use kde
	then
		pushd plugin/klash &> /dev/null
		make DESTDIR="${D}" install-plugin
		popd &> /dev/null
	fi

	dodoc AUTHORS ChangeLog* NEWS README

}

pkg_postinst() {
	ewarn "BETA"
	ewarn "gnash is still in heavy development"
	ewarn "please report gnash bugs upstream to the gnash devs"
}