keri        09/01/16 08:42:13

  Modified:             ChangeLog
  Added:                yap-5.1.3-r1.ebuild
  Log:
  Revbump to install docs and support dynamic-loading
  (Portage version: 2.1.6.4/cvs/Linux 2.6.26-gentoo-r3 x86_64)

Revision  Changes    Path
1.23                 dev-lang/yap/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/yap/ChangeLog?rev=1.23&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/yap/ChangeLog?rev=1.23&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/yap/ChangeLog?r1=1.22&r2=1.23

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-lang/yap/ChangeLog,v
retrieving revision 1.22
retrieving revision 1.23
diff -u -r1.22 -r1.23
--- ChangeLog	27 Jul 2008 05:11:50 -0000	1.22
+++ ChangeLog	16 Jan 2009 08:42:13 -0000	1.23
@@ -1,6 +1,12 @@
 # ChangeLog for dev-lang/yap
-# Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/yap/ChangeLog,v 1.22 2008/07/27 05:11:50 keri Exp $
+# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/yap/ChangeLog,v 1.23 2009/01/16 08:42:13 keri Exp $
+
+*yap-5.1.3-r1 (16 Jan 2009)
+
+  16 Jan 2009; <keri@g.o> +files/yap-5.1.3-bootdir.patch,
+  +yap-5.1.3-r1.ebuild:
+  Revbump to install docs and support dynamic-loading
 
 *yap-5.1.3 (27 Jul 2008)
 



1.1                  dev-lang/yap/yap-5.1.3-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/yap/yap-5.1.3-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/yap/yap-5.1.3-r1.ebuild?rev=1.1&content-type=text/plain

Index: yap-5.1.3-r1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-lang/yap/yap-5.1.3-r1.ebuild,v 1.1 2009/01/16 08:42:13 keri Exp $

inherit autotools eutils java-pkg-opt-2

MY_P="Yap-${PV}"

DESCRIPTION="YAP is a high-performance Prolog compiler."
HOMEPAGE="http://www.ncc.up.pt/~vsc/Yap/"
SRC_URI="http://www.ncc.up.pt/~vsc/Yap/current/Yap-5.1.3.tar.gz"

LICENSE="Artistic LGPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="debug doc examples gmp java mpi mysql odbc readline static tk threads"

DEPEND="gmp? ( dev-libs/gmp )
	java? ( >=virtual/jdk-1.4 )
	mpi? ( virtual/mpi )
	mysql? ( virtual/mysql )
	odbc? ( dev-db/unixODBC )
	readline? ( sys-libs/readline )
	doc? ( app-text/texi2html )"

RDEPEND="${DEPEND}
	tk? ( dev-lang/tk )"

S="${WORKDIR}"/${MY_P}

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/${P}-config.h.patch
	epatch "${FILESDIR}"/${P}-configure.patch
	epatch "${FILESDIR}"/${P}-multilib.patch
	epatch "${FILESDIR}"/${P}-parallel-make.patch
	epatch "${FILESDIR}"/${P}-bootdir.patch
	epatch "${FILESDIR}"/${P}-chr.patch
	epatch "${FILESDIR}"/${P}-tkyap.patch

	eautoconf
}

src_compile() {
	econf \
		--libdir=/usr/$(get_libdir) \
		--enable-cut-c \
		$(use_enable !static dynamic-loading) \
		$(use_enable threads) \
		$(use_enable threads pthread-locking) \
		$(use_enable debug debug-yap) \
		$(use_enable debug low-level-tracer) \
		$(use_enable mysql myddas-mysql) \
		$(use_enable mysql myddas-stats) \
		$(use_enable mysql myddas-top-level) \
		$(use_enable odbc myddas-odbc) \
		$(use_with gmp) \
		$(use_with readline) \
		$(use_with mpi) \
		$(use_with mpi mpe) \
		$(use_with java jpl) \
		|| die "econf failed"

	emake || die "emake failed"

	if use doc ; then
		emake html || die "emake html failed"
	fi
}

src_install() {
	emake DESTDIR="${D}" install || die "make install failed."

	if use tk ; then
		exeinto /usr/bin
		doexe misc/tkyap
	fi

	dodoc changes*.html README

	if use doc ; then
		dodoc yap.html
	fi

	if use examples ; then
		docinto examples
		dodoc CLPBN/clpbn/examples/cg.yap
		dodoc CLPBN/clpbn/examples/School/*
	fi
}