[gentoo-commits] gentoo-x86 commit in media-sound/audacious: ChangeLog audacious-1.5.1-r1.ebuild

[Tony Vroon (chainsaw)]

chainsaw    08/07/22 14:16:03

  Modified:             ChangeLog
  Added:                audacious-1.5.1-r1.ebuild
  Log:
  Revision bump. Upstream patch from Matti Hamalainen <ccr@××××.org> closes bug #228365.
  (Portage version: 2.2_rc1/cvs/Linux 2.6.26 x86_64)

Revision  Changes    Path
1.149                media-sound/audacious/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/audacious/ChangeLog?rev=1.149&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/audacious/ChangeLog?rev=1.149&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/audacious/ChangeLog?r1=1.148&r2=1.149

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/audacious/ChangeLog,v
retrieving revision 1.148
retrieving revision 1.149
diff -u -r1.148 -r1.149
--- ChangeLog	24 May 2008 00:34:54 -0000	1.148
+++ ChangeLog	22 Jul 2008 14:16:02 -0000	1.149
@@ -1,6 +1,13 @@
 # ChangeLog for media-sound/audacious
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/audacious/ChangeLog,v 1.148 2008/05/24 00:34:54 chainsaw Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/audacious/ChangeLog,v 1.149 2008/07/22 14:16:02 chainsaw Exp $
+
+*audacious-1.5.1-r1 (22 Jul 2008)
+
+  22 Jul 2008; <chainsaw@g.o> +files/1.5.1-commandline-options.patch,
+  +audacious-1.5.1-r1.ebuild:
+  Revision bump. Upstream patch from Matti Hamalainen <ccr@××××.org> closes
+  bug #228365.
 
 *audacious-1.5.1 (24 May 2008)
 



1.1                  media-sound/audacious/audacious-1.5.1-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/audacious/audacious-1.5.1-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/audacious/audacious-1.5.1-r1.ebuild?rev=1.1&content-type=text/plain

Index: audacious-1.5.1-r1.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/audacious/audacious-1.5.1-r1.ebuild,v 1.1 2008/07/22 14:16:02 chainsaw Exp $

inherit flag-o-matic

MY_P="${P/_/-}"
S="${WORKDIR}/${MY_P}"
DESCRIPTION="Audacious Player - Your music, your way, no exceptions"
HOMEPAGE="http://audacious-media-player.org/"
SRC_URI="http://distfiles.atheme.org/${MY_P}.tgz
	 mirror://gentoo/gentoo_ice-xmms-0.2.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="altivec chardet nls libsamplerate session sse2"

RDEPEND=">=dev-libs/dbus-glib-0.60
	>=dev-libs/glib-2.14
	>=dev-libs/libmcs-0.7.1-r1
	>=dev-libs/libmowgli-0.7.0
	dev-libs/libxml2
	>=gnome-base/libglade-2.3.1
	>=x11-libs/cairo-1.2.4
	>=x11-libs/gtk+-2.10
	>=x11-libs/pango-1.8.0
	libsamplerate? ( media-libs/libsamplerate )
	session? ( x11-libs/libSM )"

DEPEND="${RDEPEND}
	>=dev-util/pkgconfig-0.9.0
	nls? ( dev-util/intltool )"

PDEPEND=">=media-plugins/audacious-plugins-1.5.1-r1"

src_unpack() {
	unpack ${A}
	cd "${S}"
	# Bug #228365, patch by Matti Hamalainen <ccr@××××.org>
	epatch "${FILESDIR}/${PV}-commandline-options.patch"
}

src_compile() {
	# D-Bus is a mandatory dependency, remote control,
	# session management and some plugins depend on this.
	# Building without D-Bus is *unsupported* and a USE-flag
	# will not be added due to the bug reports that will result.
	# Bugs #197894, #199069, #207330, #208606
	econf \
		--enable-dbus \
		$(use_enable altivec) \
		$(use_enable chardet) \
		$(use_enable nls) \
		$(use_enable session sm) \
		$(use_enable sse2) \
		$(use_enable libsamplerate samplerate) \
		|| die

	emake || die "make failed"
}

src_install() {
	make DESTDIR="${D}" install || die
	dodoc AUTHORS NEWS README

	# Gentoo_ice skin installation; bug #109772
	insinto /usr/share/audacious/Skins/gentoo_ice
	doins "${WORKDIR}"/gentoo_ice/*
	docinto gentoo_ice
	dodoc "${WORKDIR}"/README
}

pkg_postinst() {
	elog "Note that you need to recompile *all* third-party plugins for Audacious 1.5"
	elog "Plugins compiled against 1.3 or 1.4 will not be loaded."
}