voyageur    08/01/24 14:30:11

  Modified:             ChangeLog
  Added:                nxnode-3.1.0-r1.ebuild
  Log:
  Maintenance release bump
  (Portage version: 2.1.4)

Revision  Changes    Path
1.20                 net-misc/nxnode/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/nxnode/ChangeLog?rev=1.20&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/nxnode/ChangeLog?rev=1.20&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/nxnode/ChangeLog?r1=1.19&r2=1.20

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/nxnode/ChangeLog,v
retrieving revision 1.19
retrieving revision 1.20
diff -u -r1.19 -r1.20
--- ChangeLog	14 Dec 2007 12:11:41 -0000	1.19
+++ ChangeLog	24 Jan 2008 14:30:10 -0000	1.20
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/nxnode
-# Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/nxnode/ChangeLog,v 1.19 2007/12/14 12:11:41 voyageur Exp $
+# Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/nxnode/ChangeLog,v 1.20 2008/01/24 14:30:10 voyageur Exp $
+
+*nxnode-3.1.0-r1 (24 Jan 2008)
+
+  24 Jan 2008; Bernard Cafarelli <voyageur@g.o>
+  +nxnode-3.1.0-r1.ebuild:
+  Maintenance release bump
 
 *nxnode-3.1.0 (14 Dec 2007)
 



1.1                  net-misc/nxnode/nxnode-3.1.0-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/nxnode/nxnode-3.1.0-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/nxnode/nxnode-3.1.0-r1.ebuild?rev=1.1&content-type=text/plain

Index: nxnode-3.1.0-r1.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/nxnode/nxnode-3.1.0-r1.ebuild,v 1.1 2008/01/24 14:30:10 voyageur Exp $

inherit eutils

MY_PV="${PV}-5"
DESCRIPTION="nxnode provides the components that are shared between the different editions of NoMachine's NX Server"
HOMEPAGE="http://www.nomachine.com/"
SRC_URI="amd64? ( http://64.34.161.181/download/${PV}/Linux/nxnode-${MY_PV}.x86_64.tar.gz )
	x86? ( http://64.34.161.181/download/${PV}/Linux/nxnode-${MY_PV}.i386.tar.gz )"

LICENSE="nomachine"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="rdesktop vnc"
RESTRICT="strip"

DEPEND="!net-misc/nxserver-freenx
	!<net-misc/nxserver-freeedition-3.0.0"

RDEPEND="=net-misc/nxclient-3.1*
	x11-libs/libICE
	x11-libs/libXmu
	x11-libs/libSM
	x11-libs/libXt
	x11-libs/libXaw
	x11-libs/libXpm
	x11-apps/xrdb
	rdesktop? ( net-misc/rdesktop )
	vnc? ( || ( net-misc/vnc net-misc/tightvnc ) )"

S=${WORKDIR}/NX

pkg_setup() {
	if use vnc; then
		if has_version net-misc/vnc && ! built_with_use net-misc/vnc server;
		then
			die "net-misc/vnc needs to be built with USE=\"server\" for VNC support"
		fi

		if has_version net-misc/tightvnc && ! built_with_use net-misc/tightvnc server;
		then
			die "net-misc/tightvnc needs to be built with USE=\"server\" for VNC support"
		fi
	fi
}

src_unpack()
{
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/nxnode-3.0.0-setup.patch
}

src_install()
{
	# we install nxnode into /usr/NX, to make sure it doesn't clash
	# with libraries installed for FreeNX

	into /usr/NX
	for x in nxagent nxnode nxsensor nxspool nxuexec ; do
		dobin bin/$x
	done

	dodir /usr/NX/etc
	cp etc/node-debian.cfg.sample "${D}"/usr/NX/etc/node-gentoo.cfg.sample || die
	sed -e 's|COMMAND_FUSER = .*|COMMAND_FUSER = "/usr/bin/fuser"|;' -i "${D}"/usr/NX/etc/node-gentoo.cfg.sample || die
	cp etc/node.lic.sample "${D}"/usr/NX/etc/node.lic.sample || die

	dodir /usr/NX/lib
	cp -R lib "${D}"/usr/NX || die

	dodir /usr/NX/scripts
	cp -R scripts "${D}"/usr/NX || die

	dodir /usr/NX/share
	cp -R share "${D}"/usr/NX || die

	dodir /usr/NX/var
	cp -R var "${D}"/usr/NX || die

	dodir /etc/init.d
	newinitd "${FILESDIR}"/nxnode-3.0.0-init nxsensor
}

pkg_postinst()
{
	# Only install license file if none is found
	if [ ! -f /usr/NX/etc/node.lic ]; then
		cp "${ROOT}"/usr/NX/etc/node.lic.sample "${ROOT}"/usr/NX/etc/node.lic || die
		chmod 0400 "${ROOT}"/usr/NX/etc/node.lic
		chown nx:root "${ROOT}"/usr/NX/etc/node.lic
	fi

	# only run install on the first time
	if [ -f /usr/NX/etc/node.cfg ]; then
		einfo "Running NoMachine's update script"
		"${ROOT}"/usr/NX/scripts/setup/nxnode --update
	else
		einfo "Running NoMachine's setup script"
		"${ROOT}"/usr/NX/scripts/setup/nxnode --install
	fi

	elog "If you want server statistics, please add nxsensor to your default runlevel"
	elog
	elog "  rc-update add nxsensor default"
	elog
	elog "You will also need to change EnableSensor to 1 in /usr/NX/etc/node.cfg"
}



-- 
gentoo-commits@g.o mailing list